qcsrc/client/view.qc

   1 #if defined(CSQC)
   2         #include "../dpdefs/csprogsdefs.qh"
   3         #include "defs.qh"
   4         #include "../common/constants.qh"
   5         #include "../common/stats.qh"
   6         #include "../warpzonelib/mathlib.qh"
   7         #include "../warpzonelib/common.qh"
   8         #include "../warpzonelib/client.qh"
   9         #include "../common/teams.qh"
  10         #include "../common/util.qh"
  11         #include "../common/nades.qh"
  12         #include "../common/weapons/weapons.qh"
  13         #include "../common/mapinfo.qh"
  14         #include "autocvars.qh"
  15         #include "hud.qh"
  16         #include "scoreboard.qh"
  17         #include "noise.qh"
  18         #include "main.qh"
  19         #include "../csqcmodellib/cl_player.qh"
  20 #elif defined(MENUQC)
  21 #elif defined(SVQC)
  22 #endif
  23
  24 entity porto;
  25 vector polyline[16];
  26 void Porto_Draw()
  27 {
  28         vector p, dir, ang, q, nextdir;
  29         float portal_number, portal1_idx;
  30
  31         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  32                 return;
  33         if(g_balance_porto_secondary)
  34                 return;
  35         if(intermission == 1)
  36                 return;
  37         if(intermission == 2)
  38                 return;
  39         if (getstati(STAT_HEALTH) <= 0)
  40                 return;
  41
  42         dir = view_forward;
  43
  44         if(angles_held_status)
  45         {
  46                 makevectors(angles_held);
  47                 dir = v_forward;
  48         }
  49
  50         p = view_origin;
  51
  52         polyline[0] = p;
  53         int idx = 1;
  54         portal_number = 0;
  55         nextdir = dir;
  56
  57         for (;;)
  58         {
  59                 dir = nextdir;
  60                 traceline(p, p + 65536 * dir, true, porto);
  61                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  62                         return;
  63                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  64                 p = trace_endpos;
  65                 polyline[idx] = p;
  66                 ++idx;
  67                 if(idx >= 16)
  68                         return;
  69                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  70                         continue;
  71                 ++portal_number;
  72                 ang = vectoangles2(trace_plane_normal, dir);
  73                 ang.x = -ang.x;
  74                 makevectors(ang);
  75                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  76                         return;
  77                 if(portal_number == 1)
  78                 {
  79                         portal1_idx = idx;
  80                         if(portal_number >= 2)
  81                                 break;
  82                 }
  83         }
  84
  85         while(idx >= 2)
  86         {
  87                 p = polyline[idx-2];
  88                 q = polyline[idx-1];
  89                 if(idx == 2)
  90                         p = p - view_up * 16;
  91                 if(idx-1 >= portal1_idx)
  92                 {
  93                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  94                 }
  95                 else
  96                 {
  97                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  98                 }
  99                 --idx;
 100         }
 101 }
 102
 103 void Porto_Init()
 104 {
 105         porto = spawn();
 106         porto.classname = "porto";
 107         porto.draw = Porto_Draw;
 108         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 109 }
 110
 111 float drawtime;
 112 float avgspeed;
 113 vector GetCurrentFov(float fov)
 114 {
 115         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 116         float velocityzoom, curspeed;
 117         vector v;
 118
 119         zoomsensitivity = autocvar_cl_zoomsensitivity;
 120         zoomfactor = autocvar_cl_zoomfactor;
 121         if(zoomfactor < 1 || zoomfactor > 16)
 122                 zoomfactor = 2.5;
 123         zoomspeed = autocvar_cl_zoomspeed;
 124         if(zoomspeed >= 0)
 125         if(zoomspeed < 0.5 || zoomspeed > 16)
 126                         zoomspeed = 3.5;
 127
 128         zoomdir = button_zoom;
 129         if(hud == HUD_NORMAL)
 130         if((activeweapon == WEP_VORTEX && vortex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 131                 zoomdir += button_attack2;
 132         if(spectatee_status > 0 || isdemo())
 133         {
 134                 if(spectatorbutton_zoom)
 135                 {
 136                         if(zoomdir)
 137                                 zoomdir = 0;
 138                         else
 139                                 zoomdir = 1;
 140                 }
 141                 // fteqcc failed twice here already, don't optimize this
 142         }
 143
 144         if(zoomdir) { zoomin_effect = 0; }
 145
 146         if(camera_active)
 147         {
 148                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 149         }
 150         else if(autocvar_cl_spawnzoom && zoomin_effect)
 151         {
 152                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 153
 154                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 155                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 156                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 189         {
 190                 if(intermission) { curspeed = 0; }
 191                 else
 192                 {
 193
 194                         makevectors(view_angles);
 195                         v = pmove_vel;
 196                         if(csqcplayer)
 197                                 v = csqcplayer.velocity;
 198
 199                         switch(autocvar_cl_velocityzoom_type)
 200                         {
 201                                 case 3: curspeed = max(0, v_forward * v); break;
 202                                 case 2: curspeed = (v_forward * v); break;
 203                                 case 1: default: curspeed = vlen(v); break;
 204                         }
 205                 }
 206
 207                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 208                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 209                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 210
 211                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 212         }
 213         else
 214                 velocityzoom = 1;
 215
 216         float frustumx, frustumy, fovx, fovy;
 217         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 218         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 219         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 220         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 221
 222         return '1 0 0' * fovx + '0 1 0' * fovy;
 223 }
 224
 225 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 226 {
 227         float fovx, fovy;
 228         float width = (ov_worldmax.x - ov_worldmin.x);
 229         float height = (ov_worldmax.y - ov_worldmin.y);
 230         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 231         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 232         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 233         return '1 0 0' * fovx + '0 1 0' * fovy;
 234 }
 235
 236 // this function must match W_SetupShot!
 237 float zoomscript_caught;
 238
 239 vector wcross_origin;
 240 float wcross_scale_prev, wcross_alpha_prev;
 241 vector wcross_color_prev;
 242 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 243 vector wcross_color_goal_prev;
 244 float wcross_changedonetime;
 245
 246 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 247 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 248 float wcross_name_changestarttime, wcross_name_changedonetime;
 249 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 250
 251 float wcross_ring_prev;
 252
 253 entity trueaim;
 254 entity trueaim_rifle;
 255
 256 const float SHOTTYPE_HITTEAM = 1;
 257 const float SHOTTYPE_HITOBSTRUCTION = 2;
 258 const float SHOTTYPE_HITWORLD = 3;
 259 const float SHOTTYPE_HITENEMY = 4;
 260
 261 void TrueAim_Init()
 262 {
 263         trueaim = spawn();
 264         trueaim.classname = "trueaim";
 265         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 266         trueaim_rifle = spawn();
 267         trueaim_rifle.classname = "trueaim_rifle";
 268         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 269 }
 270
 271 float EnemyHitCheck()
 272 {
 273         float t, n;
 274         wcross_origin = project_3d_to_2d(trace_endpos);
 275         wcross_origin.z = 0;
 276         if(trace_ent)
 277                 n = trace_ent.entnum;
 278         else
 279                 n = trace_networkentity;
 280         if(n < 1)
 281                 return SHOTTYPE_HITWORLD;
 282         if(n > maxclients)
 283                 return SHOTTYPE_HITWORLD;
 284         t = GetPlayerColor(n - 1);
 285         if(teamplay)
 286                 if(t == myteam)
 287                         return SHOTTYPE_HITTEAM;
 288         if(t == NUM_SPECTATOR)
 289                 return SHOTTYPE_HITWORLD;
 290         return SHOTTYPE_HITENEMY;
 291 }
 292
 293 float TrueAimCheck()
 294 {
 295         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 296         vector vecs, trueaimpoint, w_shotorg;
 297         vector mi, ma, dv;
 298         float shottype;
 299         entity ta;
 300         float mv;
 301
 302         mi = ma = '0 0 0';
 303         ta = trueaim;
 304         mv = MOVE_NOMONSTERS;
 305
 306         switch(activeweapon) // WEAPONTODO
 307         {
 308                 case WEP_TUBA: // no aim
 309                 case WEP_PORTO: // shoots from eye
 310                 case WEP_HOOK: // no trueaim
 311                 case WEP_MORTAR: // toss curve
 312                         return SHOTTYPE_HITWORLD;
 313                 case WEP_VORTEX:
 314                 case WEP_VAPORIZER:
 315                         mv = MOVE_NORMAL;
 316                         break;
 317                 case WEP_RIFLE:
 318                         ta = trueaim_rifle;
 319                         mv = MOVE_NORMAL;
 320                         if(zoomscript_caught)
 321                         {
 322                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 323                                 return EnemyHitCheck();
 324                         }
 325                         break;
 326                 case WEP_DEVASTATOR: // projectile has a size!
 327                         mi = '-3 -3 -3';
 328                         ma = '3 3 3';
 329                         break;
 330                 case WEP_FIREBALL: // projectile has a size!
 331                         mi = '-16 -16 -16';
 332                         ma = '16 16 16';
 333                         break;
 334                 case WEP_SEEKER: // projectile has a size!
 335                         mi = '-2 -2 -2';
 336                         ma = '2 2 2';
 337                         break;
 338                 case WEP_ELECTRO: // projectile has a size!
 339                         mi = '0 0 -3';
 340                         ma = '0 0 -3';
 341                         break;
 342         }
 343
 344         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 345
 346         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 347
 348         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 349         trueaimpoint = trace_endpos;
 350
 351         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 352                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 353
 354         if(vecs.x > 0)
 355                 vecs.y = -vecs.y;
 356         else
 357                 vecs = '0 0 0';
 358
 359         dv = view_right * vecs.y + view_up * vecs.z;
 360         w_shotorg = traceorigin + dv;
 361
 362         // now move the vecs forward as much as requested if possible
 363         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 364         w_shotorg = trace_endpos - view_forward * nudge;
 365
 366         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 367         shottype = EnemyHitCheck();
 368         if(shottype != SHOTTYPE_HITWORLD)
 369                 return shottype;
 370
 371 #if 0
 372         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 373         // or rather, I know why, but see no fix
 374         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 375                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 376                 return SHOTTYPE_HITOBSTRUCTION;
 377 #endif
 378
 379         return SHOTTYPE_HITWORLD;
 380 }
 381
 382 void CSQC_common_hud(void);
 383
 384 void PostInit(void);
 385 void CSQC_Demo_Camera();
 386 float HUD_WouldDrawScoreboard();
 387 float camera_mode;
 388 const float CAMERA_FREE = 1;
 389 const float CAMERA_CHASE = 2;
 390 float reticle_type;
 391 string reticle_image;
 392 string NextFrameCommand;
 393 void CSQC_SPIDER_HUD();
 394 void CSQC_RAPTOR_HUD();
 395
 396 vector freeze_org, freeze_ang;
 397 entity nightvision_noise, nightvision_noise2;
 398
 399 const float MAX_TIME_DIFF = 5;
 400 float pickup_crosshair_time, pickup_crosshair_size;
 401 float hitindication_crosshair_size;
 402 float use_vortex_chargepool;
 403
 404 float myhealth, myhealth_prev;
 405 float myhealth_flash;
 406
 407 float old_blurradius, old_bluralpha;
 408 float old_sharpen_intensity;
 409
 410 vector myhealth_gentlergb;
 411
 412 float contentavgalpha, liquidalpha_prev;
 413 vector liquidcolor_prev;
 414
 415 float eventchase_current_distance;
 416 float eventchase_running;
 417 float WantEventchase()
 418 {
 419         if(autocvar_cl_orthoview)
 420                 return false;
 421         if(intermission)
 422                 return true;
 423         if(spectatee_status >= 0)
 424         {
 425                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO)))
 426                         return true;
 427                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 428                 {
 429                         if(autocvar_cl_eventchase_death == 2)
 430                         {
 431                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 432                                 if(self.velocity == '0 0 0' || eventchase_running)
 433                                         return true;
 434                         }
 435                         else return true;
 436                 }
 437         }
 438         return false;
 439 }
 440
 441 vector damage_blurpostprocess, content_blurpostprocess;
 442
 443 float checkfail[16];
 444
 445 float unaccounted_damage = 0;
 446 void UpdateDamage()
 447 {
 448         // accumulate damage with each stat update
 449         static float damage_total_prev = 0;
 450         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 451         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 452         damage_total_prev = damage_total;
 453
 454         static float damage_dealt_time_prev = 0;
 455         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 456         if (damage_dealt_time != damage_dealt_time_prev)
 457         {
 458                 unaccounted_damage += unaccounted_damage_new;
 459                 dprint("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 460         }
 461         damage_dealt_time_prev = damage_dealt_time;
 462
 463         // prevent hitsound when switching spectatee
 464         static float spectatee_status_prev = 0;
 465         if (spectatee_status != spectatee_status_prev)
 466                 unaccounted_damage = 0;
 467         spectatee_status_prev = spectatee_status;
 468 }
 469
 470 void UpdateHitsound()
 471 {
 472         // varying sound pitch
 473
 474         static float hitsound_time_prev = 0;
 475         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 476         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 477         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 478         {
 479                 if (autocvar_cl_hitsound && unaccounted_damage)
 480                 {
 481                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 482                         float a = autocvar_cl_hitsound_max_pitch;
 483                         float b = autocvar_cl_hitsound_min_pitch;
 484                         float c = autocvar_cl_hitsound_nom_damage;
 485                         float x = unaccounted_damage;
 486                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 487
 488                         // if sound variation is disabled, set pitch_shift to 1
 489                         if (autocvar_cl_hitsound == 1)
 490                                 pitch_shift = 1;
 491
 492                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 493                         if (autocvar_cl_hitsound == 3)
 494                         {
 495                                 float mirror_value = (a-b)/2 + b;
 496                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 497                         }
 498
 499                         dprint("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 500
 501                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 502                         // todo: normalize sound pressure levels? seems unnecessary
 503
 504                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 505                 }
 506                 unaccounted_damage = 0;
 507                 hitsound_time_prev = time;
 508         }
 509
 510         static float typehit_time_prev = 0;
 511         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 512         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 513         {
 514                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 515                 typehit_time_prev = typehit_time;
 516         }
 517 }
 518
 519 void UpdateCrosshair()
 520 {
 521         static float rainbow_last_flicker;
 522     static vector rainbow_prev_color;
 523         entity e = self;
 524         float f, i, j;
 525         vector v;
 526         if(getstati(STAT_FROZEN))
 527                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 528         else if (getstatf(STAT_HEALING_ORB)>time)
 529                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
 530         if(!intermission)
 531         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 532         {
 533                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 534                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 535         }
 536         else if(getstatf(STAT_REVIVE_PROGRESS))
 537         {
 538                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 539                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 540         }
 541
 542         if(autocvar_r_letterbox == 0)
 543                 if(autocvar_viewsize < 120)
 544                         CSQC_common_hud();
 545
 546         // crosshair goes VERY LAST
 547         if(!scoreboard_active && !camera_active && intermission != 2 &&
 548                 spectatee_status != -1 && hud == HUD_NORMAL &&
 549                 !HUD_MinigameMenu_IsOpened() )
 550         {
 551                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 552                         return;
 553
 554                 string wcross_style;
 555                 float wcross_alpha, wcross_resolution;
 556                 wcross_style = autocvar_crosshair;
 557                 if (wcross_style == "0")
 558                         return;
 559                 wcross_resolution = autocvar_crosshair_size;
 560                 if (wcross_resolution == 0)
 561                         return;
 562                 wcross_alpha = autocvar_crosshair_alpha;
 563                 if (wcross_alpha == 0)
 564                         return;
 565
 566                 // TrueAim check
 567                 float shottype;
 568
 569                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 570                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 571                 wcross_origin.z = 0;
 572                 if(autocvar_crosshair_hittest)
 573                 {
 574                         vector wcross_oldorigin;
 575                         wcross_oldorigin = wcross_origin;
 576                         shottype = TrueAimCheck();
 577                         if(shottype == SHOTTYPE_HITWORLD)
 578                         {
 579                                 v = wcross_origin - wcross_oldorigin;
 580                                 v.x /= vid_conwidth;
 581                                 v.y /= vid_conheight;
 582                                 if(vlen(v) > 0.01)
 583                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 584                         }
 585                         if(!autocvar_crosshair_hittest_showimpact)
 586                                 wcross_origin = wcross_oldorigin;
 587                 }
 588                 else
 589                         shottype = SHOTTYPE_HITWORLD;
 590
 591                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 592                 string wcross_name = "";
 593                 float wcross_scale, wcross_blur;
 594
 595                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 596                 {
 597                         e = get_weaponinfo(switchingweapon);
 598                         if(e)
 599                         {
 600                                 if(autocvar_crosshair_per_weapon)
 601                                 {
 602                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 603                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 604                                         //if (wcross_resolution == 0)
 605                                                 //return;
 606
 607                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 608                                         wcross_resolution *= e.w_crosshair_size;
 609                                         wcross_name = e.w_crosshair;
 610                                 }
 611                         }
 612                 }
 613
 614                 if(wcross_name == "")
 615                         wcross_name = strcat("gfx/crosshair", wcross_style);
 616
 617                 // MAIN CROSSHAIR COLOR DECISION
 618                 switch(autocvar_crosshair_color_special)
 619                 {
 620                         case 1: // crosshair_color_per_weapon
 621                         {
 622                                 if(e)
 623                                 {
 624                                         wcross_color = e.wpcolor;
 625                                         break;
 626                                 }
 627                                 else { goto normalcolor; }
 628                         }
 629
 630                         case 2: // crosshair_color_by_health
 631                         {
 632                                 float x = getstati(STAT_HEALTH);
 633
 634                                 //x = red
 635                                 //y = green
 636                                 //z = blue
 637
 638                                 wcross_color.z = 0;
 639
 640                                 if(x > 200)
 641                                 {
 642                                         wcross_color.x = 0;
 643                                         wcross_color.y = 1;
 644                                 }
 645                                 else if(x > 150)
 646                                 {
 647                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 648                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 649                                 }
 650                                 else if(x > 100)
 651                                 {
 652                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 653                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 654                                         wcross_color.z = 1 - (x-100)*0.02;
 655                                 }
 656                                 else if(x > 50)
 657                                 {
 658                                         wcross_color.x = 1;
 659                                         wcross_color.y = 1;
 660                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 661                                 }
 662                                 else if(x > 20)
 663                                 {
 664                                         wcross_color.x = 1;
 665                                         wcross_color.y = (x-20)*90/27/100;
 666                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 667                                 }
 668                                 else
 669                                 {
 670                                         wcross_color.x = 1;
 671                                         wcross_color.y = 0;
 672                                 }
 673                                 break;
 674                         }
 675
 676                         case 3: // crosshair_color_rainbow
 677                         {
 678                                 if(time >= rainbow_last_flicker)
 679                                 {
 680                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 681                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 682                                 }
 683                                 wcross_color = rainbow_prev_color;
 684                                 break;
 685                         }
 686                         :normalcolor
 687                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 688                 }
 689
 690                 if(autocvar_crosshair_effect_scalefade)
 691                 {
 692                         wcross_scale = wcross_resolution;
 693                         wcross_resolution = 1;
 694                 }
 695                 else
 696                 {
 697                         wcross_scale = 1;
 698                 }
 699
 700                 if(autocvar_crosshair_pickup)
 701                 {
 702                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 703
 704                         if(pickup_crosshair_time < stat_pickup_time)
 705                         {
 706                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 707                                         pickup_crosshair_size = 1;
 708
 709                                 pickup_crosshair_time = stat_pickup_time;
 710                         }
 711
 712                         if(pickup_crosshair_size > 0)
 713                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 714                         else
 715                                 pickup_crosshair_size = 0;
 716
 717                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 718                 }
 719
 720                 // todo: make crosshair hit indication dependent on damage dealt
 721                 if(autocvar_crosshair_hitindication)
 722                 {
 723                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 724
 725                         if(unaccounted_damage)
 726                         {
 727                                 hitindication_crosshair_size = 1;
 728                         }
 729
 730                         if(hitindication_crosshair_size > 0)
 731                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 732                         else
 733                                 hitindication_crosshair_size = 0;
 734
 735                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 736                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 737                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 738                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 739                 }
 740
 741                 if(shottype == SHOTTYPE_HITENEMY)
 742                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 743                 if(shottype == SHOTTYPE_HITTEAM)
 744                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 745
 746                 f = fabs(autocvar_crosshair_effect_time);
 747                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 748                 {
 749                         wcross_changedonetime = time + f;
 750                 }
 751                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 752                 {
 753                         wcross_name_changestarttime = time;
 754                         wcross_name_changedonetime = time + f;
 755                         if(wcross_name_goal_prev_prev)
 756                                 strunzone(wcross_name_goal_prev_prev);
 757                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 758                         wcross_name_goal_prev = strzone(wcross_name);
 759                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 760                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 761                         wcross_resolution_goal_prev = wcross_resolution;
 762                 }
 763
 764                 wcross_scale_goal_prev = wcross_scale;
 765                 wcross_alpha_goal_prev = wcross_alpha;
 766                 wcross_color_goal_prev = wcross_color;
 767
 768                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 769                 {
 770                         wcross_blur = 1;
 771                         wcross_alpha *= 0.75;
 772                 }
 773                 else
 774                         wcross_blur = 0;
 775                 // *_prev is at time-frametime
 776                 // * is at wcross_changedonetime+f
 777                 // what do we have at time?
 778                 if(time < wcross_changedonetime)
 779                 {
 780                         f = frametime / (wcross_changedonetime - time + frametime);
 781                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 782                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 783                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 784                 }
 785
 786                 wcross_scale_prev = wcross_scale;
 787                 wcross_alpha_prev = wcross_alpha;
 788                 wcross_color_prev = wcross_color;
 789
 790                 wcross_scale *= 1 - autocvar__menu_alpha;
 791                 wcross_alpha *= 1 - autocvar__menu_alpha;
 792                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 793
 794                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 795                 {
 796                         // crosshair rings for weapon stats
 797                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 798                         {
 799                                 // declarations and stats
 800                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 801                                 string ring_image = string_null, ring_inner_image = string_null;
 802                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 803
 804                                 ring_scale = autocvar_crosshair_ring_size;
 805
 806                                 float weapon_clipload, weapon_clipsize;
 807                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 808                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 809
 810                                 float ok_ammo_charge, ok_ammo_chargepool;
 811                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 812                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 813
 814                                 float vortex_charge, vortex_chargepool;
 815                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 816                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 817
 818                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 819
 820                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 821                                         vortex_charge_movingavg = vortex_charge;
 822
 823
 824                                 // handle the values
 825                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 826                                 {
 827                                         if (vortex_chargepool || use_vortex_chargepool) {
 828                                                 use_vortex_chargepool = 1;
 829                                                 ring_inner_value = vortex_chargepool;
 830                                         } else {
 831                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 832                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 833                                         }
 834
 835                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 836                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 837                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 838
 839                                         // draw the outer ring to show the current charge of the weapon
 840                                         ring_value = vortex_charge;
 841                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 842                                         ring_rgb = wcross_color;
 843                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 844                                 }
 845                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 846                                 {
 847                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 848                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 849                                         ring_rgb = wcross_color;
 850                                         ring_image = "gfx/crosshair_ring.tga";
 851                                 }
 852                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 853                                 {
 854                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 855                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 856                                         ring_rgb = wcross_color;
 857                                         ring_image = "gfx/crosshair_ring.tga";
 858                                 }
 859                                 else if (ok_ammo_charge)
 860                                 {
 861                                         ring_value = ok_ammo_chargepool;
 862                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 863                                         ring_rgb = wcross_color;
 864                                         ring_image = "gfx/crosshair_ring.tga";
 865                                 }
 866                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 867                                 {
 868                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 869                                         ring_scale = autocvar_crosshair_ring_reload_size;
 870                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 871                                         ring_rgb = wcross_color;
 872
 873                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 874                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 875                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
 876                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 877                                         else
 878                                                 ring_image = "gfx/crosshair_ring.tga";
 879                                 }
 880                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
 881                                 {
 882                                         ring_value = arc_heat;
 883                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 884                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 885                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 886                                         ring_image = "gfx/crosshair_ring.tga";
 887                                 }
 888
 889                                 // if in weapon switch animation, fade ring out/in
 890                                 if(autocvar_crosshair_effect_time > 0)
 891                                 {
 892                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 893                                         if (f >= 1)
 894                                         {
 895                                                 wcross_ring_prev = ((ring_image) ? true : false);
 896                                         }
 897
 898                                         if(wcross_ring_prev)
 899                                         {
 900                                                 if(f < 1)
 901                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 902                                         }
 903                                         else
 904                                         {
 905                                                 if(f < 1)
 906                                                         ring_alpha *= bound(0, f, 1);
 907                                         }
 908                                 }
 909
 910                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 911                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 912
 913                                 if (ring_value)
 914                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 915                         }
 916
 917 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 918                         do \
 919                         { \
 920                                 if(wcross_blur > 0) \
 921                                 { \
 922                                         for(i = -2; i <= 2; ++i) \
 923                                         for(j = -2; j <= 2; ++j) \
 924                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 925                                 } \
 926                                 else \
 927                                 { \
 928                                         M(0,0,sz,wcross_name,wcross_alpha); \
 929                                 } \
 930                         } \
 931                         while(0)
 932
 933 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 934                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 935
 936 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 937                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 938
 939                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 940                         {
 941                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 942                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 943                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 944                                 f = 1 - f;
 945                         }
 946                         else
 947                         {
 948                                 f = 1;
 949                         }
 950                         wcross_name_alpha_goal_prev = f;
 951
 952                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 953                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 954
 955                         if(autocvar_crosshair_dot)
 956                         {
 957                                 vector wcross_color_old;
 958                                 wcross_color_old = wcross_color;
 959
 960                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 961                                         wcross_color = stov(autocvar_crosshair_dot_color);
 962
 963                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 964                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 965                                 wcross_color = wcross_color_old;
 966                         }
 967                 }
 968         }
 969         else
 970         {
 971                 wcross_scale_prev = 0;
 972                 wcross_alpha_prev = 0;
 973                 wcross_scale_goal_prev = 0;
 974                 wcross_alpha_goal_prev = 0;
 975                 wcross_changedonetime = 0;
 976                 if(wcross_name_goal_prev)
 977                         strunzone(wcross_name_goal_prev);
 978                 wcross_name_goal_prev = string_null;
 979                 if(wcross_name_goal_prev_prev)
 980                         strunzone(wcross_name_goal_prev_prev);
 981                 wcross_name_goal_prev_prev = string_null;
 982                 wcross_name_changestarttime = 0;
 983                 wcross_name_changedonetime = 0;
 984                 wcross_name_alpha_goal_prev = 0;
 985                 wcross_name_alpha_goal_prev_prev = 0;
 986                 wcross_resolution_goal_prev = 0;
 987                 wcross_resolution_goal_prev_prev = 0;
 988         }
 989 }
 990
 991 const int BUTTON_3 = 4;
 992 const int BUTTON_4 = 8;
 993 float cl_notice_run();
 994 float prev_myteam;
 995 void CSQC_UpdateView(float w, float h)
 996 {
 997         entity e;
 998         float fov;
 999         float f;
1000         int i;
1001         vector vf_size, vf_min;
1002         float a;
1003
1004         execute_next_frame();
1005
1006         ++framecount;
1007
1008         hud = getstati(STAT_HUD);
1009
1010         if(autocvar__hud_showbinds_reload) // menu can set this one
1011         {
1012                 db_close(binddb);
1013                 binddb = db_create();
1014                 cvar_set("_hud_showbinds_reload", "0");
1015         }
1016
1017         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1018                 view_quality = getproperty(VF_MINFPS_QUALITY);
1019         else
1020                 view_quality = 1;
1021
1022         button_attack2 = (input_buttons & BUTTON_3);
1023         button_zoom = (input_buttons & BUTTON_4);
1024
1025 #define CHECKFAIL_ASSERT(flag,func,parm,val) do {                                                                   \
1026         float checkfailv = (func)(parm);                                                                                \
1027         if (checkfailv != (val)) {                                                                                      \
1028                 if (!checkfail[(flag)])                                                                                     \
1029                 localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv));                           \
1030                 checkfail[(flag)] = 1;                                                                                      \
1031         }                                                                                                               \
1032 } while(0)
1033         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
1034         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
1035         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
1036         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1037         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
1038         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
1039         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1040
1041         vf_size = getpropertyvec(VF_SIZE);
1042         vf_min = getpropertyvec(VF_MIN);
1043         vid_width = vf_size.x;
1044         vid_height = vf_size.y;
1045
1046         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1047         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1048
1049         WaypointSprite_Load();
1050
1051         CSQCPlayer_SetCamera();
1052
1053         myteam = GetPlayerColor(player_localentnum - 1);
1054
1055         if(myteam != prev_myteam)
1056         {
1057                 myteamcolors = colormapPaletteColor(myteam, 1);
1058                 for(i = 0; i < HUD_PANEL_NUM; ++i)
1059                         hud_panel[i].update_time = time;
1060                 prev_myteam = myteam;
1061         }
1062
1063         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1064
1065         float is_dead = (getstati(STAT_HEALTH) <= 0);
1066
1067         // FIXME do we need this hack?
1068         if(isdemo())
1069         {
1070                 // in demos, input_buttons do not work
1071                 button_zoom = (autocvar__togglezoom == "-");
1072         }
1073         else if(button_zoom
1074                 && autocvar_cl_unpress_zoom_on_death
1075                 && (spectatee_status >= 0)
1076                 && (is_dead || intermission))
1077         {
1078                 // no zoom while dead or in intermission please
1079                 localcmd("-zoom\n");
1080                 button_zoom = false;
1081         }
1082
1083         // event chase camera
1084         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1085         {
1086                 if(WantEventchase())
1087                 {
1088                         eventchase_running = true;
1089
1090                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1091                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1092
1093                         // detect maximum viewoffset and use it
1094                         if(autocvar_cl_eventchase_viewoffset)
1095                         {
1096                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1097                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
1098                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1099                         }
1100
1101                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1102                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1103                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1104                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1105
1106                         // make the camera smooth back
1107                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
1108                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1109                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
1110                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
1111
1112                         makevectors(view_angles);
1113
1114                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1115                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1116
1117                         // If the boxtrace fails, revert back to line tracing.
1118                         if(trace_startsolid)
1119                         {
1120                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1121                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1122                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1123                         }
1124                         else { setproperty(VF_ORIGIN, trace_endpos); }
1125
1126                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1127                 }
1128                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1129                 {
1130                         eventchase_running = false;
1131                         cvar_set("chase_active", "0");
1132                         eventchase_current_distance = 0; // start from 0 next time
1133                 }
1134         }
1135         // workaround for camera stuck between player's legs when using chase_active 1
1136         // because the engine stops updating the chase_active camera when the game ends
1137         else if(intermission)
1138         {
1139                 cvar_settemp("chase_active", "-1");
1140                 eventchase_current_distance = 0;
1141         }
1142
1143         // do lockview after event chase camera so that it still applies whenever necessary.
1144         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
1145         {
1146                 setproperty(VF_ORIGIN, freeze_org);
1147                 setproperty(VF_ANGLES, freeze_ang);
1148         }
1149         else
1150         {
1151                 freeze_org = getpropertyvec(VF_ORIGIN);
1152                 freeze_ang = getpropertyvec(VF_ANGLES);
1153         }
1154
1155         WarpZone_FixView();
1156         //WarpZone_FixPMove();
1157
1158         vector ov_org = '0 0 0';
1159         vector ov_mid = '0 0 0';
1160         vector ov_worldmin = '0 0 0';
1161         vector ov_worldmax = '0 0 0';
1162         if(autocvar_cl_orthoview)
1163         {
1164                 ov_worldmin = mi_picmin;
1165                 ov_worldmax = mi_picmax;
1166
1167                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1168                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1169                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1170
1171                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1172                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1173
1174                 float ov_nearest = vlen(ov_org - vec3(
1175                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1176                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1177                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1178                 ));
1179
1180                 float ov_furthest = 0;
1181                 float dist = 0;
1182
1183                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1184                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1185                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1186                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1187                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1188                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1189                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1190                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1191
1192                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1193                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1194                 cvar_settemp("r_farclip_world", "0");
1195                 cvar_settemp("r_novis", "1");
1196                 cvar_settemp("r_useportalculling", "0");
1197                 cvar_settemp("r_useinfinitefarclip", "0");
1198
1199                 setproperty(VF_ORIGIN, ov_org);
1200                 setproperty(VF_ANGLES, '90 0 0');
1201
1202                 #if 0
1203                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1204                         vtos(ov_org),
1205                         vtos(getpropertyvec(VF_ANGLES)),
1206                         ov_distance,
1207                         ov_nearest,
1208                         ov_furthest);
1209                 #endif
1210         }
1211
1212         // Render the Scene
1213         view_origin = getpropertyvec(VF_ORIGIN);
1214         view_angles = getpropertyvec(VF_ANGLES);
1215         makevectors(view_angles);
1216         view_forward = v_forward;
1217         view_right = v_right;
1218         view_up = v_up;
1219
1220 #ifdef BLURTEST
1221         if(time > blurtest_time0 && time < blurtest_time1)
1222         {
1223                 float r, t;
1224
1225                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1226                 r = t * blurtest_radius;
1227                 f = 1 / pow(t, blurtest_power) - 1;
1228
1229                 cvar_set("r_glsl_postprocess", "1");
1230                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1231         }
1232         else
1233         {
1234                 cvar_set("r_glsl_postprocess", "0");
1235                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1236         }
1237 #endif
1238
1239         TargetMusic_Advance();
1240         Fog_Force();
1241
1242         if(drawtime == 0)
1243                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1244         else
1245                 drawframetime = bound(0.000001, time - drawtime, 1);
1246         drawtime = time;
1247
1248         // watch for gametype changes here...
1249         // in ParseStuffCMD the cmd isn't executed yet :/
1250         // might even be better to add the gametype to TE_CSQC_INIT...?
1251         if(!postinit)
1252                 PostInit();
1253
1254         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1255         {
1256                 if(calledhooks & HOOK_START)
1257                 {
1258                         localcmd("\ncl_hook_gameend\n");
1259                         calledhooks |= HOOK_END;
1260                 }
1261         }
1262
1263         Announcer();
1264
1265         fov = autocvar_fov;
1266         if(fov <= 59.5)
1267         {
1268                 if(!zoomscript_caught)
1269                 {
1270                         localcmd("+button9\n");
1271                         zoomscript_caught = 1;
1272                 }
1273         }
1274         else
1275         {
1276                 if(zoomscript_caught)
1277                 {
1278                         localcmd("-button9\n");
1279                         zoomscript_caught = 0;
1280                 }
1281         }
1282
1283         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1284
1285         // next WANTED weapon (for HUD)
1286         switchweapon = getstati(STAT_SWITCHWEAPON);
1287
1288         // currently switching-to weapon (for crosshair)
1289         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1290
1291         // actually active weapon (for zoom)
1292         activeweapon = getstati(STAT_ACTIVEWEAPON);
1293
1294         f = (serverflags & SERVERFLAG_TEAMPLAY);
1295         if(f != teamplay)
1296         {
1297                 teamplay = f;
1298                 HUD_InitScores();
1299         }
1300
1301         if(last_switchweapon != switchweapon)
1302         {
1303                 weapontime = time;
1304                 last_switchweapon = switchweapon;
1305                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1306                 {
1307                         localcmd("-zoom\n");
1308                         button_zoom = false;
1309                 }
1310                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1311                 {
1312                         localcmd("-fire\n");
1313                         localcmd("-fire2\n");
1314                         button_attack2 = false;
1315                 }
1316         }
1317         if(last_activeweapon != activeweapon)
1318         {
1319                 last_activeweapon = activeweapon;
1320
1321                 e = get_weaponinfo(activeweapon);
1322                 if(e.netname != "")
1323                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1324                 else
1325                         localcmd("\ncl_hook_activeweapon none\n");
1326         }
1327
1328         // ALWAYS Clear Current Scene First
1329         clearscene();
1330
1331         setproperty(VF_ORIGIN, view_origin);
1332         setproperty(VF_ANGLES, view_angles);
1333
1334         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1335         setproperty(VF_SIZE, vf_size);
1336         setproperty(VF_MIN, vf_min);
1337
1338         // Assign Standard Viewflags
1339         // Draw the World (and sky)
1340         setproperty(VF_DRAWWORLD, 1);
1341
1342         // Set the console size vars
1343         vid_conwidth = autocvar_vid_conwidth;
1344         vid_conheight = autocvar_vid_conheight;
1345         vid_pixelheight = autocvar_vid_pixelheight;
1346
1347         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1348         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1349
1350         // Camera for demo playback
1351         if(camera_active)
1352         {
1353                 if(autocvar_camera_enable)
1354                         CSQC_Demo_Camera();
1355                 else
1356                 {
1357                         cvar_set("chase_active", ftos(chase_active_backup));
1358                         cvar_set("cl_demo_mousegrab", "0");
1359                         camera_active = false;
1360                 }
1361         }
1362         else
1363         {
1364 #ifdef CAMERATEST
1365                 if(autocvar_camera_enable)
1366 #else
1367                 if(autocvar_camera_enable && isdemo())
1368 #endif
1369                 {
1370                         // Enable required Darkplaces cvars
1371                         chase_active_backup = autocvar_chase_active;
1372                         cvar_set("chase_active", "2");
1373                         cvar_set("cl_demo_mousegrab", "1");
1374                         camera_active = true;
1375                         camera_mode = false;
1376                 }
1377         }
1378
1379         // Draw the Crosshair
1380         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1381
1382         // Draw the Engine Status Bar (the default Quake HUD)
1383         setproperty(VF_DRAWENGINESBAR, 0);
1384
1385         // Update the mouse position
1386         /*
1387            mousepos_x = vid_conwidth;
1388            mousepos_y = vid_conheight;
1389            mousepos = mousepos*0.5 + getmousepos();
1390          */
1391
1392         e = self;
1393         for(self = world; (self = nextent(self)); )
1394                 if(self.draw)
1395                         self.draw();
1396         self = e;
1397
1398         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1399         renderscene();
1400
1401         // now switch to 2D drawing mode by calling a 2D drawing function
1402         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1403         // next R_RenderScene call
1404         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1405
1406         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1407         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1408         {
1409                 // apply night vision effect
1410                 vector tc_00, tc_01, tc_10, tc_11;
1411                 vector rgb = '0 0 0';
1412
1413                 if(!nightvision_noise)
1414                 {
1415                         nightvision_noise = spawn();
1416                         nightvision_noise.classname = "nightvision_noise";
1417                 }
1418                 if(!nightvision_noise2)
1419                 {
1420                         nightvision_noise2 = spawn();
1421                         nightvision_noise2.classname = "nightvision_noise2";
1422                 }
1423
1424                 // color tint in yellow
1425                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1426
1427                 // draw BG
1428                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1429                 rgb = '1 1 1';
1430                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1431                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1432                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1433                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1434                 tc_11 = tc_01 + tc_10 - tc_00;
1435                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1436                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1437                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1438                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1439                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1440                 R_EndPolygon();
1441
1442                 // draw FG
1443                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1444                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1445                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1446                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1447                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1448                 tc_11 = tc_01 + tc_10 - tc_00;
1449                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1450                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1451                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1452                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1453                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1454                 R_EndPolygon();
1455         }
1456
1457         if(autocvar_cl_reticle)
1458         {
1459                 // Draw the aiming reticle for weapons that use it
1460                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1461                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1462                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1463                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1464                 {
1465                         // no zoom reticle while dead
1466                         reticle_type = 0;
1467                 }
1468                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
1469                 {
1470                         if(reticle_image != "") { reticle_type = 2; }
1471                         else { reticle_type = 0; }
1472                 }
1473                 else if(button_zoom || zoomscript_caught)
1474                 {
1475                         // normal zoom
1476                         reticle_type = 1;
1477                 }
1478
1479                 if(reticle_type)
1480                 {
1481                         if(autocvar_cl_reticle_stretch)
1482                         {
1483                                 reticle_size.x = vid_conwidth;
1484                                 reticle_size.y = vid_conheight;
1485                                 reticle_pos.x = 0;
1486                                 reticle_pos.y = 0;
1487                         }
1488                         else
1489                         {
1490                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1491                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1492                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1493                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1494                         }
1495
1496                         if(zoomscript_caught)
1497                                 f = 1;
1498                         else
1499                                 f = current_zoomfraction;
1500
1501                         if(f)
1502                         {
1503                                 switch(reticle_type)
1504                                 {
1505                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1506                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1507                                 }
1508                         }
1509                 }
1510         }
1511         else
1512         {
1513                 if(reticle_type != 0) { reticle_type = 0; }
1514         }
1515
1516
1517         // improved polyblend
1518         if(autocvar_hud_contents)
1519         {
1520                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1521                 vector liquidcolor;
1522
1523                 switch(pointcontents(view_origin))
1524                 {
1525                         case CONTENT_WATER:
1526                                 liquidalpha = autocvar_hud_contents_water_alpha;
1527                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1528                                 incontent = 1;
1529                                 break;
1530
1531                         case CONTENT_LAVA:
1532                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1533                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1534                                 incontent = 1;
1535                                 break;
1536
1537                         case CONTENT_SLIME:
1538                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1539                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1540                                 incontent = 1;
1541                                 break;
1542
1543                         default:
1544                                 liquidalpha = 0;
1545                                 liquidcolor = '0 0 0';
1546                                 incontent = 0;
1547                                 break;
1548                 }
1549
1550                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1551                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1552                         contentfadetime = autocvar_hud_contents_fadeintime;
1553                         liquidalpha_prev = liquidalpha;
1554                         liquidcolor_prev = liquidcolor;
1555                 }
1556                 else
1557                         contentfadetime = autocvar_hud_contents_fadeouttime;
1558
1559                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1560                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1561
1562                 if(contentavgalpha)
1563                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1564
1565                 if(autocvar_hud_postprocessing)
1566                 {
1567                         if(autocvar_hud_contents_blur && contentavgalpha)
1568                         {
1569                                 content_blurpostprocess.x = 1;
1570                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1571                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1572                         }
1573                         else
1574                         {
1575                                 content_blurpostprocess.x = 0;
1576                                 content_blurpostprocess.y = 0;
1577                                 content_blurpostprocess.z = 0;
1578                         }
1579                 }
1580         }
1581
1582         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1583         {
1584                 splash_size.x = max(vid_conwidth, vid_conheight);
1585                 splash_size.y = max(vid_conwidth, vid_conheight);
1586                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1587                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1588
1589                 float myhealth_flash_temp;
1590                 myhealth = getstati(STAT_HEALTH);
1591
1592                 // fade out
1593                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1594                 // add new damage
1595                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1596
1597                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1598                 pain_threshold = autocvar_hud_damage_pain_threshold;
1599                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1600                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1601
1602                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1603                 {
1604                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1605                 }
1606
1607                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1608
1609                 if(myhealth_prev < 1)
1610                 {
1611                         if(myhealth >= 1)
1612                         {
1613                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1614                                 myhealth_flash_temp = 0;
1615                         }
1616                         else
1617                         {
1618                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1619                         }
1620                 }
1621
1622                 if(spectatee_status == -1 || intermission)
1623                 {
1624                         myhealth_flash = 0; // observing, or match ended
1625                         myhealth_flash_temp = 0;
1626                 }
1627
1628                 myhealth_prev = myhealth;
1629
1630                 // IDEA: change damage color/picture based on player model for robot/alien species?
1631                 // pro: matches model better
1632                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1633                 // maybe different reddish pics?
1634                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1635                 {
1636                         if(autocvar_cl_gentle_damage == 2)
1637                         {
1638                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1639                                 {
1640                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1641                                 }
1642                         }
1643                         else
1644                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1645
1646                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1647                 }
1648                 else
1649                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1650
1651                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1652                 {
1653                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1654                         {
1655                                 damage_blurpostprocess.x = 1;
1656                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1657                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1658                         }
1659                         else
1660                         {
1661                                 damage_blurpostprocess.x = 0;
1662                                 damage_blurpostprocess.y = 0;
1663                                 damage_blurpostprocess.z = 0;
1664                         }
1665                 }
1666         }
1667
1668         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1669         float e2 = (autocvar_hud_powerup != 0);
1670         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1671         {
1672                 // enable or disable rendering types if they are used or not
1673                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1674                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1675
1676                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1677                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1678                 {
1679                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1680                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1681                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1682                         {
1683                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1684                                 old_blurradius = blurradius;
1685                                 old_bluralpha = bluralpha;
1686                         }
1687                 }
1688                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1689                 {
1690                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1691                         old_blurradius = 0;
1692                         old_bluralpha = 0;
1693                 }
1694
1695                 // edge detection postprocess handling done second (used by hud_powerup)
1696                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1697                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1698                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1699
1700                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1701
1702                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1703                 {
1704                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1705                         {
1706                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1707                                 old_sharpen_intensity = sharpen_intensity;
1708                         }
1709                 }
1710                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1711                 {
1712                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1713                         old_sharpen_intensity = 0;
1714                 }
1715
1716                 if(cvar("r_glsl_postprocess") == 0)
1717                         cvar_set("r_glsl_postprocess", "2");
1718         }
1719         else if(cvar("r_glsl_postprocess") == 2)
1720                 cvar_set("r_glsl_postprocess", "0");
1721
1722         if(menu_visible)
1723                 menu_show();
1724
1725         /*if(gametype == MAPINFO_TYPE_CTF)
1726           {
1727           ctf_view();
1728           } else */
1729
1730         // draw 2D entities
1731         e = self;
1732         for(self = world; (self = nextent(self)); )
1733                 if(self.draw2d)
1734                         self.draw2d();
1735         self = e;
1736         Draw_ShowNames_All();
1737
1738         scoreboard_active = HUD_WouldDrawScoreboard();
1739
1740         UpdateDamage();
1741         UpdateCrosshair();
1742         UpdateHitsound();
1743
1744         if(NextFrameCommand)
1745         {
1746                 localcmd("\n", NextFrameCommand, "\n");
1747                 NextFrameCommand = string_null;
1748         }
1749
1750         // we must do this check AFTER a frame was rendered, or it won't work
1751         if(cs_project_is_b0rked == 0)
1752         {
1753                 string w0, h0;
1754                 w0 = ftos(autocvar_vid_conwidth);
1755                 h0 = ftos(autocvar_vid_conheight);
1756                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1757                 //setproperty(VF_FOV, '90 90 0');
1758                 setproperty(VF_ORIGIN, '0 0 0');
1759                 setproperty(VF_ANGLES, '0 0 0');
1760                 setproperty(VF_PERSPECTIVE, 1);
1761                 makevectors('0 0 0');
1762                 vector v1, v2;
1763                 cvar_set("vid_conwidth", "800");
1764                 cvar_set("vid_conheight", "600");
1765                 v1 = cs_project(v_forward);
1766                 cvar_set("vid_conwidth", "640");
1767                 cvar_set("vid_conheight", "480");
1768                 v2 = cs_project(v_forward);
1769                 if(v1 == v2)
1770                         cs_project_is_b0rked = 1;
1771                 else
1772                         cs_project_is_b0rked = -1;
1773                 cvar_set("vid_conwidth", w0);
1774                 cvar_set("vid_conheight", h0);
1775         }
1776
1777         if(autocvar__hud_configure)
1778                 HUD_Panel_Mouse();
1779         if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
1780                 HUD_Minigame_Mouse();
1781
1782     if(hud && !intermission)
1783     {
1784         if(hud == HUD_SPIDERBOT)
1785             CSQC_SPIDER_HUD();
1786         else if(hud == HUD_WAKIZASHI)
1787             CSQC_WAKIZASHI_HUD();
1788         else if(hud == HUD_RAPTOR)
1789             CSQC_RAPTOR_HUD();
1790         else if(hud == HUD_BUMBLEBEE)
1791             CSQC_BUMBLE_HUD();
1792         else if(hud == HUD_BUMBLEBEE_GUN)
1793             CSQC_BUMBLE_GUN_HUD();
1794     }
1795
1796         cl_notice_run();
1797
1798         // let's reset the view back to normal for the end
1799         setproperty(VF_MIN, '0 0 0');
1800         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1801 }
1802
1803
1804 void CSQC_common_hud(void)
1805 {
1806         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1807                 Accuracy_LoadLevels();
1808
1809         HUD_Main(); // always run these functions for alpha checks
1810         HUD_DrawScoreboard();
1811
1812         if (scoreboard_active) // scoreboard/accuracy
1813                 HUD_Reset();
1814         else if (intermission == 2) // map voting screen
1815         {
1816                 MapVote_Draw();
1817                 HUD_Reset();
1818         }
1819 }
1820
1821
1822 // following vectors must be global to allow seamless switching between camera modes
1823 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1824 void CSQC_Demo_Camera()
1825 {
1826         float speed, attenuation, dimensions;
1827         vector tmp, delta;
1828
1829         if( autocvar_camera_reset || !camera_mode )
1830         {
1831                 camera_offset = '0 0 0';
1832                 current_angles = '0 0 0';
1833                 camera_direction = '0 0 0';
1834                 camera_offset.z += 30;
1835                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1836                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1837                 current_origin = view_origin;
1838                 current_camera_offset  = camera_offset;
1839                 cvar_set("camera_reset", "0");
1840                 camera_mode = CAMERA_CHASE;
1841         }
1842
1843         // Camera angles
1844         if( camera_roll )
1845                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1846
1847         if(autocvar_camera_look_player)
1848         {
1849                 vector dir;
1850                 float n;
1851
1852                 dir = normalize(view_origin - current_position);
1853                 n = mouse_angles.z;
1854                 mouse_angles = vectoangles(dir);
1855                 mouse_angles.x = mouse_angles.x * -1;
1856                 mouse_angles.z = n;
1857         }
1858         else
1859         {
1860                 tmp = getmousepos() * 0.1;
1861                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1862                 {
1863                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1864                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1865                 }
1866         }
1867
1868         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1869         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1870         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1871         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1872
1873         // Fix difference when angles don't have the same sign
1874         delta = '0 0 0';
1875         if(mouse_angles.y < -60 && current_angles.y > 60)
1876                 delta = '0 360 0';
1877         if(mouse_angles.y > 60 && current_angles.y < -60)
1878                 delta = '0 -360 0';
1879
1880         if(autocvar_camera_look_player)
1881                 attenuation = autocvar_camera_look_attenuation;
1882         else
1883                 attenuation = autocvar_camera_speed_attenuation;
1884
1885         attenuation = 1 / max(1, attenuation);
1886         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1887
1888         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1889         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1890         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1891         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1892
1893         // Camera position
1894         tmp = '0 0 0';
1895         dimensions = 0;
1896
1897         if( camera_direction.x )
1898         {
1899                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1900                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1901                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1902                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1903                 ++dimensions;
1904         }
1905
1906         if( camera_direction.y )
1907         {
1908                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1909                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1910                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1911                 ++dimensions;
1912         }
1913
1914         if( camera_direction.z )
1915         {
1916                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1917                 ++dimensions;
1918         }
1919
1920         if(autocvar_camera_free)
1921                 speed = autocvar_camera_speed_free;
1922         else
1923                 speed = autocvar_camera_speed_chase;
1924
1925         if(dimensions)
1926         {
1927                 speed = speed * sqrt(1 / dimensions);
1928                 camera_offset += tmp * speed;
1929         }
1930
1931         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1932
1933         // Camera modes
1934         if( autocvar_camera_free )
1935         {
1936                 if ( camera_mode == CAMERA_CHASE )
1937                 {
1938                         current_camera_offset = current_origin + current_camera_offset;
1939                         camera_offset = current_origin + camera_offset;
1940                 }
1941
1942                 camera_mode = CAMERA_FREE;
1943                 current_position = current_camera_offset;
1944         }
1945         else
1946         {
1947                 if ( camera_mode == CAMERA_FREE )
1948                 {
1949                         current_origin = view_origin;
1950                         camera_offset = camera_offset - current_origin;
1951                         current_camera_offset = current_camera_offset - current_origin;
1952                 }
1953
1954                 camera_mode = CAMERA_CHASE;
1955
1956                 if(autocvar_camera_chase_smoothly)
1957                         current_origin += (view_origin - current_origin) * attenuation;
1958                 else
1959                         current_origin = view_origin;
1960
1961                 current_position = current_origin + current_camera_offset;
1962         }
1963
1964         setproperty(VF_ANGLES, current_angles);
1965         setproperty(VF_ORIGIN, current_position);
1966 }