qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         HUD_Panel_GetName(i);
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  84                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  85                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  86                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  87                                         HUD_Write_PanelCvar_q("_onlyowned");
  88                                         break;
  89                                 case HUD_PANEL_AMMO:
  90                                         HUD_Write_PanelCvar_q("_onlycurrent");
  91                                         HUD_Write_PanelCvar_q("_iconalign");
  92                                         HUD_Write_PanelCvar_q("_progressbar");
  93                                         HUD_Write_PanelCvar_q("_progressbar_name");
  94                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  95                                         HUD_Write_PanelCvar_q("_text");
  96                                         break;
  97                                 case HUD_PANEL_POWERUPS:
  98                                         HUD_Write_PanelCvar_q("_flip");
  99                                         HUD_Write_PanelCvar_q("_iconalign");
 100                                         HUD_Write_PanelCvar_q("_baralign");
 101                                         HUD_Write_PanelCvar_q("_progressbar");
 102                                         HUD_Write_PanelCvar_q("_progressbar_strength");
 103                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 104                                         HUD_Write_PanelCvar_q("_text");
 105                                         break;
 106                                 case HUD_PANEL_HEALTHARMOR:
 107                                         HUD_Write_PanelCvar_q("_flip");
 108                                         HUD_Write_PanelCvar_q("_iconalign");
 109                                         HUD_Write_PanelCvar_q("_baralign");
 110                                         HUD_Write_PanelCvar_q("_progressbar");
 111                                         HUD_Write_PanelCvar_q("_progressbar_health");
 112                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 113                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 114                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 115                                         HUD_Write_PanelCvar_q("_text");
 116                                         break;
 117                                 case HUD_PANEL_NOTIFY:
 118                                         HUD_Write_PanelCvar_q("_flip");
 119                                         HUD_Write_PanelCvar_q("_fontsize");
 120                                         HUD_Write_PanelCvar_q("_time");
 121                                         HUD_Write_PanelCvar_q("_fadetime");
 122                                         break;
 123                                 case HUD_PANEL_TIMER:
 124                                         HUD_Write_PanelCvar_q("_increment");
 125                                         break;
 126                                 case HUD_PANEL_RADAR:
 127                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 128                                         HUD_Write_PanelCvar_q("_rotation");
 129                                         HUD_Write_PanelCvar_q("_zoommode");
 130                                         HUD_Write_PanelCvar_q("_scale");
 131                                         HUD_Write_PanelCvar_q("_maximized_scale");
 132                                         HUD_Write_PanelCvar_q("_maximized_size");
 133                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 134                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 135                                         break;
 136                                 case HUD_PANEL_SCORE:
 137                                         HUD_Write_PanelCvar_q("_rankings");
 138                                         break;
 139                                 case HUD_PANEL_VOTE:
 140                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 141                                         break;
 142                                 case HUD_PANEL_MODICONS:
 143                                         HUD_Write_PanelCvar_q("_dom_layout");
 144                                         break;
 145                                 case HUD_PANEL_PRESSEDKEYS:
 146                                         HUD_Write_PanelCvar_q("_aspect");
 147                                         HUD_Write_PanelCvar_q("_attack");
 148                                         break;
 149                                 case HUD_PANEL_ENGINEINFO:
 150                                         HUD_Write_PanelCvar_q("_framecounter_time");
 151                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 152                                         break;
 153                                 case HUD_PANEL_INFOMESSAGES:
 154                                         HUD_Write_PanelCvar_q("_flip");
 155                                         break;
 156                                 case HUD_PANEL_PHYSICS:
 157                                         HUD_Write_PanelCvar_q("_speed_unit");
 158                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 159                                         HUD_Write_PanelCvar_q("_speed_max");
 160                                         HUD_Write_PanelCvar_q("_speed_vertical");
 161                                         HUD_Write_PanelCvar_q("_topspeed");
 162                                         HUD_Write_PanelCvar_q("_topspeed_time");
 163                                         HUD_Write_PanelCvar_q("_acceleration_max");
 164                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 165                                         HUD_Write_PanelCvar_q("_flip");
 166                                         HUD_Write_PanelCvar_q("_baralign");
 167                                         HUD_Write_PanelCvar_q("_progressbar");
 168                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 169                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 170                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 171                                         HUD_Write_PanelCvar_q("_text");
 172                                         HUD_Write_PanelCvar_q("_text_scale");
 173                                         break;
 174                                 case HUD_PANEL_CENTERPRINT:
 175                                         HUD_Write_PanelCvar_q("_align");
 176                                         HUD_Write_PanelCvar_q("_flip");
 177                                         HUD_Write_PanelCvar_q("_fontscale");
 178                                         HUD_Write_PanelCvar_q("_time");
 179                                         HUD_Write_PanelCvar_q("_fade_in");
 180                                         HUD_Write_PanelCvar_q("_fade_out");
 181                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 182                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 183                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 184                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 185                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 186                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 187                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 188                                         break;
 189                                 case HUD_PANEL_ITEMSTIME:
 190                                         HUD_Write_PanelCvar_q("_iconalign");
 191                                         HUD_Write_PanelCvar_q("_progressbar");
 192                                         HUD_Write_PanelCvar_q("_progressbar_name");
 193                                         HUD_Write_PanelCvar_q("_progressbar_reduced");
 194                                         HUD_Write_PanelCvar_q("_showspawned");
 195                                         HUD_Write_PanelCvar_q("_text");
 196                                         HUD_Write_PanelCvar_q("_ratio");
 197                                         HUD_Write_PanelCvar_q("_size_dinamic");
 198                                         break;
 199                         }
 200                         HUD_Write("\n");
 201                 }
 202                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 203
 204                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 205                 fclose(fh);
 206         }
 207         else
 208                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 209 }
 210
 211 void HUD_Configure_Exit_Force()
 212 {
 213         if (menu_enabled)
 214         {
 215                 menu_enabled = 0;
 216                 localcmd("togglemenu\n");
 217         }
 218         cvar_set("_hud_configure", "0");
 219 }
 220
 221 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 222 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 223 {
 224         float i;
 225         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 226         vector myTarget;
 227         myTarget = myPos;
 228
 229         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 230                 if(i == highlightedPanel || !panel_enabled)
 231                         continue;
 232
 233                 HUD_Panel_UpdatePosSizeForId(i);
 234
 235                 panel_pos -= '1 1 0' * panel_bg_border;
 236                 panel_size += '2 2 0' * panel_bg_border;
 237
 238                 if(myPos_y + mySize_y < panel_pos_y)
 239                         continue;
 240                 if(myPos_y > panel_pos_y + panel_size_y)
 241                         continue;
 242
 243                 if(myPos_x + mySize_x < panel_pos_x)
 244                         continue;
 245                 if(myPos_x > panel_pos_x + panel_size_x)
 246                         continue;
 247
 248                 // OK, there IS a collision.
 249
 250                 myCenter_x = myPos_x + 0.5 * mySize_x;
 251                 myCenter_y = myPos_y + 0.5 * mySize_y;
 252
 253                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 254                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 255
 256                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 257                 {
 258                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 259                                 myTarget_x = panel_pos_x - mySize_x;
 260                         else // push it upwards
 261                                 myTarget_y = panel_pos_y - mySize_y;
 262                 }
 263                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 264                 {
 265                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 266                                 myTarget_x = panel_pos_x + panel_size_x;
 267                         else // push it upwards
 268                                 myTarget_y = panel_pos_y - mySize_y;
 269                 }
 270                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 271                 {
 272                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 273                                 myTarget_x = panel_pos_x - mySize_x;
 274                         else // push it downwards
 275                                 myTarget_y = panel_pos_y + panel_size_y;
 276                 }
 277                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 278                 {
 279                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 280                                 myTarget_x = panel_pos_x + panel_size_x;
 281                         else // push it downwards
 282                                 myTarget_y = panel_pos_y + panel_size_y;
 283                 }
 284                 //if(cvar("hud_configure_checkcollisions_debug"))
 285                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 286         }
 287
 288         return myTarget;
 289 }
 290
 291 void HUD_Panel_SetPos(vector pos)
 292 {
 293         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 294         vector mySize;
 295         mySize = panel_size;
 296
 297         //if(cvar("hud_configure_checkcollisions_debug"))
 298                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 299
 300         if(autocvar_hud_configure_grid)
 301         {
 302                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 303                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 304         }
 305
 306         if(hud_configure_checkcollisions)
 307                 pos = HUD_Panel_CheckMove(pos, mySize);
 308
 309         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 310         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 311
 312         string s;
 313         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 314
 315         HUD_Panel_GetName(highlightedPanel);
 316         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 317 }
 318
 319 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 320 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 321         float i;
 322
 323         vector targEndPos;
 324
 325         float dist_x, dist_y;
 326         float ratio;
 327         ratio = mySize_x/mySize_y;
 328
 329         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 330                 if(i == highlightedPanel || !panel_enabled)
 331                         continue;
 332
 333                 HUD_Panel_UpdatePosSizeForId(i);
 334
 335                 panel_pos -= '1 1 0' * panel_bg_border;
 336                 panel_size += '2 2 0' * panel_bg_border;
 337
 338                 targEndPos = panel_pos + panel_size;
 339
 340                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 341                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 342                         continue;
 343
 344                 if (resizeCorner == 1)
 345                 {
 346                         // check if this panel is on our way
 347                         if (resizeorigin_x <= panel_pos_x)
 348                                 continue;
 349                         if (resizeorigin_y <= panel_pos_y)
 350                                 continue;
 351                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 352                                 continue;
 353                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 354                                 continue;
 355
 356                         // there is a collision:
 357                         // detect which side of the panel we are facing is actually limiting the resizing
 358                         // (which side the resize direction finds for first) and reduce the size up to there
 359                         //
 360                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 361                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 362                         dist_x = resizeorigin_x - targEndPos_x;
 363                         dist_y = resizeorigin_y - targEndPos_y;
 364                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 365                                 mySize_x = min(mySize_x, dist_x);
 366                         else
 367                                 mySize_y = min(mySize_y, dist_y);
 368                 }
 369                 else if (resizeCorner == 2)
 370                 {
 371                         if (resizeorigin_x >= targEndPos_x)
 372                                 continue;
 373                         if (resizeorigin_y <= panel_pos_y)
 374                                 continue;
 375                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 376                                 continue;
 377                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 378                                 continue;
 379
 380                         dist_x = panel_pos_x - resizeorigin_x;
 381                         dist_y = resizeorigin_y - targEndPos_y;
 382                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 383                                 mySize_x = min(mySize_x, dist_x);
 384                         else
 385                                 mySize_y = min(mySize_y, dist_y);
 386                 }
 387                 else if (resizeCorner == 3)
 388                 {
 389                         if (resizeorigin_x <= panel_pos_x)
 390                                 continue;
 391                         if (resizeorigin_y >= targEndPos_y)
 392                                 continue;
 393                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 394                                 continue;
 395                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 396                                 continue;
 397
 398                         dist_x = resizeorigin_x - targEndPos_x;
 399                         dist_y = panel_pos_y - resizeorigin_y;
 400                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 401                                 mySize_x = min(mySize_x, dist_x);
 402                         else
 403                                 mySize_y = min(mySize_y, dist_y);
 404                 }
 405                 else if (resizeCorner == 4)
 406                 {
 407                         if (resizeorigin_x >= targEndPos_x)
 408                                 continue;
 409                         if (resizeorigin_y >= targEndPos_y)
 410                                 continue;
 411                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 412                                 continue;
 413                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 414                                 continue;
 415
 416                         dist_x = panel_pos_x - resizeorigin_x;
 417                         dist_y = panel_pos_y - resizeorigin_y;
 418                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 419                                 mySize_x = min(mySize_x, dist_x);
 420                         else
 421                                 mySize_y = min(mySize_y, dist_y);
 422                 }
 423                 //if(cvar("hud_configure_checkcollisions_debug"))
 424                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 425         }
 426
 427         return mySize;
 428 }
 429
 430 void HUD_Panel_SetPosSize(vector mySize)
 431 {
 432         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 433         vector resizeorigin;
 434         resizeorigin = panel_click_resizeorigin;
 435         local noref vector myPos; // fteqcc sucks
 436
 437         // minimum panel size cap
 438         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 439         mySize_y = max(0.025 * vid_conheight, mySize_y);
 440
 441         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 442         {
 443                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 444                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 445         }
 446
 447         // collision testing|
 448         // -----------------+
 449
 450         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 451         if(resizeCorner == 1) {
 452                 myPos_x = resizeorigin_x - mySize_x;
 453                 myPos_y = resizeorigin_y - mySize_y;
 454         } else if(resizeCorner == 2) {
 455                 myPos_x = resizeorigin_x;
 456                 myPos_y = resizeorigin_y - mySize_y;
 457         } else if(resizeCorner == 3) {
 458                 myPos_x = resizeorigin_x - mySize_x;
 459                 myPos_y = resizeorigin_y;
 460         } else { // resizeCorner == 4
 461                 myPos_x = resizeorigin_x;
 462                 myPos_y = resizeorigin_y;
 463         }
 464
 465         // left/top screen edges
 466         if(myPos_x < 0)
 467                 mySize_x = mySize_x + myPos_x;
 468         if(myPos_y < 0)
 469                 mySize_y = mySize_y + myPos_y;
 470
 471         // bottom/right screen edges
 472         if(myPos_x + mySize_x > vid_conwidth)
 473                 mySize_x = vid_conwidth - myPos_x;
 474         if(myPos_y + mySize_y > vid_conheight)
 475                 mySize_y = vid_conheight - myPos_y;
 476
 477         //if(cvar("hud_configure_checkcollisions_debug"))
 478                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 479
 480         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 481         if(autocvar_hud_configure_grid)
 482         {
 483                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 484                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 485         }
 486
 487         if(hud_configure_checkcollisions)
 488                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 489
 490         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 491         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 492         mySize_y = max(0.025 * vid_conheight, mySize_y);
 493
 494         // do another pos check, as size might have changed by now
 495         if(resizeCorner == 1) {
 496                 myPos_x = resizeorigin_x - mySize_x;
 497                 myPos_y = resizeorigin_y - mySize_y;
 498         } else if(resizeCorner == 2) {
 499                 myPos_x = resizeorigin_x;
 500                 myPos_y = resizeorigin_y - mySize_y;
 501         } else if(resizeCorner == 3) {
 502                 myPos_x = resizeorigin_x - mySize_x;
 503                 myPos_y = resizeorigin_y;
 504         } else { // resizeCorner == 4
 505                 myPos_x = resizeorigin_x;
 506                 myPos_y = resizeorigin_y;
 507         }
 508
 509         //if(cvar("hud_configure_checkcollisions_debug"))
 510                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 511
 512         HUD_Panel_GetName(highlightedPanel);
 513         string s;
 514         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 515         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 516
 517         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 518         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 519 }
 520
 521 float pressed_key_time;
 522 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 523 void HUD_Panel_Arrow_Action(float nPrimary)
 524 {
 525         if (highlightedPanel == -1)
 526                 return;
 527
 528         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 529
 530         float step;
 531         if(autocvar_hud_configure_grid)
 532         {
 533                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 534                 {
 535                         if (hudShiftState & S_SHIFT)
 536                                 step = hud_configure_realGridSize_y;
 537                         else
 538                                 step = 2 * hud_configure_realGridSize_y;
 539                 }
 540                 else
 541                 {
 542                         if (hudShiftState & S_SHIFT)
 543                                 step = hud_configure_realGridSize_x;
 544                         else
 545                                 step = 2 * hud_configure_realGridSize_x;
 546                 }
 547         }
 548         else
 549         {
 550                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 551                         step = vid_conheight;
 552                 else
 553                         step = vid_conwidth;
 554                 if (hudShiftState & S_SHIFT)
 555                         step = (step / 256); // more precision
 556                 else
 557                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 558         }
 559
 560         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 561
 562         highlightedPanel_initial_pos = panel_pos;
 563         highlightedPanel_initial_size = panel_size;
 564
 565         if (hudShiftState & S_ALT) // resize
 566         {
 567                 highlightedAction = 1;
 568                 if(nPrimary == K_UPARROW)
 569                         resizeCorner = 1;
 570                 else if(nPrimary == K_RIGHTARROW)
 571                         resizeCorner = 2;
 572                 else if(nPrimary == K_LEFTARROW)
 573                         resizeCorner = 3;
 574                 else // if(nPrimary == K_DOWNARROW)
 575                         resizeCorner = 4;
 576
 577                 // ctrl+arrow reduces the size, instead of increasing it
 578                 // Note that ctrl disables collisions check too, but it's fine
 579                 // since we don't collide with anything reducing the size
 580                 if (hudShiftState & S_CTRL) {
 581                         step = -step;
 582                         resizeCorner = 5 - resizeCorner;
 583                 }
 584
 585                 vector mySize;
 586                 mySize = panel_size;
 587                 panel_click_resizeorigin = panel_pos;
 588                 if(resizeCorner == 1) {
 589                         panel_click_resizeorigin += mySize;
 590                         mySize_y += step;
 591                 } else if(resizeCorner == 2) {
 592                         panel_click_resizeorigin_y += mySize_y;
 593                         mySize_x += step;
 594                 } else if(resizeCorner == 3) {
 595                         panel_click_resizeorigin_x += mySize_x;
 596                         mySize_x += step;
 597                 } else { // resizeCorner == 4
 598                         mySize_y += step;
 599                 }
 600                 HUD_Panel_SetPosSize(mySize);
 601         }
 602         else // move
 603         {
 604                 highlightedAction = 2;
 605                 vector pos;
 606                 pos = panel_pos;
 607                 if(nPrimary == K_UPARROW)
 608                         pos_y -= step;
 609                 else if(nPrimary == K_DOWNARROW)
 610                         pos_y += step;
 611                 else if(nPrimary == K_LEFTARROW)
 612                         pos_x -= step;
 613                 else // if(nPrimary == K_RIGHTARROW)
 614                         pos_x += step;
 615
 616                 HUD_Panel_SetPos(pos);
 617         }
 618
 619         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 620
 621         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 622         {
 623                 // backup!
 624                 panel_pos_backup = highlightedPanel_initial_pos;
 625                 panel_size_backup = highlightedPanel_initial_size;
 626                 highlightedPanel_backup = highlightedPanel;
 627         }
 628 }
 629
 630 const float S_MOUSE1 = 1;
 631 const float S_MOUSE2 = 2;
 632 const float S_MOUSE3 = 4;
 633 float mouseClicked;
 634 float prevMouseClicked; // previous state
 635 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 636 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 637
 638 void HUD_Panel_EnableMenu();
 639 float tab_panels[HUD_PANEL_NUM];
 640 float tab_panel, tab_backward;
 641 vector tab_panel_pos;
 642 void HUD_Panel_FirstInDrawQ(float id);
 643 void reset_tab_panels()
 644 {
 645         int i;
 646         for(i = 0; i < HUD_PANEL_NUM; ++i)
 647                 tab_panels[i] = -1;
 648 }
 649 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 650 {
 651         string s;
 652
 653         if(bInputType == 2)
 654                 return false;
 655
 656         if(!autocvar__hud_configure)
 657                 return false;
 658
 659         // block any input while a menu dialog is fading
 660         if(autocvar__menu_alpha)
 661                 return true;
 662
 663         if(bInputType == 3)
 664         {
 665                 mousepos_x = nPrimary;
 666                 mousepos_y = nSecondary;
 667                 return true;
 668         }
 669
 670         // allow console bind to work
 671         string con_keys;
 672         float keys;
 673         con_keys = findkeysforcommand("toggleconsole", 0);
 674         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 675
 676         float hit_con_bind = 0, i;
 677         for (i = 0; i < keys; ++i)
 678         {
 679                 if(nPrimary == stof(argv(i)))
 680                         hit_con_bind = 1;
 681         }
 682
 683         if(bInputType == 0) {
 684                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 685                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 686                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 687         }
 688         else if(bInputType == 1) {
 689                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 690                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 691                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 692         }
 693
 694         if(nPrimary == K_CTRL)
 695         {
 696                 if (bInputType == 1) //ctrl has been released
 697                 {
 698                         if (tab_panel != -1)
 699                         {
 700                                 //switch to selected panel
 701                                 highlightedPanel = tab_panel;
 702                                 highlightedAction = 0;
 703                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
 704                         }
 705                         tab_panel = -1;
 706                         reset_tab_panels();
 707                 }
 708         }
 709
 710         if(nPrimary == K_MOUSE1)
 711         {
 712                 if(bInputType == 0) // key pressed
 713                         mouseClicked |= S_MOUSE1;
 714                 else if(bInputType == 1) // key released
 715                         mouseClicked -= (mouseClicked & S_MOUSE1);
 716         }
 717         else if(nPrimary == K_MOUSE2)
 718         {
 719                 if(bInputType == 0) // key pressed
 720                         mouseClicked |= S_MOUSE2;
 721                 else if(bInputType == 1) // key released
 722                         mouseClicked -= (mouseClicked & S_MOUSE2);
 723         }
 724         else if(nPrimary == K_ESCAPE)
 725         {
 726                 if (bInputType == 1)
 727                         return true;
 728                 menu_enabled = 1;
 729                 menu_enabled_time = time;
 730                 localcmd("menu_showhudexit\n");
 731         }
 732         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 733         {
 734                 if (bInputType == 1)
 735                         return true;
 736                 if (!menu_enabled)
 737                         cvar_set("_hud_configure", "0");
 738         }
 739         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 740         {
 741                 if (bInputType == 1 || mouseClicked)
 742                         return true;
 743
 744                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 745                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 746                 //(it should only after every other panel of the hud)
 747                 //It's a minor bug anyway, we can live with it
 748
 749                 float starting_panel;
 750                 float old_tab_panel = tab_panel;
 751                 if (tab_panel == -1) //first press of TAB
 752                 {
 753                         if (highlightedPanel != -1)
 754                                 HUD_Panel_UpdatePosSizeForId(highlightedPanel)
 755                         else
 756                                 panel_pos = '0 0 0';
 757                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
 758                         tab_panel_pos = panel_pos; //to compute level
 759                 }
 760                 else
 761                 {
 762                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 763                                 reset_tab_panels();
 764                         starting_panel = tab_panel;
 765                 }
 766                 tab_backward = (hudShiftState & S_SHIFT);
 767
 768                 float k, level = 0, start_pos_x;
 769                 vector candidate_pos = '0 0 0';
 770                 const float LEVELS_NUM = 4;
 771                 float level_height = vid_conheight / LEVELS_NUM;
 772 :find_tab_panel
 773                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 774                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 775                 start_pos_x = tab_panel_pos_x;
 776                 tab_panel = -1;
 777                 k=0;
 778                 while(++k)
 779                 {
 780                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 781                         {
 782                                 if (i == tab_panels[i] || i == starting_panel)
 783                                         continue;
 784                                 HUD_Panel_UpdatePosSizeForId(i)
 785                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 786                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 787                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 788                                 {
 789                                         tab_panel = i;
 790                                         tab_panel_pos = candidate_pos = panel_pos;
 791                                 }
 792                         }
 793                         if (tab_panel != -1)
 794                                 break;
 795                         if (k == LEVELS_NUM) //tab_panel not found
 796                         {
 797                                 reset_tab_panels();
 798                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
 799                                 {
 800                                         tab_panel = -1;
 801                                         return true;
 802                                 }
 803                                 starting_panel = old_tab_panel;
 804                                 old_tab_panel = -2;
 805                                 goto find_tab_panel; //u must find tab_panel!
 806                         }
 807                         if (!tab_backward)
 808                         {
 809                                 level = mod(level + level_height, vid_conheight);
 810                                 start_pos_x = 0;
 811                                 candidate_pos_x = vid_conwidth;
 812                         }
 813                         else
 814                         {
 815                                 level = mod(level - level_height, vid_conheight);
 816                                 start_pos_x = vid_conwidth;
 817                                 candidate_pos_x = 0;
 818                         }
 819                 }
 820
 821                 tab_panels[tab_panel] = tab_panel;
 822         }
 823         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 824         {
 825                 if (bInputType == 1 || mouseClicked)
 826                         return true;
 827
 828                 if (highlightedPanel != -1)
 829                 {
 830                         HUD_Panel_GetName(highlightedPanel);
 831                         cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
 832                 }
 833                 else
 834                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 835         }
 836         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 837         {
 838                 if (bInputType == 1 || mouseClicked)
 839                         return true;
 840
 841                 if (highlightedPanel != -1)
 842                 {
 843                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 844                         panel_size_copied = panel_size;
 845                         highlightedPanel_copied = highlightedPanel;
 846                 }
 847         }
 848         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 849         {
 850                 if (bInputType == 1 || mouseClicked)
 851                         return true;
 852
 853                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
 854                         return true;
 855
 856                 HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 857
 858                 // reduce size if it'd go beyond screen boundaries
 859                 vector tmp_size = panel_size_copied;
 860                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 861                         tmp_size_x = vid_conwidth - panel_pos_x;
 862                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 863                         tmp_size_y = vid_conheight - panel_pos_y;
 864
 865                 if (panel_size == tmp_size)
 866                         return true;
 867
 868                 // backup first!
 869                 panel_pos_backup = panel_pos;
 870                 panel_size_backup = panel_size;
 871                 highlightedPanel_backup = highlightedPanel;
 872
 873                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 874                 HUD_Panel_GetName(highlightedPanel);
 875                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 876         }
 877         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 878         {
 879                 if (bInputType == 1 || mouseClicked)
 880                         return true;
 881                 //restore previous values
 882                 if (highlightedPanel_backup != -1)
 883                 {
 884                         HUD_Panel_GetName(highlightedPanel_backup);
 885                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 886                         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 887                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 888                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 889                         highlightedPanel_backup = -1;
 890                 }
 891         }
 892         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 893         {
 894                 if (bInputType == 1)
 895                 {
 896                         pressed_key_time = 0;
 897                         return true;
 898                 }
 899                 else if (pressed_key_time == 0)
 900                         pressed_key_time = time;
 901
 902                 if (!mouseClicked)
 903                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 904         }
 905         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 906         {
 907                 if (bInputType == 1)
 908                         return true;
 909                 if (highlightedPanel != -1)
 910                         HUD_Panel_EnableMenu();
 911         }
 912         else if(hit_con_bind)
 913                 return false;
 914
 915         return true;
 916 }
 917
 918 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 919 {
 920         float i, j = 0, border;
 921
 922         while(j < HUD_PANEL_NUM)
 923         {
 924                 i = panel_order[j];
 925                 j += 1;
 926
 927                 HUD_Panel_UpdatePosSizeForId(i);
 928
 929                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 930
 931                 // move
 932                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
 933                 {
 934                         return 1;
 935                 }
 936                 // resize from topleft border
 937                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 938                 {
 939                         return 2;
 940                 }
 941                 // resize from topright border
 942                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 943                 {
 944                         return 3;
 945                 }
 946                 // resize from bottomleft border
 947                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 948                 {
 949                         return 3;
 950                 }
 951                 // resize from bottomright border
 952                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 953                 {
 954                         return 2;
 955                 }
 956         }
 957         return 0;
 958 }
 959
 960 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 961 void HUD_Panel_FirstInDrawQ(float id)
 962 {
 963         float i;
 964         var float place = -1;
 965         // find out where in the array our current id is, save into place
 966         for(i = 0; i < HUD_PANEL_NUM; ++i)
 967         {
 968                 if(panel_order[i] == id)
 969                 {
 970                         place = i;
 971                         break;
 972                 }
 973         }
 974         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 975         if(place == -1)
 976                 place = HUD_PANEL_NUM - 1;
 977
 978         // move all ids up by one step in the array until "place"
 979         for(i = place; i > 0; --i)
 980         {
 981                 panel_order[i] = panel_order[i-1];
 982         }
 983         // now save the new top id
 984         panel_order[0] = id;
 985
 986         // let's save them into the cvar by some strcat trickery
 987         string s = "";
 988         for(i = 0; i < HUD_PANEL_NUM; ++i)
 989         {
 990                 s = strcat(s, ftos(panel_order[i]), " ");
 991         }
 992         cvar_set("_hud_panelorder", s);
 993         if(hud_panelorder_prev)
 994                 strunzone(hud_panelorder_prev);
 995         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 996 }
 997
 998 void HUD_Panel_Highlight(float allow_move)
 999 {
1000         float i, j = 0, border;
1001
1002         while(j < HUD_PANEL_NUM)
1003         {
1004                 i = panel_order[j];
1005                 j += 1;
1006
1007                 HUD_Panel_UpdatePosSizeForId(i);
1008
1009                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1010
1011                 // move
1012                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
1013                 {
1014                         highlightedPanel = i;
1015                         HUD_Panel_FirstInDrawQ(i);
1016                         highlightedAction = 1;
1017                         panel_click_distance = mousepos - panel_pos;
1018                         return;
1019                 }
1020                 // resize from topleft border
1021                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1022                 {
1023                         highlightedPanel = i;
1024                         HUD_Panel_FirstInDrawQ(i);
1025                         highlightedAction = 2;
1026                         resizeCorner = 1;
1027                         panel_click_distance = mousepos - panel_pos;
1028                         panel_click_resizeorigin = panel_pos + panel_size;
1029                         return;
1030                 }
1031                 // resize from topright border
1032                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1033                 {
1034                         highlightedPanel = i;
1035                         HUD_Panel_FirstInDrawQ(i);
1036                         highlightedAction = 2;
1037                         resizeCorner = 2;
1038                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1039                         panel_click_distance_y = mousepos_y - panel_pos_y;
1040                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1041                         return;
1042                 }
1043                 // resize from bottomleft border
1044                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1045                 {
1046                         highlightedPanel = i;
1047                         HUD_Panel_FirstInDrawQ(i);
1048                         highlightedAction = 2;
1049                         resizeCorner = 3;
1050                         panel_click_distance_x = mousepos_x - panel_pos_x;
1051                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1052                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1053                         return;
1054                 }
1055                 // resize from bottomright border
1056                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1057                 {
1058                         highlightedPanel = i;
1059                         HUD_Panel_FirstInDrawQ(i);
1060                         highlightedAction = 2;
1061                         resizeCorner = 4;
1062                         panel_click_distance = panel_size - mousepos + panel_pos;
1063                         panel_click_resizeorigin = panel_pos;
1064                         return;
1065                 }
1066         }
1067         highlightedPanel = -1;
1068         highlightedAction = 0;
1069 }
1070
1071 void HUD_Panel_EnableMenu()
1072 {
1073         menu_enabled = 2;
1074         menu_enabled_time = time;
1075         HUD_Panel_GetName(highlightedPanel);
1076         localcmd("menu_showhudoptions ", panel_name, "\n");
1077 }
1078 float mouse_over_panel;
1079 void HUD_Panel_Mouse()
1080 {
1081         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1082         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1083                 menu_enabled = 0;
1084
1085         /*
1086         print("menu_enabled: ", ftos(menu_enabled), "\n");
1087         print("Highlighted: ", ftos(highlightedPanel), "\n");
1088         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1089         */
1090
1091         if(autocvar__menu_alpha == 1)
1092                 return;
1093
1094         if not(autocvar_hud_cursormode)
1095         {
1096                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1097
1098                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
1099                 mousepos_y = bound(0, mousepos_y, vid_conheight);
1100         }
1101
1102         if(mouseClicked)
1103         {
1104                 if(prevMouseClicked == 0)
1105                 {
1106                         if (tab_panel != -1)
1107                         {
1108                                 //stop ctrl-tab selection
1109                                 tab_panel = -1;
1110                                 reset_tab_panels();
1111                         }
1112                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1113                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1114                         if (highlightedPanel != -1)
1115                         {
1116                                 highlightedPanel_initial_pos = panel_pos;
1117                                 highlightedPanel_initial_size = panel_size;
1118                         }
1119                         // doubleclick check
1120                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1121                         {
1122                                 mouseClicked = 0; // to prevent spam, I guess.
1123                                 HUD_Panel_EnableMenu();
1124                         }
1125                         else
1126                         {
1127                                 if (mouseClicked & S_MOUSE1)
1128                                 {
1129                                         prevMouseClickedTime = time;
1130                                         prevMouseClickedPos = mousepos;
1131                                 }
1132                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1133                         }
1134                 }
1135                 else
1136                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1137
1138                 if (highlightedPanel != -1)
1139                 {
1140                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1141                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1142                         {
1143                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1144                                 // backup!
1145                                 panel_pos_backup = highlightedPanel_initial_pos;
1146                                 panel_size_backup = highlightedPanel_initial_size;
1147                                 highlightedPanel_backup = highlightedPanel;
1148                         }
1149                         else
1150                                 // in case the clicked panel is inside another panel and we aren't
1151                                 // moving it, avoid the immediate "fix" of its position/size
1152                                 // (often unwanted and hateful) by disabling collisions check
1153                                 hud_configure_checkcollisions = false;
1154                 }
1155
1156                 if(highlightedAction == 1)
1157                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1158                 else if(highlightedAction == 2)
1159                 {
1160                         vector mySize = '0 0 0';
1161                         if(resizeCorner == 1) {
1162                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1163                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1164                         } else if(resizeCorner == 2) {
1165                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1166                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1167                         } else if(resizeCorner == 3) {
1168                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1169                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1170                         } else { // resizeCorner == 4
1171                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1172                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1173                         }
1174                         HUD_Panel_SetPosSize(mySize);
1175                 }
1176         }
1177         else
1178         {
1179                 if(menu_enabled == 2)
1180                         mouse_over_panel = 0;
1181                 else
1182                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1183                 if (mouse_over_panel && tab_panel == -1)
1184                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1185         }
1186         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1187         const vector cursorsize = '32 32 0';
1188         float cursor_alpha = 1 - autocvar__menu_alpha;
1189
1190         if(!mouse_over_panel)
1191                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1192         else if(mouse_over_panel == 1)
1193                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1194         else if(mouse_over_panel == 2)
1195                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1196         else
1197                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1198
1199         prevMouseClicked = mouseClicked;
1200 }
1201
1202 const float hlBorderSize = 4;
1203 const string hlBorder = "gfx/hud/default/border_highlighted";
1204 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1205 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1206 {
1207         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1208         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1209         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1210         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1211         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1212 }