qcsrc/client/hud.qc

   1 /*
   2 ==================
   3 Misc HUD functions
   4 ==================
   5 */
   6
   7 // a border picture is a texture containing nine parts:
   8 //   1/4 width: left part
   9 //   1/2 width: middle part (stretched)
  10 //   1/4 width: right part
  11 // divided into
  12 //   1/4 height: top part
  13 //   1/2 height: middle part (stretched)
  14 //   1/4 height: bottom part
  15 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  16 {
  17     if (theBorderSize_x < 0 && theBorderSize_y < 0) // draw whole image as it is
  18     {
  19                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  20                 return;
  21     }
  22         if (theBorderSize_x == 0 && theBorderSize_y == 0) // no border
  23         {
  24                 // draw only the central part
  25                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  26                 return;
  27         }
  28
  29         vector dX, dY;
  30         vector width, height;
  31         vector bW, bH;
  32         //pic = draw_UseSkinFor(pic);
  33         width = eX * theSize_x;
  34         height = eY * theSize_y;
  35         if(theSize_x <= theBorderSize_x * 2)
  36         {
  37                 // not wide enough... draw just left and right then
  38                 bW = eX * (0.25 * theSize_x / (theBorderSize_x * 2));
  39                 if(theSize_y <= theBorderSize_y * 2)
  40                 {
  41                         // not high enough... draw just corners
  42                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  43                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  44                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  45                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  46                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  47                 }
  48                 else
  49                 {
  50                         dY = theBorderSize_x * eY;
  51                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  52                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  53                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  54                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  55                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  56                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  57                 }
  58         }
  59         else
  60         {
  61                 if(theSize_y <= theBorderSize_y * 2)
  62                 {
  63                         // not high enough... draw just top and bottom then
  64                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  65                         dX = theBorderSize_x * eX;
  66                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  67                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  68                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  69                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  70                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  71                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  72                 }
  73                 else
  74                 {
  75                         dX = theBorderSize_x * eX;
  76                         dY = theBorderSize_x * eY;
  77                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  78                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
  79                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  80                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  81                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
  82                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  83                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  84                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
  85                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  86                 }
  87         }
  88 }
  89
  90 vector HUD_Get_Num_Color (float x, float maxvalue)
  91 {
  92         float blinkingamt;
  93         vector color;
  94         if(x >= maxvalue) {
  95                 color_x = sin(2*M_PI*time);
  96                 color_y = 1;
  97                 color_z = sin(2*M_PI*time);
  98         }
  99         else if(x > maxvalue * 0.75) {
 100                 color_x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 101                 color_y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 102                 color_z = 0;
 103         }
 104         else if(x > maxvalue * 0.5) {
 105                 color_x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 106                 color_y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 107                 color_z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 108         }
 109         else if(x > maxvalue * 0.25) {
 110                 color_x = 1;
 111                 color_y = 1;
 112                 color_z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 113         }
 114         else if(x > maxvalue * 0.1) {
 115                 color_x = 1;
 116                 color_y = (x-20)*90/27/100; // green value between 0 -> 1
 117                 color_z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 118         }
 119         else {
 120                 color_x = 1;
 121                 color_y = 0;
 122                 color_z = 0;
 123         }
 124
 125         blinkingamt = (1 - x/maxvalue/0.25);
 126         if(blinkingamt > 0)
 127         {
 128                 color_x = color_x - color_x * blinkingamt * sin(2*M_PI*time);
 129                 color_y = color_y - color_y * blinkingamt * sin(2*M_PI*time);
 130                 color_z = color_z - color_z * blinkingamt * sin(2*M_PI*time);
 131         }
 132         return color;
 133 }
 134
 135 float stringwidth_colors(string s, vector theSize)
 136 {
 137         return stringwidth(s, TRUE, theSize);
 138 }
 139
 140 float stringwidth_nocolors(string s, vector theSize)
 141 {
 142         return stringwidth(s, FALSE, theSize);
 143 }
 144
 145 void drawstringright(vector position, string text, vector scale, vector rgb, float theAlpha, float flag)
 146 {
 147         position_x -= 2 / 3 * strlen(text) * scale_x;
 148         drawstring(position, text, scale, rgb, theAlpha, flag);
 149 }
 150
 151 void drawstringcenter(vector position, string text, vector scale, vector rgb, float theAlpha, float flag)
 152 {
 153         position_x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * scale_x);
 154         drawstring(position, text, scale, rgb, theAlpha, flag);
 155 }
 156
 157 // return the string of the onscreen race timer
 158 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
 159 {
 160         string col;
 161         string timestr;
 162         string cpname;
 163         string lapstr;
 164         lapstr = "";
 165
 166         if(histime == 0) // goal hit
 167         {
 168                 if(mytime > 0)
 169                 {
 170                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 171                         col = "^1";
 172                 }
 173                 else if(mytime == 0)
 174                 {
 175                         timestr = "+0.0";
 176                         col = "^3";
 177                 }
 178                 else
 179                 {
 180                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 181                         col = "^2";
 182                 }
 183
 184                 if(lapdelta > 0)
 185                 {
 186                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 187                         col = "^2";
 188                 }
 189                 else if(lapdelta < 0)
 190                 {
 191                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 192                         col = "^1";
 193                 }
 194         }
 195         else if(histime > 0) // anticipation
 196         {
 197                 if(mytime >= histime)
 198                         timestr = strcat("+", ftos_decimals(mytime - histime, TIME_DECIMALS));
 199                 else
 200                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(histime));
 201                 col = "^3";
 202         }
 203         else
 204         {
 205                 col = "^7";
 206                 timestr = "";
 207         }
 208
 209         if(cp == 254)
 210                 cpname = _("Start line");
 211         else if(cp == 255)
 212                 cpname = _("Finish line");
 213         else if(cp)
 214                 cpname = sprintf(_("Intermediate %d"), cp);
 215         else
 216                 cpname = _("Finish line");
 217
 218         if(histime < 0)
 219                 return strcat(col, cpname);
 220         else if(hisname == "")
 221                 return strcat(col, sprintf(_("%s (%s)"), cpname, timestr));
 222         else
 223                 return strcat(col, sprintf(_("%s (%s %s)"), cpname, timestr, strcat(hisname, col, lapstr)));
 224 }
 225
 226 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 227 float race_CheckName(string net_name) {
 228         float i;
 229         for (i=RANKINGS_CNT-1;i>=0;--i)
 230                 if(grecordholder[i] == net_name)
 231                         return i+1;
 232         return 0;
 233 }
 234
 235 float GetPlayerColorForce(float i)
 236 {
 237         if(!teamplay)
 238                 return 0;
 239         else
 240                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 241 }
 242
 243 float GetPlayerColor(float i)
 244 {
 245         if not(playerslots[i].gotscores) // unconnected
 246                 return NUM_SPECTATOR;
 247         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 248                 return NUM_SPECTATOR;
 249         else
 250                 return GetPlayerColorForce(i);
 251 }
 252
 253 string GetPlayerName(float i)
 254 {
 255         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 256 }
 257
 258
 259 /*
 260 ==================
 261 HUD panels
 262 ==================
 263 */
 264
 265 // draw the background/borders
 266 #define HUD_Panel_DrawBg(theAlpha)\
 267 if(panel_bg != "0")\
 268         draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER))
 269
 270 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 271 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, float vertical, float baralign, vector theColor, float theAlpha, float drawflag)
 272 {
 273         if(!length_ratio || !theAlpha)
 274                 return;
 275         if(length_ratio > 1)
 276                 length_ratio = 1;
 277         if (baralign == 3)
 278         {
 279                 if(length_ratio < -1)
 280                         length_ratio = -1;
 281         }
 282         else if(length_ratio < 0)
 283                 return;
 284
 285         vector square;
 286         vector width, height;
 287         if(vertical) {
 288                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 289                 if(precache_pic(pic) == "") {
 290                         pic = "gfx/hud/default/progressbar_vertical";
 291                 }
 292
 293         if (baralign == 1) // bottom align
 294                         theOrigin_y += (1 - length_ratio) * theSize_y;
 295         else if (baralign == 2) // center align
 296             theOrigin_y += 0.5 * (1 - length_ratio) * theSize_y;
 297         else if (baralign == 3) // center align, positive values down, negative up
 298                 {
 299                         theSize_y *= 0.5;
 300                         if (length_ratio > 0)
 301                                 theOrigin_y += theSize_y;
 302                         else
 303                         {
 304                                 theOrigin_y += (1 + length_ratio) * theSize_y;
 305                                 length_ratio = -length_ratio;
 306                         }
 307                 }
 308                 theSize_y *= length_ratio;
 309
 310                 vector bH;
 311                 width = eX * theSize_x;
 312                 height = eY * theSize_y;
 313                 if(theSize_y <= theSize_x * 2)
 314                 {
 315                         // button not high enough
 316                         // draw just upper and lower part then
 317                         square = eY * theSize_y * 0.5;
 318                         bH = eY * (0.25 * theSize_y / (theSize_x * 2));
 319                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 320                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 321                 }
 322                 else
 323                 {
 324                         square = eY * theSize_x;
 325                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 326                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 327                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 328                 }
 329         } else {
 330                 pic = strcat(hud_skin_path, "/", pic);
 331                 if(precache_pic(pic) == "") {
 332                         pic = "gfx/hud/default/progressbar";
 333                 }
 334
 335                 if (baralign == 1) // right align
 336                         theOrigin_x += (1 - length_ratio) * theSize_x;
 337         else if (baralign == 2) // center align
 338             theOrigin_x += 0.5 * (1 - length_ratio) * theSize_x;
 339         else if (baralign == 3) // center align, positive values on the right, negative on the left
 340                 {
 341                         theSize_x *= 0.5;
 342                         if (length_ratio > 0)
 343                                 theOrigin_x += theSize_x;
 344                         else
 345                         {
 346                                 theOrigin_x += (1 + length_ratio) * theSize_x;
 347                                 length_ratio = -length_ratio;
 348                         }
 349                 }
 350                 theSize_x *= length_ratio;
 351
 352                 vector bW;
 353                 width = eX * theSize_x;
 354                 height = eY * theSize_y;
 355                 if(theSize_x <= theSize_y * 2)
 356                 {
 357                         // button not wide enough
 358                         // draw just left and right part then
 359                         square = eX * theSize_x * 0.5;
 360                         bW = eX * (0.25 * theSize_x / (theSize_y * 2));
 361                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 362                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 363                 }
 364                 else
 365                 {
 366                         square = eX * theSize_y;
 367                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 368                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 369                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 370                 }
 371         }
 372 }
 373
 374 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, float drawflag)
 375 {
 376         if(!theAlpha)
 377                 return;
 378
 379         string pic;
 380         pic = strcat(hud_skin_path, "/num_leading");
 381         if(precache_pic(pic) == "") {
 382                 pic = "gfx/hud/default/num_leading";
 383         }
 384
 385         drawsubpic(pos, eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 386         if(mySize_x/mySize_y > 2)
 387                 drawsubpic(pos + eX * mySize_y, eX * (mySize_x - 2 * mySize_y) + eY * mySize_y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 388         drawsubpic(pos + eX * mySize_x - eX * min(mySize_x * 0.5, mySize_y), eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 389 }
 390
 391 // Weapon icons (#0)
 392 //
 393 entity weaponorder[WEP_MAXCOUNT];
 394 void weaponorder_swap(float i, float j, entity pass)
 395 {
 396         entity h;
 397         h = weaponorder[i];
 398         weaponorder[i] = weaponorder[j];
 399         weaponorder[j] = h;
 400 }
 401
 402 string weaponorder_cmp_str;
 403 float weaponorder_cmp(float i, float j, entity pass)
 404 {
 405         float ai, aj;
 406         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 407         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 408         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 409 }
 410
 411 float GetAmmoStat(float i)
 412 {
 413         switch(i)
 414         {
 415                 case 0: return STAT_SHELLS;
 416                 case 1: return STAT_NAILS;
 417                 case 2: return STAT_ROCKETS;
 418                 case 3: return STAT_CELLS;
 419                 case 4: return STAT_FUEL;
 420                 default: return -1;
 421         }
 422 }
 423
 424 float GetAmmoTypeForWep(float i)
 425 {
 426         switch(i)
 427         {
 428                 case WEP_SHOTGUN: return 0;
 429                 case WEP_UZI: return 1;
 430                 case WEP_GRENADE_LAUNCHER: return 2;
 431                 case WEP_MINE_LAYER: return 2;
 432                 case WEP_ELECTRO: return 3;
 433                 case WEP_CRYLINK: return 3;
 434                 case WEP_HLAC: return 3;
 435                 case WEP_MINSTANEX: return 3;
 436                 case WEP_NEX: return 3;
 437                 case WEP_RIFLE: return 1;
 438                 case WEP_HAGAR: return 2;
 439                 case WEP_ROCKET_LAUNCHER: return 2;
 440                 case WEP_SEEKER: return 2;
 441                 case WEP_FIREBALL: return 4;
 442                 case WEP_HOOK: return 3;
 443                 default: return -1;
 444         }
 445 }
 446
 447 void HUD_Weapons(void)
 448 {
 449         // declarations
 450         WEPSET_DECLARE_A(weapons_stat);
 451         WEPSET_COPY_AS(weapons_stat);
 452         float i, f, a;
 453         float screen_ar, center_x = 0, center_y;
 454         float weapon_count, weapon_id;
 455         float row, column, rows = 0, columns;
 456         float aspect = autocvar_hud_panel_weapons_aspect;
 457
 458         float panel_weapon_accuracy;
 459
 460         float timeout = autocvar_hud_panel_weapons_timeout;
 461         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 462         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 463
 464         float ammo_type, ammo_full;
 465         float barsize_x = 0, barsize_y = 0, baroffset_x = 0, baroffset_y = 0;
 466         vector ammo_color = '1 0 1';
 467         float ammo_alpha = 1;
 468
 469         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 470         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 471
 472         vector weapon_pos, weapon_size = '0 0 0';
 473         local noref vector old_panel_size; // fteqcc sucks
 474         vector color;
 475
 476         // check to see if we want to continue
 477         if(hud != HUD_NORMAL) { return; }
 478
 479         if(!autocvar__hud_configure)
 480         {
 481                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 482                         return;
 483                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 484                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 485                 {
 486                         weaponprevtime = time;
 487                         return;
 488                 }
 489         }
 490
 491         // update generic hud functions
 492         HUD_Panel_UpdateCvars();
 493         HUD_Panel_ApplyFadeAlpha();
 494
 495         draw_beginBoldFont();
 496
 497         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 498         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 499         {
 500                 float weapon_cnt;
 501                 if(weaponorder_bypriority)
 502                         strunzone(weaponorder_bypriority);
 503                 if(weaponorder_byimpulse)
 504                         strunzone(weaponorder_byimpulse);
 505
 506                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 507                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 508                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 509
 510                 weapon_cnt = 0;
 511                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 512                 {
 513                         self = get_weaponinfo(i);
 514                         if(self.impulse >= 0)
 515                         {
 516                                 weaponorder[weapon_cnt] = self;
 517                                 ++weapon_cnt;
 518                         }
 519                 }
 520                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 521                         weaponorder[i] = world;
 522                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 523
 524                 weaponorder_cmp_str = string_null;
 525         }
 526
 527         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 528                 complain_weapon = 0;
 529
 530         // determine which weapons are going to be shown
 531         if (autocvar_hud_panel_weapons_onlyowned)
 532         {
 533                 if(autocvar__hud_configure)
 534                 {
 535                         if (WEPSET_EMPTY_A(weapons_stat))
 536                                 for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 537                                         WEPSET_OR_AW(weapons_stat, i);
 538
 539                         if(menu_enabled != 2)
 540                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 541                 }
 542
 543                 // do we own this weapon?
 544                 weapon_count = 0;
 545                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 546                         if(WEPSET_CONTAINS_AW(weapons_stat, weaponorder[i].weapon))
 547                                 ++weapon_count;
 548
 549                 // add it anyway if weaponcomplain is shown
 550                 if(complain_weapon)
 551                         ++weapon_count;
 552
 553                 // might as well commit suicide now, no reason to live ;)
 554                 if (weapon_count == 0)
 555                 {
 556                         draw_endBoldFont();
 557                         return;
 558                 }
 559
 560                 old_panel_size = panel_size;
 561                 if(panel_bg_padding)
 562                         old_panel_size -= '2 2 0' * panel_bg_padding;
 563
 564                 // first find values for the standard table (with all the weapons)
 565                 rows = old_panel_size_y/old_panel_size_x;
 566                 rows = bound(1, floor((sqrt(4 * aspect * rows * WEP_COUNT + rows * rows) + rows + 0.5) / 2), WEP_COUNT);
 567                 columns = ceil(WEP_COUNT/rows);
 568                 weapon_size_x = old_panel_size_x / columns;
 569                 weapon_size_y = old_panel_size_y / rows;
 570
 571                 // change table values to include only the owned weapons
 572                 // weapon_size won't be changed
 573                 if(weapon_count <= rows)
 574                 {
 575                         rows = weapon_count;
 576                         columns = 1;
 577                 }
 578                 else
 579                         columns = ceil(weapon_count / rows);
 580
 581                 // reduce size of the panel
 582                 panel_size_x = columns * weapon_size_x;
 583                 panel_size_y = rows * weapon_size_y;
 584                 panel_pos_x += (old_panel_size_x - panel_size_x) / 2;
 585                 panel_pos_y += (old_panel_size_y - panel_size_y) / 2;
 586                 if(panel_bg_padding)
 587                         panel_size += '2 2 0' * panel_bg_padding;
 588         }
 589         else
 590                 weapon_count = WEP_COUNT;
 591
 592         // animation for fading in/out the panel respectively when not in use
 593         if(!autocvar__hud_configure)
 594         {
 595                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 596                 {
 597                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 598
 599                         // fade the panel alpha
 600                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 601                         {
 602                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 603                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 604                         }
 605                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 606                         {
 607                                 panel_bg_alpha *= (1 - f);
 608                                 panel_fg_alpha *= (1 - f);
 609                         }
 610
 611                         // move the panel off the screen
 612                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 613                         {
 614                                 f *= f; // for a cooler movement
 615                                 center_x = panel_pos_x + panel_size_x/2;
 616                                 center_y = panel_pos_y + panel_size_y/2;
 617                                 screen_ar = vid_conwidth/vid_conheight;
 618                                 if (center_x/center_y < screen_ar) //bottom left
 619                                 {
 620                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 621                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 622                                         else //left
 623                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 624                                 }
 625                                 else //top right
 626                                 {
 627                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 628                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 629                                         else //top
 630                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 631                                 }
 632                                 if(f == 1)
 633                                         center_x = -1; // mark the panel as off screen
 634                         }
 635                         weaponprevtime = time - (1 - f) * timein_effect_length;
 636                 }
 637                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 638                 {
 639                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 640
 641                         // fade the panel alpha
 642                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 643                         {
 644                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 645                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 646                         }
 647                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 648                         {
 649                                 panel_bg_alpha *= (f);
 650                                 panel_fg_alpha *= (f);
 651                         }
 652
 653                         // move the panel back on screen
 654                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 655                         {
 656                                 f *= f; // for a cooler movement
 657                                 f = 1 - f;
 658                                 center_x = panel_pos_x + panel_size_x/2;
 659                                 center_y = panel_pos_y + panel_size_y/2;
 660                                 screen_ar = vid_conwidth/vid_conheight;
 661                                 if (center_x/center_y < screen_ar) //bottom left
 662                                 {
 663                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 664                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 665                                         else //left
 666                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 667                                 }
 668                                 else //top right
 669                                 {
 670                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 671                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 672                                         else //top
 673                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 674                                 }
 675                         }
 676                 }
 677         }
 678
 679         // draw the background, then change the virtual size of it to better fit other items inside
 680         HUD_Panel_DrawBg(1);
 681
 682         if(center_x == -1)
 683         {
 684                 draw_endBoldFont();
 685                 return;
 686         }
 687
 688         if(panel_bg_padding)
 689         {
 690                 panel_pos += '1 1 0' * panel_bg_padding;
 691                 panel_size -= '2 2 0' * panel_bg_padding;
 692         }
 693
 694         // after the sizing and animations are done, update the other values
 695
 696         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 697         {
 698                 rows = panel_size_y/panel_size_x;
 699                 rows = bound(1, floor((sqrt(4 * aspect * rows * weapon_count + rows * rows) + rows + 0.5) / 2), weapon_count);
 700                 columns = ceil(weapon_count/rows);
 701                 weapon_size = eX * panel_size_x*(1/columns) + eY * panel_size_y*(1/rows);
 702         }
 703
 704         // calculate position/size for visual bar displaying ammount of ammo status
 705         if (autocvar_hud_panel_weapons_ammo)
 706         {
 707                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 708                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 709
 710                 if(weapon_size_x/weapon_size_y > aspect)
 711                 {
 712                         barsize_x = aspect * weapon_size_y;
 713                         barsize_y = weapon_size_y;
 714                         baroffset_x = (weapon_size_x - barsize_x) / 2;
 715                 }
 716                 else
 717                 {
 718                         barsize_y = 1/aspect * weapon_size_x;
 719                         barsize_x = weapon_size_x;
 720                         baroffset_y = (weapon_size_y - barsize_y) / 2;
 721                 }
 722         }
 723         if(autocvar_hud_panel_weapons_accuracy)
 724                 Accuracy_LoadColors();
 725
 726         row = column = 0;
 727         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 728         {
 729                 // retrieve information about the current weapon to be drawn
 730                 self = weaponorder[i];
 731                 weapon_id = self.impulse;
 732
 733                 // skip if this weapon doesn't exist
 734                 if(!self || weapon_id < 0) { continue; }
 735
 736                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 737                 if(autocvar_hud_panel_weapons_onlyowned)
 738                 if not(WEPSET_CONTAINS_AW(weapons_stat, self.weapon) || (self.weapon == complain_weapon))
 739                         continue;
 740
 741                 // figure out the drawing position of weapon
 742                 weapon_pos = (panel_pos
 743                         + eX * column * weapon_size_x
 744                         + eY * row * weapon_size_y);
 745
 746                 // draw background behind currently selected weapon
 747                 if(self.weapon == switchweapon)
 748                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 749
 750                 // draw the weapon accuracy
 751                 if(autocvar_hud_panel_weapons_accuracy)
 752                 {
 753                         panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 754                         if(panel_weapon_accuracy >= 0)
 755                         {
 756                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 757                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 758                         }
 759                 }
 760
 761                 // drawing all the weapon items
 762                 if(WEPSET_CONTAINS_AW(weapons_stat, self.weapon))
 763                 {
 764                         // draw the weapon image
 765                         drawpic_aspect_skin(weapon_pos, strcat("weapon", self.netname), weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 766
 767                         // draw weapon label string
 768                         switch(autocvar_hud_panel_weapons_label)
 769                         {
 770                                 case 1: // weapon number
 771                                         drawstring(weapon_pos, ftos(weapon_id), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 772                                         break;
 773
 774                                 case 2: // bind
 775                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 776                                         break;
 777
 778                                 case 3: // weapon name
 779                                         drawstring(weapon_pos, self.netname, '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 780                                         break;
 781
 782                                 default: // nothing
 783                                         break;
 784                         }
 785
 786                         // draw ammo status bar
 787                         if(autocvar_hud_panel_weapons_ammo && self.weapon != WEP_TUBA && self.weapon != WEP_LASER && self.weapon != WEP_PORTO)
 788                         {
 789                                 a = 0;
 790                                 ammo_type = GetAmmoTypeForWep(self.weapon);
 791                                 if(ammo_type != -1)
 792                                         a = getstati(GetAmmoStat(ammo_type)); // how much ammo do we have?
 793
 794                                 if(a > 0)
 795                                 {
 796                                         switch(ammo_type) {
 797                                                 case 0: ammo_full = autocvar_hud_panel_weapons_ammo_full_shells; break;
 798                                                 case 1: ammo_full = autocvar_hud_panel_weapons_ammo_full_nails; break;
 799                                                 case 2: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 800                                                 case 3: ammo_full = autocvar_hud_panel_weapons_ammo_full_cells; break;
 801                                                 case 4: ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel; break;
 802                                                 default: ammo_full = 60;
 803                                         }
 804
 805                                         drawsetcliparea(
 806                                                 weapon_pos_x + baroffset_x,
 807                                                 weapon_pos_y + baroffset_y,
 808                                                 barsize_x * bound(0, a/ammo_full, 1),
 809                                                 barsize_y);
 810                                         drawpic_aspect_skin(weapon_pos, "weapon_ammo", weapon_size, ammo_color, ammo_alpha, DRAWFLAG_NORMAL);
 811                                         drawresetcliparea();
 812                                 }
 813                         }
 814                 }
 815                 else // draw a "ghost weapon icon" if you don't have the weapon
 816                 {
 817                         drawpic_aspect_skin(weapon_pos, strcat("weapon", self.netname), weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 818                 }
 819
 820                 // draw the complain message
 821                 if(self.weapon == complain_weapon)
 822                 {
 823                         if(fadetime)
 824                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 825                         else
 826                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 827
 828                         string s;
 829                         if(complain_weapon_type == 0) {
 830                                 s = _("Out of ammo");
 831                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 832                         }
 833                         else if(complain_weapon_type == 1) {
 834                                 s = _("Don't have");
 835                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 836                         }
 837                         else {
 838                                 s = _("Unavailable");
 839                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 840                         }
 841                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 842                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 843                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 844                 }
 845
 846                 // continue with new position for the next weapon
 847                 ++row;
 848                 if(row >= rows)
 849                 {
 850                         row = 0;
 851                         ++column;
 852                 }
 853         }
 854
 855         draw_endBoldFont();
 856 }
 857
 858 // Ammo (#1)
 859 //
 860 // TODO: macro
 861 float GetAmmoItemCode(float i)
 862 {
 863         switch(i)
 864         {
 865                 case 0: return IT_SHELLS;
 866                 case 1: return IT_NAILS;
 867                 case 2: return IT_ROCKETS;
 868                 case 3: return IT_CELLS;
 869                 case 4: return IT_FUEL;
 870                 default: return -1;
 871         }
 872 }
 873
 874 string GetAmmoPicture(float i)
 875 {
 876         switch(i)
 877         {
 878                 case 0: return "ammo_shells";
 879                 case 1: return "ammo_bullets";
 880                 case 2: return "ammo_rockets";
 881                 case 3: return "ammo_cells";
 882                 case 4: return "ammo_fuel";
 883                 default: return "";
 884         }
 885 }
 886
 887 void DrawAmmoItem(vector myPos, vector mySize, float itemcode, float currently_selected, float infinite_ammo)
 888 {
 889         float a;
 890         if(autocvar__hud_configure)
 891         {
 892                 currently_selected = (itemcode == 2); //rockets always selected
 893                 a = 31 + mod(itemcode*93, 128);
 894         }
 895         else
 896                 a = getstati(GetAmmoStat(itemcode)); // how much ammo do we have of type itemcode?
 897
 898         vector color;
 899         if(infinite_ammo)
 900                 color = '0 0.5 0.75';
 901         else if(a < 10)
 902                 color = '0.7 0 0';
 903         else
 904                 color = '1 1 1';
 905
 906         float theAlpha;
 907         if(currently_selected)
 908                 theAlpha = 1;
 909         else
 910                 theAlpha = 0.7;
 911
 912         vector picpos, numpos;
 913         if(autocvar_hud_panel_ammo_iconalign)
 914         {
 915                 numpos = myPos;
 916                 picpos = myPos + eX * 2 * mySize_y;
 917         }
 918         else
 919         {
 920                 numpos = myPos + eX * mySize_y;
 921                 picpos = myPos;
 922         }
 923
 924         if (currently_selected)
 925                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 926
 927     if(a > 0 && autocvar_hud_panel_ammo_progressbar)
 928         HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, autocvar_hud_panel_ammo_progressbar_name, a/autocvar_hud_panel_ammo_maxammo, 0, 0, color, autocvar_hud_progressbar_alpha * panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 929
 930     if(autocvar_hud_panel_ammo_text)
 931     {
 932         if(a > 0 || infinite_ammo)
 933             drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 934         else // "ghost" ammo count
 935             drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, '0 0 0', panel_fg_alpha * theAlpha * 0.5, DRAWFLAG_NORMAL);
 936     }
 937         if(a > 0 || infinite_ammo)
 938                 drawpic_aspect_skin(picpos, GetAmmoPicture(itemcode), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 939         else // "ghost" ammo icon
 940                 drawpic_aspect_skin(picpos, GetAmmoPicture(itemcode), '1 1 0' * mySize_y, '0 0 0', panel_fg_alpha * theAlpha * 0.5, DRAWFLAG_NORMAL);
 941 }
 942
 943 void HUD_Ammo(void)
 944 {
 945     if(hud != HUD_NORMAL) return;
 946         if(!autocvar__hud_configure)
 947         {
 948                 if(!autocvar_hud_panel_ammo) return;
 949                 if(spectatee_status == -1) return;
 950         }
 951
 952         HUD_Panel_UpdateCvars();
 953         HUD_Panel_ApplyFadeAlpha();
 954
 955         draw_beginBoldFont();
 956
 957         vector pos, mySize;
 958         pos = panel_pos;
 959         mySize = panel_size;
 960
 961         HUD_Panel_DrawBg(1);
 962         if(panel_bg_padding)
 963         {
 964                 pos += '1 1 0' * panel_bg_padding;
 965                 mySize -= '2 2 0' * panel_bg_padding;
 966         }
 967
 968         float rows = 0, columns, row, column;
 969         vector ammo_size;
 970         if (autocvar_hud_panel_ammo_onlycurrent)
 971                 ammo_size = mySize;
 972         else
 973         {
 974                 rows = mySize_y/mySize_x;
 975                 rows = bound(1, floor((sqrt(4 * (3/1) * rows * AMMO_COUNT + rows * rows) + rows + 0.5) / 2), AMMO_COUNT);
 976                 //                               ^^^ ammo item aspect goes here
 977
 978                 columns = ceil(AMMO_COUNT/rows);
 979
 980                 ammo_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
 981         }
 982
 983         local vector offset = '0 0 0'; // fteqcc sucks
 984         float newSize;
 985         if(ammo_size_x/ammo_size_y > 3)
 986         {
 987                 newSize = 3 * ammo_size_y;
 988                 offset_x = ammo_size_x - newSize;
 989                 pos_x += offset_x/2;
 990                 ammo_size_x = newSize;
 991         }
 992         else
 993         {
 994                 newSize = 1/3 * ammo_size_x;
 995                 offset_y = ammo_size_y - newSize;
 996                 pos_y += offset_y/2;
 997                 ammo_size_y = newSize;
 998         }
 999
1000         float i, stat_items, currently_selected, infinite_ammo;
1001         infinite_ammo = FALSE;
1002         if (autocvar_hud_panel_ammo_onlycurrent)
1003         {
1004                 if(autocvar__hud_configure)
1005                 {
1006                         DrawAmmoItem(pos, ammo_size, 2, true, FALSE); //show rockets
1007                 }
1008                 else
1009                 {
1010                         stat_items = getstati(STAT_ITEMS, 0, 24);
1011                         if (stat_items & IT_UNLIMITED_WEAPON_AMMO)
1012                                 infinite_ammo = TRUE;
1013                         for (i = 0; i < AMMO_COUNT; ++i) {
1014                                 currently_selected = stat_items & GetAmmoItemCode(i);
1015                                 if (currently_selected)
1016                                 {
1017                                         DrawAmmoItem(pos, ammo_size, i, true, infinite_ammo);
1018                                         break;
1019                                 }
1020                         }
1021                 }
1022         }
1023         else
1024         {
1025                 stat_items = getstati(STAT_ITEMS, 0, 24);
1026                 if (stat_items & IT_UNLIMITED_WEAPON_AMMO)
1027                         infinite_ammo = TRUE;
1028                 row = column = 0;
1029                 for (i = 0; i < AMMO_COUNT; ++i) {
1030                         currently_selected = stat_items & GetAmmoItemCode(i);
1031                         DrawAmmoItem(pos + eX * column * (ammo_size_x + offset_x) + eY * row * (ammo_size_y + offset_y), ammo_size, i, currently_selected, infinite_ammo);
1032                         ++row;
1033                         if(row >= rows)
1034                         {
1035                                 row = 0;
1036                                 column = column + 1;
1037                         }
1038                 }
1039         }
1040
1041         draw_endBoldFont();
1042 }
1043
1044 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha, float fadelerp)
1045 {
1046         vector newPos = '0 0 0', newSize = '0 0 0';
1047         vector picpos, numpos;
1048
1049         if (vertical)
1050         {
1051                 if(mySize_y/mySize_x > 2)
1052                 {
1053                         newSize_y = 2 * mySize_x;
1054                         newSize_x = mySize_x;
1055
1056                         newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1057                         newPos_x = myPos_x;
1058                 }
1059                 else
1060                 {
1061                         newSize_x = 1/2 * mySize_y;
1062                         newSize_y = mySize_y;
1063
1064                         newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1065                         newPos_y = myPos_y;
1066                 }
1067
1068                 if(icon_right_align)
1069                 {
1070                         numpos = newPos;
1071                         picpos = newPos + eY * newSize_x;
1072                 }
1073                 else
1074                 {
1075                         picpos = newPos;
1076                         numpos = newPos + eY * newSize_x;
1077                 }
1078
1079                 newSize_y /= 2;
1080                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1081                 // make number smaller than icon, it looks better
1082                 // reduce only y to draw numbers with different number of digits with the same y size
1083                 numpos_y += newSize_y * ((1 - 0.7) / 2);
1084                 newSize_y *= 0.7;
1085                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1086                 return;
1087         }
1088
1089         if(mySize_x/mySize_y > 3)
1090         {
1091                 newSize_x = 3 * mySize_y;
1092                 newSize_y = mySize_y;
1093
1094                 newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1095                 newPos_y = myPos_y;
1096         }
1097         else
1098         {
1099                 newSize_y = 1/3 * mySize_x;
1100                 newSize_x = mySize_x;
1101
1102                 newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1103                 newPos_x = myPos_x;
1104         }
1105
1106         if(icon_right_align) // right align
1107         {
1108                 numpos = newPos;
1109                 picpos = newPos + eX * 2 * newSize_y;
1110         }
1111         else // left align
1112         {
1113                 numpos = newPos + eX * newSize_y;
1114                 picpos = newPos;
1115         }
1116
1117         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1118         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1119         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1120         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1121 }
1122
1123 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha)
1124 {
1125         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1126 }
1127
1128 // Powerups (#2)
1129 //
1130 void HUD_Powerups(void)
1131 {
1132         float strength_time, shield_time, superweapons_time;
1133         if(!autocvar__hud_configure)
1134         {
1135                 if(!autocvar_hud_panel_powerups) return;
1136                 if(spectatee_status == -1) return;
1137                 if not(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON)) return;
1138                 if (getstati(STAT_HEALTH) <= 0) return;
1139
1140                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1141                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1142                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1143
1144                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1145                         superweapons_time = 99; // force max
1146
1147                 // prevent stuff to show up on mismatch that will be fixed next frame
1148                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1149                         superweapons_time = 0;
1150         }
1151         else
1152         {
1153                 strength_time = 15;
1154                 shield_time = 27;
1155                 superweapons_time = 13;
1156         }
1157
1158         HUD_Panel_UpdateCvars();
1159         HUD_Panel_ApplyFadeAlpha();
1160
1161         draw_beginBoldFont();
1162
1163         vector pos, mySize;
1164         pos = panel_pos;
1165         mySize = panel_size;
1166
1167         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1168         if(panel_bg_padding)
1169         {
1170                 pos += '1 1 0' * panel_bg_padding;
1171                 mySize -= '2 2 0' * panel_bg_padding;
1172         }
1173
1174         float panel_ar = mySize_x/mySize_y;
1175         float is_vertical = (panel_ar < 1);
1176         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1177
1178         float superweapons_is = -1;
1179
1180         if(superweapons_time)
1181         {
1182                 if(strength_time)
1183                 {
1184                         if(shield_time)
1185                                 superweapons_is = 0;
1186                         else
1187                                 superweapons_is = 2;
1188                 }
1189                 else
1190                 {
1191                         if(shield_time)
1192                                 superweapons_is = 1;
1193                         else
1194                                 superweapons_is = 2;
1195                 }
1196         }
1197
1198         // FIXME handle superweapons here
1199         if(superweapons_is == 0)
1200         {
1201                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1202                 {
1203                         mySize_x *= (1.0 / 3.0);
1204                         superweapons_offset_x = mySize_x;
1205                         if (autocvar_hud_panel_powerups_flip)
1206                                 shield_offset_x = 2*mySize_x;
1207                         else
1208                                 strength_offset_x = 2*mySize_x;
1209                 }
1210                 else
1211                 {
1212                         mySize_y *= (1.0 / 3.0);
1213                         superweapons_offset_y = mySize_y;
1214                         if (autocvar_hud_panel_powerups_flip)
1215                                 shield_offset_y = 2*mySize_y;
1216                         else
1217                                 strength_offset_y = 2*mySize_y;
1218                 }
1219         }
1220         else
1221         {
1222                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1223                 {
1224                         mySize_x *= 0.5;
1225                         if (autocvar_hud_panel_powerups_flip)
1226                                 shield_offset_x = mySize_x;
1227                         else
1228                                 strength_offset_x = mySize_x;
1229                 }
1230                 else
1231                 {
1232                         mySize_y *= 0.5;
1233                         if (autocvar_hud_panel_powerups_flip)
1234                                 shield_offset_y = mySize_y;
1235                         else
1236                                 strength_offset_y = mySize_y;
1237                 }
1238         }
1239
1240         float shield_baralign, strength_baralign, superweapons_baralign;
1241         float shield_iconalign, strength_iconalign, superweapons_iconalign;
1242
1243         if (autocvar_hud_panel_powerups_flip)
1244         {
1245                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1246                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1247                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1248                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1249         }
1250         else
1251         {
1252                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1253                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1254                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1255                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1256         }
1257
1258         if(superweapons_is == 0)
1259         {
1260                 superweapons_iconalign = strength_iconalign;
1261                 superweapons_baralign = 2;
1262         }
1263         else if(superweapons_is == 1)
1264         {
1265                 superweapons_offset = strength_offset;
1266                 superweapons_iconalign = strength_iconalign;
1267                 superweapons_baralign = strength_baralign;
1268         }
1269         else // if(superweapons_is == 2)
1270         {
1271                 superweapons_offset = shield_offset;
1272                 superweapons_iconalign = shield_iconalign;
1273                 superweapons_baralign = shield_baralign;
1274         }
1275
1276         if(shield_time)
1277         {
1278                 const float maxshield = 30;
1279                 float shield = ceil(shield_time);
1280                 if(autocvar_hud_panel_powerups_progressbar)
1281                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, autocvar_hud_progressbar_shield_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1282                 if(autocvar_hud_panel_powerups_text)
1283                 {
1284                         if(shield > 1)
1285                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1286                         if(shield <= 5)
1287                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1288                 }
1289         }
1290
1291         if(strength_time)
1292         {
1293                 const float maxstrength = 30;
1294                 float strength = ceil(strength_time);
1295                 if(autocvar_hud_panel_powerups_progressbar)
1296                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, autocvar_hud_progressbar_strength_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1297                 if(autocvar_hud_panel_powerups_text)
1298                 {
1299                         if(strength > 1)
1300                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1301                         if(strength <= 5)
1302                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1303                 }
1304         }
1305
1306         if(superweapons_time)
1307         {
1308                 const float maxsuperweapons = 30;
1309                 float superweapons = ceil(superweapons_time);
1310                 if(autocvar_hud_panel_powerups_progressbar)
1311                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, autocvar_hud_progressbar_superweapons_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1312                 if(autocvar_hud_panel_powerups_text)
1313                 {
1314                         if(superweapons > 1)
1315                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1316                         if(superweapons <= 5)
1317                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1318                 }
1319         }
1320
1321         draw_endBoldFont();
1322 }
1323
1324 // Health/armor (#3)
1325 //
1326
1327 // prev_* vars contain the health/armor at the previous FRAME
1328 // set to -1 when player is dead or was not playing
1329 float prev_health, prev_armor;
1330 float health_damagetime, armor_damagetime;
1331 float health_beforedamage, armor_beforedamage;
1332 // old_p_* vars keep track of previous values when smoothing value changes of the progressbar
1333 float old_p_health, old_p_armor;
1334 float old_p_healthtime, old_p_armortime;
1335 // prev_p_* vars contain the health/armor progressbar value at the previous FRAME
1336 // set to -1 to forcedly stop effects when we switch spectated player (e.g. from playerX: 70h to playerY: 50h)
1337 float prev_p_health, prev_p_armor;
1338
1339 void HUD_HealthArmor(void)
1340 {
1341         float armor, health, fuel;
1342         if(!autocvar__hud_configure)
1343         {
1344                 if(!autocvar_hud_panel_healtharmor) return;
1345                 if(hud != HUD_NORMAL) return;
1346                 if(spectatee_status == -1) return;
1347
1348                 health = getstati(STAT_HEALTH);
1349                 if(health <= 0)
1350                 {
1351                         prev_health = -1;
1352                         return;
1353                 }
1354                 armor = getstati(STAT_ARMOR);
1355
1356                 // code to check for spectatee_status changes is in Ent_ClientData()
1357                 // prev_p_health and prev_health can be set to -1 there
1358
1359                 if (prev_p_health == -1)
1360                 {
1361                         // no effect
1362                         health_beforedamage = 0;
1363                         armor_beforedamage = 0;
1364                         health_damagetime = 0;
1365                         armor_damagetime = 0;
1366                         prev_health = health;
1367                         prev_armor = armor;
1368                         old_p_health = health;
1369                         old_p_armor = armor;
1370                         prev_p_health = health;
1371                         prev_p_armor = armor;
1372                 }
1373                 else if (prev_health == -1)
1374                 {
1375                         //start the load effect
1376                         health_damagetime = 0;
1377                         armor_damagetime = 0;
1378                         prev_health = 0;
1379                         prev_armor = 0;
1380                 }
1381                 fuel = getstati(STAT_FUEL);
1382         }
1383         else
1384         {
1385                 health = 150;
1386                 armor = 75;
1387                 fuel = 20;
1388         }
1389
1390         HUD_Panel_UpdateCvars();
1391         HUD_Panel_ApplyFadeAlpha();
1392         vector pos, mySize;
1393         pos = panel_pos;
1394         mySize = panel_size;
1395
1396         HUD_Panel_DrawBg(1);
1397         if(panel_bg_padding)
1398         {
1399                 pos += '1 1 0' * panel_bg_padding;
1400                 mySize -= '2 2 0' * panel_bg_padding;
1401         }
1402
1403         float baralign = autocvar_hud_panel_healtharmor_baralign;
1404         float iconalign = autocvar_hud_panel_healtharmor_iconalign;
1405
1406     float maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1407     float maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1408         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1409         {
1410                 vector v;
1411                 v = healtharmor_maxdamage(health, armor, armorblockpercent);
1412
1413                 float x;
1414                 x = floor(v_x + 1);
1415
1416         float maxtotal = maxhealth + maxarmor;
1417                 string biggercount;
1418                 if(v_z) // NOT fully armored
1419                 {
1420                         biggercount = "health";
1421                         if(autocvar_hud_panel_healtharmor_progressbar)
1422                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1423                         if(armor)
1424             if(autocvar_hud_panel_healtharmor_text)
1425                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "armor", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1426                 }
1427                 else
1428                 {
1429                         biggercount = "armor";
1430                         if(autocvar_hud_panel_healtharmor_progressbar)
1431                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1432                         if(health)
1433             if(autocvar_hud_panel_healtharmor_text)
1434                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "health", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1435                 }
1436         if(autocvar_hud_panel_healtharmor_text)
1437                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1438
1439                 if(fuel)
1440                         HUD_Panel_DrawProgressBar(pos, eX * mySize_x + eY * 0.2 * mySize_y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1441         }
1442         else
1443         {
1444                 float panel_ar = mySize_x/mySize_y;
1445                 float is_vertical = (panel_ar < 1);
1446                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1447                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1448                 {
1449                         mySize_x *= 0.5;
1450                         if (autocvar_hud_panel_healtharmor_flip)
1451                                 health_offset_x = mySize_x;
1452                         else
1453                                 armor_offset_x = mySize_x;
1454                 }
1455                 else
1456                 {
1457                         mySize_y *= 0.5;
1458                         if (autocvar_hud_panel_healtharmor_flip)
1459                                 health_offset_y = mySize_y;
1460                         else
1461                                 armor_offset_y = mySize_y;
1462                 }
1463
1464                 float health_baralign, armor_baralign, fuel_baralign;
1465                 float health_iconalign, armor_iconalign;
1466                 if (autocvar_hud_panel_healtharmor_flip)
1467                 {
1468                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1469                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1470                         fuel_baralign = health_baralign;
1471                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1472                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1473                 }
1474                 else
1475                 {
1476                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1477                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1478                         fuel_baralign = armor_baralign;
1479                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1480                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1481                 }
1482
1483                 //if(health)
1484                 {
1485                         if(autocvar_hud_panel_healtharmor_progressbar)
1486                         {
1487                                 float p_health, pain_health_alpha;
1488                                 p_health = health;
1489                                 pain_health_alpha = 1;
1490                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1491                                 {
1492                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1493                                         {
1494                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1495                                                 {
1496                                                         if (time - old_p_healthtime < 1)
1497                                                                 old_p_health = prev_p_health;
1498                                                         else
1499                                                                 old_p_health = prev_health;
1500                                                         old_p_healthtime = time;
1501                                                 }
1502                                                 if (time - old_p_healthtime < 1)
1503                                                 {
1504                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1505                                                         prev_p_health = p_health;
1506                                                 }
1507                                         }
1508                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1509                                         {
1510                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1511                                                 {
1512                                                         if (time - health_damagetime >= 1)
1513                                                                 health_beforedamage = prev_health;
1514                                                         health_damagetime = time;
1515                                                 }
1516                                                 if (time - health_damagetime < 1)
1517                                                 {
1518                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1519                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1520                                                 }
1521                                         }
1522                                         prev_health = health;
1523
1524                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1525                                         {
1526                                                 float BLINK_FACTOR = 0.15;
1527                                                 float BLINK_BASE = 0.85;
1528                                                 float BLINK_FREQ = 9;
1529                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1530                                         }
1531                                 }
1532                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1533                         }
1534                         if(autocvar_hud_panel_healtharmor_text)
1535                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1536                 }
1537
1538                 if(armor)
1539                 {
1540                         if(autocvar_hud_panel_healtharmor_progressbar)
1541                         {
1542                                 float p_armor;
1543                                 p_armor = armor;
1544                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1545                                 {
1546                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1547                                         {
1548                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1549                                                 {
1550                                                         if (time - old_p_armortime < 1)
1551                                                                 old_p_armor = prev_p_armor;
1552                                                         else
1553                                                                 old_p_armor = prev_armor;
1554                                                         old_p_armortime = time;
1555                                                 }
1556                                                 if (time - old_p_armortime < 1)
1557                                                 {
1558                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1559                                                         prev_p_armor = p_armor;
1560                                                 }
1561                                         }
1562                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1563                                         {
1564                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1565                                                 {
1566                                                         if (time - armor_damagetime >= 1)
1567                                                                 armor_beforedamage = prev_armor;
1568                                                         armor_damagetime = time;
1569                                                 }
1570                                                 if (time - armor_damagetime < 1)
1571                                                 {
1572                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1573                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1574                                                 }
1575                                         }
1576                                         prev_armor = armor;
1577                                 }
1578                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1579                         }
1580                         if(autocvar_hud_panel_healtharmor_text)
1581                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1582                 }
1583
1584                 if(fuel)
1585                 {
1586                         if (is_vertical)
1587                                 mySize_x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1588                         else
1589                                 mySize_y *= 0.2;
1590                         if (panel_ar >= 4)
1591                                 mySize_x *= 2; //restore full panel size
1592                         else if (panel_ar < 1/4)
1593                                 mySize_y *= 2; //restore full panel size
1594                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1595                 }
1596         }
1597 }
1598
1599 // Notification area (#4)
1600 //
1601
1602 void HUD_Notify_Push(string icon, string attacker, string victim)
1603 {
1604         if(icon != "")
1605         {
1606                 --kn_index;
1607                 if (kn_index == -1) { kn_index = KN_MAX_ENTRIES-1; }
1608                 notify_times[kn_index] = time;
1609
1610                 // icon
1611                 if(notify_icon[kn_index]) { strunzone(notify_icon[kn_index]); }
1612                 notify_icon[kn_index] = strzone(icon);
1613
1614                 // attacker
1615                 if(notify_attackers[kn_index]) { strunzone(notify_attackers[kn_index]); }
1616                 notify_attackers[kn_index] = strzone(attacker);
1617
1618                 // victim
1619                 if(notify_victims[kn_index]) { strunzone(notify_victims[kn_index]); }
1620                 notify_victims[kn_index] = strzone(victim);
1621         }
1622 }
1623
1624 void HUD_Notify(void)
1625 {
1626         if(!autocvar__hud_configure)
1627         {
1628                 if(!autocvar_hud_panel_notify) return;
1629         }
1630
1631         HUD_Panel_UpdateCvars();
1632         HUD_Panel_ApplyFadeAlpha();
1633         vector pos, mySize;
1634         pos = panel_pos;
1635         mySize = panel_size;
1636
1637         HUD_Panel_DrawBg(1);
1638         if(panel_bg_padding)
1639         {
1640                 pos += '1 1 0' * panel_bg_padding;
1641                 mySize -= '2 2 0' * panel_bg_padding;
1642         }
1643
1644         float entries, height;
1645         entries = bound(1, floor(KN_MAX_ENTRIES * mySize_y/mySize_x), KN_MAX_ENTRIES);
1646         height = mySize_y/entries;
1647
1648         vector fontsize;
1649         float fontheight = height * autocvar_hud_panel_notify_fontsize;
1650         fontsize = '0.5 0.5 0' * fontheight;
1651
1652         float a;
1653         float when;
1654         when = autocvar_hud_panel_notify_time;
1655         float fadetime;
1656         fadetime = autocvar_hud_panel_notify_fadetime;
1657
1658         vector pos_attacker, pos_victim, pos_icon;
1659         float width_attacker;
1660         string attacker, victim, icon;
1661
1662         float i, j, step, limit;
1663         if(autocvar_hud_panel_notify_flip) //order items from the top down
1664         {
1665                 i = 0;
1666                 step = +1;
1667                 limit = entries;
1668         }
1669         else //order items from the bottom up
1670         {
1671                 i = entries - 1;
1672                 step = -1;
1673                 limit = -1;
1674         }
1675
1676         for(j = kn_index;  i != limit;  i += step, ++j)
1677         {
1678                 if(autocvar__hud_configure)
1679                 {
1680                         if (step == +1)
1681                                 a = i;
1682                         else // inverse order
1683                                 a = entries - 1 - i;
1684                         attacker = textShortenToWidth(sprintf(_("Player %d"), a+1), 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1685                         victim = textShortenToWidth(sprintf(_("Player %d"), a+2), 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1686                         icon = strcat("weapon", get_weaponinfo(WEP_FIRST + mod(floor(a*2.4), WEP_LAST)).netname);
1687                         a = bound(0, (when - a) / 4, 1);
1688                         goto hud_config_notifyprint;
1689                 }
1690                 else
1691                 {
1692                         if (j == KN_MAX_ENTRIES)
1693                                 j = 0;
1694
1695                         if(notify_times[j] + when > time)
1696                                 a = 1;
1697                         else if(fadetime)
1698                         {
1699                                 a = bound(0, (notify_times[j] + when + fadetime - time) / fadetime, 1);
1700                                 if(!a)
1701                                 {
1702                                         break;
1703                                 }
1704                         }
1705                         else
1706                         {
1707                                 break;
1708                         }
1709
1710                         attacker = notify_attackers[j];
1711                         victim = notify_victims[j];
1712                         icon = notify_icon[j];
1713                 }
1714
1715                 //type = notify_deathtype[j];
1716                 //w = DEATH_WEAPONOF(type);
1717
1718                 if(icon != "")
1719                 {
1720                         if((attacker != "") && (victim == ""))
1721                         {
1722                                 // Y [used by] X
1723                                 attacker = textShortenToWidth(attacker, 0.73 * mySize_x - height, fontsize, stringwidth_colors);
1724                                 pos_attacker = pos + eX * (0.27 * mySize_x + height) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1725                                 pos_icon = pos + eX * 0.25 * mySize_x - eX * height + eY * i * height;
1726
1727                                 drawpic_aspect_skin(pos_icon, icon, '2 1 0' * height, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
1728                                 drawcolorcodedstring(pos_attacker, attacker, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1729                         }
1730                         else if((attacker != "") && (victim != ""))
1731                         {
1732                                 // X [did action to] Y
1733                                 attacker = textShortenToWidth(attacker, 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1734                                 victim = textShortenToWidth(victim, 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1735 :hud_config_notifyprint
1736                                 width_attacker = stringwidth(attacker, TRUE, fontsize);
1737                                 pos_attacker = pos + eX * (0.48 * mySize_x - height - width_attacker) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1738                                 pos_victim = pos + eX * (0.52 * mySize_x + height) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1739                                 pos_icon = pos + eX * 0.5 * mySize_x - eX * height + eY * i * height;
1740
1741                                 drawpic_aspect_skin(pos_icon, icon, '2 1 0' * height, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
1742                                 drawcolorcodedstring(pos_attacker, attacker, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1743                                 drawcolorcodedstring(pos_victim, victim, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1744                         }
1745                 }
1746         }
1747 }
1748
1749 // Timer (#5)
1750 //
1751 // TODO: macro
1752 string seconds_tostring(float sec)
1753 {
1754         float minutes;
1755         minutes = floor(sec / 60);
1756
1757         sec -= minutes * 60;
1758         return sprintf("%d:%02d", minutes, sec);
1759 }
1760
1761 void HUD_Timer(void)
1762 {
1763         if(!autocvar__hud_configure)
1764         {
1765                 if(!autocvar_hud_panel_timer) return;
1766         }
1767
1768         HUD_Panel_UpdateCvars();
1769         HUD_Panel_ApplyFadeAlpha();
1770
1771         draw_beginBoldFont();
1772
1773         vector pos, mySize;
1774         pos = panel_pos;
1775         mySize = panel_size;
1776
1777         HUD_Panel_DrawBg(1);
1778         if(panel_bg_padding)
1779         {
1780                 pos += '1 1 0' * panel_bg_padding;
1781                 mySize -= '2 2 0' * panel_bg_padding;
1782         }
1783
1784         string timer;
1785         float timelimit, elapsedTime, timeleft, minutesLeft;
1786
1787         timelimit = getstatf(STAT_TIMELIMIT);
1788
1789         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1790         timeleft = ceil(timeleft);
1791
1792         minutesLeft = floor(timeleft / 60);
1793
1794         vector timer_color;
1795         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1796                 timer_color = '1 1 1'; //white
1797         else if(minutesLeft >= 1)
1798                 timer_color = '1 1 0'; //yellow
1799         else
1800                 timer_color = '1 0 0'; //red
1801
1802         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1803                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1804                         //while restart is still active, show 00:00
1805                         timer = seconds_tostring(0);
1806                 } else {
1807                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1808                         timer = seconds_tostring(elapsedTime);
1809                 }
1810         } else {
1811                 timer = seconds_tostring(timeleft);
1812         }
1813
1814         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1815
1816         draw_endBoldFont();
1817 }
1818
1819 // Radar (#6)
1820 //
1821 void HUD_Radar(void)
1822 {
1823         if (!autocvar__hud_configure)
1824         {
1825                 if (hud_panel_radar_maximized)
1826                 {
1827                         if (!hud_draw_maximized) return;
1828                 }
1829                 else
1830                 {
1831                         if (autocvar_hud_panel_radar == 0) return;
1832                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1833                 }
1834         }
1835
1836         HUD_Panel_UpdateCvars();
1837         HUD_Panel_ApplyFadeAlpha();
1838
1839         float f = 0;
1840
1841         if (hud_panel_radar_maximized && !autocvar__hud_configure)
1842         {
1843                 panel_size = autocvar_hud_panel_radar_maximized_size;
1844                 panel_size_x = bound(0.2, panel_size_x, 1) * vid_conwidth;
1845                 panel_size_y = bound(0.2, panel_size_y, 1) * vid_conheight;
1846                 panel_pos_x = (vid_conwidth - panel_size_x) / 2;
1847                 panel_pos_y = (vid_conheight - panel_size_y) / 2;
1848
1849                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
1850                 if(precache_pic(panel_bg) == "") { panel_bg = "gfx/hud/default/border_default"; } // fallback
1851
1852                 switch(hud_panel_radar_maximized_zoommode)
1853                 {
1854                         default:
1855                         case 0:
1856                                 f = current_zoomfraction;
1857                                 break;
1858                         case 1:
1859                                 f = 1 - current_zoomfraction;
1860                                 break;
1861                         case 2:
1862                                 f = 0;
1863                                 break;
1864                         case 3:
1865                                 f = 1;
1866                                 break;
1867                 }
1868
1869                 switch(hud_panel_radar_maximized_rotation)
1870                 {
1871                         case 0:
1872                                 teamradar_angle = view_angles_y - 90;
1873                                 break;
1874                         default:
1875                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
1876                                 break;
1877                 }
1878         }
1879         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
1880         {
1881                 switch(hud_panel_radar_zoommode)
1882                 {
1883                         default:
1884                         case 0:
1885                                 f = current_zoomfraction;
1886                                 break;
1887                         case 1:
1888                                 f = 1 - current_zoomfraction;
1889                                 break;
1890                         case 2:
1891                                 f = 0;
1892                                 break;
1893                         case 3:
1894                                 f = 1;
1895                                 break;
1896                 }
1897
1898                 switch(hud_panel_radar_rotation)
1899                 {
1900                         case 0:
1901                                 teamradar_angle = view_angles_y - 90;
1902                                 break;
1903                         default:
1904                                 teamradar_angle = 90 * hud_panel_radar_rotation;
1905                                 break;
1906                 }
1907         }
1908
1909         vector pos, mySize;
1910         pos = panel_pos;
1911         mySize = panel_size;
1912
1913         HUD_Panel_DrawBg(1);
1914         if(panel_bg_padding)
1915         {
1916                 pos += '1 1 0' * panel_bg_padding;
1917                 mySize -= '2 2 0' * panel_bg_padding;
1918         }
1919
1920         float color2;
1921         entity tm;
1922         float scale2d, normalsize, bigsize;
1923
1924         teamradar_origin2d = pos + 0.5 * mySize;
1925         teamradar_size2d = mySize;
1926
1927         if(minimapname == "")
1928                 return;
1929
1930         teamradar_loadcvars();
1931
1932         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
1933         teamradar_size2d = mySize;
1934
1935         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
1936
1937         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
1938         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
1939         {
1940                 // max-min distance must fit the radar in any rotation
1941                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
1942         }
1943         else
1944         {
1945                 vector c0, c1, c2, c3, span;
1946                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
1947                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
1948                 c2 = rotate('1 0 0' * mi_min_x + '0 1 0' * mi_max_y, teamradar_angle * DEG2RAD);
1949                 c3 = rotate('1 0 0' * mi_max_x + '0 1 0' * mi_min_y, teamradar_angle * DEG2RAD);
1950                 span = '0 0 0';
1951                 span_x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
1952                 span_y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
1953
1954                 // max-min distance must fit the radar in x=x, y=y
1955                 bigsize = min(
1956                         teamradar_size2d_x * scale2d / (1.05 * span_x),
1957                         teamradar_size2d_y * scale2d / (1.05 * span_y)
1958                 );
1959         }
1960
1961         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
1962         if(bigsize > normalsize)
1963                 normalsize = bigsize;
1964
1965         teamradar_size =
1966                   f * bigsize
1967                 + (1 - f) * normalsize;
1968         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
1969                   f * mi_center
1970                 + (1 - f) * view_origin);
1971
1972         drawsetcliparea(
1973                 pos_x,
1974                 pos_y,
1975                 mySize_x,
1976                 mySize_y
1977         );
1978
1979         draw_teamradar_background(hud_panel_radar_foreground_alpha);
1980
1981         for(tm = world; (tm = find(tm, classname, "radarlink")); )
1982                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
1983         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
1984                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
1985         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
1986         {
1987                 color2 = GetPlayerColor(tm.sv_entnum);
1988                 //if(color == NUM_SPECTATOR || color == color2)
1989                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
1990         }
1991         draw_teamradar_player(view_origin, view_angles, '1 1 1');
1992
1993         drawresetcliparea();
1994 }
1995
1996 // Score (#7)
1997 //
1998 void HUD_UpdatePlayerTeams();
1999 void HUD_Score_Rankings(vector pos, vector mySize, entity me, float team_count)
2000 {
2001         float score;
2002         entity tm = world, pl;
2003 #define SCOREPANEL_MAX_ENTRIES 6
2004 #define SCOREPANEL_ASPECTRATIO 2
2005         float entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize_y/mySize_x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2006         vector fontsize = '1 1 0' * (mySize_y/entries);
2007
2008         vector rgb, score_color;
2009         rgb = '1 1 1';
2010         score_color = '1 1 1';
2011
2012         float name_size = mySize_x*0.75;
2013         float spacing_size = mySize_x*0.04;
2014         const float highlight_alpha = 0.2;
2015         float i = 0, me_printed = 0, first_pl = 0;
2016         string s;
2017         if (autocvar__hud_configure)
2018         {
2019                 float players_per_team = 0;
2020                 if (team_count)
2021                 {
2022                         // show team scores in the first line
2023                         float score_size = mySize_x / team_count;
2024                         players_per_team = max(2, ceil((entries - 1) / team_count));
2025                         for(i=0; i<team_count; ++i) {
2026                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2027                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2028                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize_y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2029                         }
2030                         first_pl = 1;
2031                         pos_y += fontsize_y;
2032                 }
2033                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2034                 for (i=first_pl; i<entries; ++i)
2035                 {
2036                         //simulate my score is lower than all displayed players,
2037                         //so that I don't appear at all showing pure rankings.
2038                         //This is to better show the difference between the 2 ranking views
2039                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2040                         {
2041                                 rgb = '1 1 0';
2042                                 drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2043                                 s = GetPlayerName(player_localnum);
2044                                 score = 7;
2045                         }
2046                         else
2047                         {
2048                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2049                                 score -= 3;
2050                         }
2051
2052                         if (team_count)
2053                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2054                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2055                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2056                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2057                         pos_y += fontsize_y;
2058                 }
2059                 return;
2060         }
2061
2062         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2063                 HUD_UpdatePlayerTeams();
2064         if (team_count)
2065         {
2066                 // show team scores in the first line
2067                 float score_size = mySize_x / team_count;
2068                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2069                         if(tm.team == NUM_SPECTATOR)
2070                                 continue;
2071                         if (tm.team == myteam)
2072                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2073                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2074                         ++i;
2075                 }
2076                 first_pl = 1;
2077                 pos_y += fontsize_y;
2078                 tm = teams.sort_next;
2079         }
2080         i = first_pl;
2081
2082         do
2083         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2084         {
2085                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2086                         continue;
2087
2088                 if (i == entries-1 && !me_printed && pl != me)
2089                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2090                 {
2091                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2092                                 if (pl.team != NUM_SPECTATOR)
2093                                         break;
2094
2095                         if (pl)
2096                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2097                         else
2098                                 rgb = '1 0 0'; //last: red
2099                         pl = me;
2100                 }
2101
2102                 if (pl == me)
2103                 {
2104                         if (i == first_pl)
2105                                 rgb = '0 1 0'; //first: green
2106                         me_printed = 1;
2107                         drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2108                 }
2109                 if (team_count)
2110                         score_color = Team_ColorRGB(pl.team) * 0.8;
2111                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2112                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2113                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2114                 pos_y += fontsize_y;
2115                 ++i;
2116         }
2117         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2118 }
2119
2120 void HUD_Score(void)
2121 {
2122         if(!autocvar__hud_configure)
2123         {
2124                 if(!autocvar_hud_panel_score) return;
2125                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2126         }
2127
2128         HUD_Panel_UpdateCvars();
2129         HUD_Panel_ApplyFadeAlpha();
2130         vector pos, mySize;
2131         pos = panel_pos;
2132         mySize = panel_size;
2133
2134         HUD_Panel_DrawBg(1);
2135         if(panel_bg_padding)
2136         {
2137                 pos += '1 1 0' * panel_bg_padding;
2138                 mySize -= '2 2 0' * panel_bg_padding;
2139         }
2140
2141         float score, distribution = 0;
2142         string sign;
2143         vector distribution_color;
2144         entity tm, pl, me;
2145
2146 #ifdef COMPAT_XON050_ENGINE
2147         me = (spectatee_status > 0) ? playerslots[spectatee_status - 1] : playerslots[player_localentnum - 1];
2148 #else
2149         me = playerslots[player_localentnum - 1];
2150 #endif
2151
2152         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2153                 string timer, distrtimer;
2154
2155                 pl = players.sort_next;
2156                 if(pl == me)
2157                         pl = pl.sort_next;
2158                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2159                         if(pl.scores[ps_primary] == 0)
2160                                 pl = world;
2161
2162                 score = me.(scores[ps_primary]);
2163                 timer = TIME_ENCODED_TOSTRING(score);
2164
2165                 draw_beginBoldFont();
2166                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2167                         // distribution display
2168                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2169
2170                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2171
2172                         if (distribution <= 0) {
2173                                 distribution_color = '0 1 0';
2174                                 sign = "-";
2175                         }
2176                         else {
2177                                 distribution_color = '1 0 0';
2178                                 sign = "+";
2179                         }
2180                         drawstring_aspect(pos + eX * 0.75 * mySize_x, strcat(sign, distrtimer), eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2181                 }
2182                 // race record display
2183                 if (distribution <= 0)
2184                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2185                 drawstring_aspect(pos, timer, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2186                 draw_endBoldFont();
2187         } else if (!teamplay) { // non-teamgames
2188                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2189                 {
2190                         HUD_Score_Rankings(pos, mySize, me, 0);
2191                         return;
2192                 }
2193                 // me vector := [team/connected frags id]
2194                 pl = players.sort_next;
2195                 if(pl == me)
2196                         pl = pl.sort_next;
2197
2198                 if(autocvar__hud_configure)
2199                         distribution = 42;
2200                 else if(pl)
2201                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2202                 else
2203                         distribution = 0;
2204
2205                 score = me.(scores[ps_primary]);
2206                 if(autocvar__hud_configure)
2207                         score = 123;
2208
2209                 if(distribution >= 5)
2210                         distribution_color = eY;
2211                 else if(distribution >= 0)
2212                         distribution_color = '1 1 1';
2213                 else if(distribution >= -5)
2214                         distribution_color = '1 1 0';
2215                 else
2216                         distribution_color = eX;
2217
2218                 string distribution_str;
2219                 distribution_str = ftos(distribution);
2220                 draw_beginBoldFont();
2221                 if (distribution >= 0)
2222                 {
2223                         if (distribution > 0)
2224                                 distribution_str = strcat("+", distribution_str);
2225                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2226                 }
2227                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2228                 drawstring_aspect(pos + eX * 0.75 * mySize_x, distribution_str, eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2229                 draw_endBoldFont();
2230         } else { // teamgames
2231                 float scores_count = 0, row, column, rows = 0, columns = 0;
2232                 local noref vector offset = '0 0 0';
2233                 vector score_pos, score_size; //for scores other than myteam
2234                 if (spectatee_status == -1 || autocvar_hud_panel_score_rankings)
2235                 {
2236                         for(tm = teams.sort_next; tm, tm.team != NUM_SPECTATOR; tm = tm.sort_next)
2237                                 ++scores_count;
2238                         if (autocvar_hud_panel_score_rankings)
2239                         {
2240                                 HUD_Score_Rankings(pos, mySize, me, scores_count);
2241                                 return;
2242                         }
2243                         rows = mySize_y/mySize_x;
2244                         rows = bound(1, floor((sqrt(4 * (3/1) * rows * scores_count + rows * rows) + rows + 0.5) / 2), scores_count);
2245                         //                               ^^^ ammo item aspect goes here
2246
2247                         columns = ceil(scores_count/rows);
2248
2249                         score_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2250
2251                         float newSize;
2252                         if(score_size_x/score_size_y > 3)
2253                         {
2254                                 newSize = 3 * score_size_y;
2255                                 offset_x = score_size_x - newSize;
2256                                 pos_x += offset_x/2;
2257                                 score_size_x = newSize;
2258                         }
2259                         else
2260                         {
2261                                 newSize = 1/3 * score_size_x;
2262                                 offset_y = score_size_y - newSize;
2263                                 pos_y += offset_y/2;
2264                                 score_size_y = newSize;
2265                         }
2266                 }
2267                 else
2268                         score_size = eX * mySize_x*(1/4) + eY * mySize_y*(1/3);
2269
2270                 float max_fragcount;
2271                 max_fragcount = -99;
2272                 draw_beginBoldFont();
2273                 row = column = 0;
2274                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2275                         if(tm.team == NUM_SPECTATOR)
2276                                 continue;
2277                         score = tm.(teamscores[ts_primary]);
2278                         if(autocvar__hud_configure)
2279                                 score = 123;
2280
2281                         if (score > max_fragcount)
2282                                 max_fragcount = score;
2283
2284                         if (spectatee_status == -1)
2285                         {
2286                                 score_pos = pos + eX * column * (score_size_x + offset_x) + eY * row * (score_size_y + offset_y);
2287                                 if (max_fragcount == score)
2288                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2289                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2290                                 ++row;
2291                                 if(row >= rows)
2292                                 {
2293                                         row = 0;
2294                                         ++column;
2295                                 }
2296                         }
2297                         else if(tm.team == myteam) {
2298                                 if (max_fragcount == score)
2299                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2300                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2301                         } else {
2302                                 if (max_fragcount == score)
2303                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2304                                 drawstring_aspect(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2305                                 ++rows;
2306                         }
2307                 }
2308                 draw_endBoldFont();
2309         }
2310 }
2311
2312 // Race timer (#8)
2313 //
2314 void HUD_RaceTimer (void)
2315 {
2316         if(!autocvar__hud_configure)
2317         {
2318                 if(!autocvar_hud_panel_racetimer) return;
2319                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2320                 if(spectatee_status == -1) return;
2321         }
2322
2323         HUD_Panel_UpdateCvars();
2324         HUD_Panel_ApplyFadeAlpha();
2325
2326         draw_beginBoldFont();
2327
2328         vector pos, mySize;
2329         pos = panel_pos;
2330         mySize = panel_size;
2331
2332         HUD_Panel_DrawBg(1);
2333         if(panel_bg_padding)
2334         {
2335                 pos += '1 1 0' * panel_bg_padding;
2336                 mySize -= '2 2 0' * panel_bg_padding;
2337         }
2338
2339         // always force 4:1 aspect
2340         vector newSize = '0 0 0';
2341         if(mySize_x/mySize_y > 4)
2342         {
2343                 newSize_x = 4 * mySize_y;
2344                 newSize_y = mySize_y;
2345
2346                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2347         }
2348         else
2349         {
2350                 newSize_y = 1/4 * mySize_x;
2351                 newSize_x = mySize_x;
2352
2353                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2354         }
2355         mySize = newSize;
2356
2357         float a, t;
2358         string s, forcetime;
2359
2360         if(autocvar__hud_configure)
2361         {
2362                 s = "0:13:37";
2363                 drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.60 0.60 0' * mySize_y), s, '0.60 0.60 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2364                 s = _("^1Intermediate 1 (+15.42)");
2365                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.60 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2366                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2367                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.80 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2368         }
2369         else if(race_checkpointtime)
2370         {
2371                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2372                 s = "";
2373                 forcetime = "";
2374                 if(a > 0) // just hit a checkpoint?
2375                 {
2376                         if(race_checkpoint != 254)
2377                         {
2378                                 if(race_time && race_previousbesttime)
2379                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2380                                 else
2381                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2382                                 if(race_time)
2383                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2384                         }
2385                 }
2386                 else
2387                 {
2388                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2389                         {
2390                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2391                                 if(a > 0) // next one?
2392                                 {
2393                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2394                                 }
2395                         }
2396                 }
2397
2398                 if(s != "" && a > 0)
2399                 {
2400                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2401                 }
2402
2403                 if(race_penaltytime)
2404                 {
2405                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2406                         if(a > 0)
2407                         {
2408                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2409                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.8 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2410                         }
2411                 }
2412
2413                 if(forcetime != "")
2414                 {
2415                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2416                         drawstring_expanding(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(forcetime, FALSE, '1 1 0' * 0.6 * mySize_y), forcetime, '1 1 0' * 0.6 * mySize_y, '1 1 1', panel_fg_alpha, 0, a);
2417                 }
2418                 else
2419                         a = 1;
2420
2421                 if(race_laptime && race_checkpoint != 255)
2422                 {
2423                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2424                         drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.6 0.6 0' * mySize_y), s, '0.6 0.6 0' * mySize_y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2425                 }
2426         }
2427         else
2428         {
2429                 if(race_mycheckpointtime)
2430                 {
2431                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2432                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2433                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2434                 }
2435                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2436                 {
2437                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2438                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2439                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2440                 }
2441
2442                 if(race_penaltytime && !race_penaltyaccumulator)
2443                 {
2444                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2445                         a = bound(0, (1 + t - time), 1);
2446                         if(a > 0)
2447                         {
2448                                 if(time < t)
2449                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2450                                 else
2451                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2452                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2453                         }
2454                 }
2455         }
2456
2457         draw_endBoldFont();
2458 }
2459
2460 // Vote window (#9)
2461 //
2462 float vote_yescount;
2463 float vote_nocount;
2464 float vote_needed;
2465 float vote_highlighted; // currently selected vote
2466
2467 float vote_active; // is there an active vote?
2468 float vote_prev; // previous state of vote_active to check for a change
2469 float vote_alpha;
2470 float vote_change; // "time" when vote_active changed
2471
2472 void HUD_Vote(void)
2473 {
2474         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2475         {
2476                 vote_active = 1;
2477                 if (autocvar__hud_configure)
2478                 {
2479                         vote_yescount = 0;
2480                         vote_nocount = 0;
2481                         print(_("^1You must answer before entering hud configure mode\n"));
2482                         cvar_set("_hud_configure", "0");
2483                 }
2484                 if(vote_called_vote)
2485                         strunzone(vote_called_vote);
2486                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2487                 uid2name_dialog = 1;
2488         }
2489
2490         if(!autocvar__hud_configure)
2491         {
2492                 if(!autocvar_hud_panel_vote) return;
2493
2494                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2495                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2496
2497                 if(panel_bg_alpha_str == "") {
2498                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2499                 }
2500                 panel_bg_alpha = stof(panel_bg_alpha_str);
2501         }
2502         else
2503         {
2504                 vote_yescount = 3;
2505                 vote_nocount = 2;
2506                 vote_needed = 4;
2507         }
2508
2509         string s;
2510         float a;
2511         if(vote_active != vote_prev) {
2512                 vote_change = time;
2513                 vote_prev = vote_active;
2514         }
2515
2516         if(vote_active || autocvar__hud_configure)
2517                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2518         else
2519                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2520
2521         if(!vote_alpha)
2522                 return;
2523
2524         HUD_Panel_UpdateCvars();
2525         HUD_Panel_ApplyFadeAlpha();
2526
2527         if(uid2name_dialog)
2528         {
2529                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2530                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2531         }
2532
2533     // these must be below above block
2534         vector pos, mySize;
2535         pos = panel_pos;
2536         mySize = panel_size;
2537
2538         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2539         HUD_Panel_DrawBg(a);
2540         a = panel_fg_alpha * a;
2541
2542         if(panel_bg_padding)
2543         {
2544                 pos += '1 1 0' * panel_bg_padding;
2545                 mySize -= '2 2 0' * panel_bg_padding;
2546         }
2547
2548         // always force 3:1 aspect
2549         vector newSize = '0 0 0';
2550         if(mySize_x/mySize_y > 3)
2551         {
2552                 newSize_x = 3 * mySize_y;
2553                 newSize_y = mySize_y;
2554
2555                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2556         }
2557         else
2558         {
2559                 newSize_y = 1/3 * mySize_x;
2560                 newSize_x = mySize_x;
2561
2562                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2563         }
2564         mySize = newSize;
2565
2566         s = _("A vote has been called for:");
2567         if(uid2name_dialog)
2568                 s = _("Allow servers to store and display your name?");
2569         drawstring_aspect(pos, s, eX * mySize_x + eY * (2/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2570         s = textShortenToWidth(vote_called_vote, mySize_x, '1 1 0' * mySize_y * (1/8), stringwidth_colors);
2571         if(autocvar__hud_configure)
2572                 s = _("^1Configure the HUD");
2573         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize_y, s, eX * mySize_x + eY * (1.75/8) * mySize_y, a, DRAWFLAG_NORMAL);
2574
2575         // print the yes/no counts
2576     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2577         drawstring_aspect(pos + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '0 1 0', a, DRAWFLAG_NORMAL);
2578     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2579         drawstring_aspect(pos + eX * 0.5 * mySize_x + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '1 0 0', a, DRAWFLAG_NORMAL);
2580
2581         // draw the progress bar backgrounds
2582         drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_back", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2583
2584         // draw the highlights
2585         if(vote_highlighted == 1) {
2586                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5, mySize_y);
2587                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2588         }
2589         else if(vote_highlighted == -1) {
2590                 drawsetcliparea(pos_x + 0.5 * mySize_x, pos_y, mySize_x * 0.5, mySize_y);
2591                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2592         }
2593
2594         // draw the progress bars
2595         if(vote_yescount && vote_needed)
2596         {
2597                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5 * (vote_yescount/vote_needed), mySize_y);
2598                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2599         }
2600
2601         if(vote_nocount && vote_needed)
2602         {
2603                 drawsetcliparea(pos_x + mySize_x - mySize_x * 0.5 * (vote_nocount/vote_needed), pos_y, mySize_x * 0.5, mySize_y);
2604                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2605         }
2606
2607         drawresetcliparea();
2608 }
2609
2610 // Mod icons panel (#10)
2611 //
2612
2613 float mod_active; // is there any active mod icon?
2614
2615 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
2616 {
2617         float stat;
2618         string pic;
2619         vector color;
2620 #ifdef GMQCC
2621         stat = -1;
2622         pic = "";
2623         color = '0 0 0';
2624 #endif
2625         switch(i)
2626         {
2627                 case 0:
2628                         stat = getstati(STAT_REDALIVE);
2629                         pic = "player_red.tga";
2630                         color = '1 0 0';
2631                         break;
2632                 case 1:
2633                         stat = getstati(STAT_BLUEALIVE);
2634                         pic = "player_blue.tga";
2635                         color = '0 0 1';
2636                         break;
2637                 case 2:
2638                         stat = getstati(STAT_YELLOWALIVE);
2639                         pic = "player_yellow.tga";
2640                         color = '1 1 0';
2641                         break;
2642                 default:
2643                 case 3:
2644                         stat = getstati(STAT_PINKALIVE);
2645                         pic = "player_pink.tga";
2646                         color = '1 0 1';
2647                         break;
2648         }
2649
2650         if(mySize_x/mySize_y > aspect_ratio)
2651         {
2652                 i = aspect_ratio * mySize_y;
2653                 myPos_x = myPos_x + (mySize_x - i) / 2;
2654                 mySize_x = i;
2655         }
2656         else
2657         {
2658                 i = 1/aspect_ratio * mySize_x;
2659                 myPos_y = myPos_y + (mySize_y - i) / 2;
2660                 mySize_y = i;
2661         }
2662
2663         if(layout)
2664         {
2665                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2666                 drawstring_aspect(myPos + eX * 0.7 * mySize_x, ftos(stat), eX * 0.3 * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2667         }
2668         else
2669                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2670 }
2671
2672 // Clan Arena and Freeze Tag HUD modicons
2673 void HUD_Mod_CA(vector myPos, vector mySize)
2674 {
2675         mod_active = 1; // required in each mod function that always shows something
2676         entity tm;
2677         float teams_count = 0;
2678         for(tm = teams.sort_next; tm; tm = tm.sort_next)
2679                 if(tm.team != NUM_SPECTATOR)
2680                         ++teams_count;
2681
2682         float layout;
2683         if(gametype == MAPINFO_TYPE_CA)
2684                 layout = autocvar_hud_panel_modicons_ca_layout;
2685         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2686                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2687         float rows, columns, aspect_ratio;
2688         rows = mySize_y/mySize_x;
2689         aspect_ratio = (layout) ? 2 : 1;
2690         rows = bound(1, floor((sqrt((4 * aspect_ratio * teams_count + rows) * rows) + rows + 0.5) / 2), teams_count);
2691         columns = ceil(teams_count/rows);
2692
2693         int i;
2694         float row = 0, column = 0;
2695         vector pos, itemSize;
2696         itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2697         for(i=0; i<teams_count; ++i)
2698         {
2699                 pos = myPos + eX * column * itemSize_x + eY * row * itemSize_y;
2700
2701                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2702
2703                 ++row;
2704                 if(row >= rows)
2705                 {
2706                         row = 0;
2707                         ++column;
2708                 }
2709         }
2710 }
2711
2712 // CTF HUD modicon section
2713 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2714 float redflag_prevstatus, blueflag_prevstatus; // last remembered status
2715 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2716
2717 void HUD_Mod_CTF_Reset(void)
2718 {
2719         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2720 }
2721
2722 void HUD_Mod_CTF(vector pos, vector mySize)
2723 {
2724         vector redflag_pos, blueflag_pos;
2725         vector flag_size;
2726         float f; // every function should have that
2727
2728         float redflag, blueflag; // current status
2729         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2730         float stat_items;
2731
2732         stat_items = getstati(STAT_ITEMS, 0, 24);
2733         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2734         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2735
2736         if(redflag || blueflag)
2737                 mod_active = 1;
2738         else
2739                 mod_active = 0;
2740
2741         if(autocvar__hud_configure)
2742         {
2743                 redflag = 1;
2744                 blueflag = 2;
2745         }
2746
2747         // when status CHANGES, set old status into prevstatus and current status into status
2748         if (redflag != redflag_prevframe)
2749         {
2750                 redflag_statuschange_time = time;
2751                 redflag_prevstatus = redflag_prevframe;
2752                 redflag_prevframe = redflag;
2753         }
2754
2755         if (blueflag != blueflag_prevframe)
2756         {
2757                 blueflag_statuschange_time = time;
2758                 blueflag_prevstatus = blueflag_prevframe;
2759                 blueflag_prevframe = blueflag;
2760         }
2761
2762         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2763         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2764
2765         float BLINK_FACTOR = 0.15;
2766         float BLINK_BASE = 0.85;
2767         // note:
2768         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2769         // thus
2770         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2771         // ensure RMS == 1
2772         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2773
2774         string red_icon, red_icon_prevstatus;
2775         float red_alpha, red_alpha_prevstatus;
2776         red_alpha = red_alpha_prevstatus = 1;
2777         switch(redflag) {
2778                 case 1: red_icon = "flag_red_taken"; break;
2779                 case 2: red_icon = "flag_red_lost"; break;
2780                 case 3: red_icon = "flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2781                 default:
2782                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2783                                 red_icon = "flag_red_shielded";
2784                         else
2785                                 red_icon = string_null;
2786                         break;
2787         }
2788         switch(redflag_prevstatus) {
2789                 case 1: red_icon_prevstatus = "flag_red_taken"; break;
2790                 case 2: red_icon_prevstatus = "flag_red_lost"; break;
2791                 case 3: red_icon_prevstatus = "flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2792                 default:
2793                         if(redflag == 3)
2794                                 red_icon_prevstatus = "flag_red_carrying"; // make it more visible
2795                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2796                                 red_icon_prevstatus = "flag_red_shielded";
2797                         else
2798                                 red_icon_prevstatus = string_null;
2799                         break;
2800         }
2801
2802         string blue_icon, blue_icon_prevstatus;
2803         float blue_alpha, blue_alpha_prevstatus;
2804         blue_alpha = blue_alpha_prevstatus = 1;
2805         switch(blueflag) {
2806                 case 1: blue_icon = "flag_blue_taken"; break;
2807                 case 2: blue_icon = "flag_blue_lost"; break;
2808                 case 3: blue_icon = "flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2809                 default:
2810                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2811                                 blue_icon = "flag_blue_shielded";
2812                         else
2813                                 blue_icon = string_null;
2814                         break;
2815         }
2816         switch(blueflag_prevstatus) {
2817                 case 1: blue_icon_prevstatus = "flag_blue_taken"; break;
2818                 case 2: blue_icon_prevstatus = "flag_blue_lost"; break;
2819                 case 3: blue_icon_prevstatus = "flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2820                 default:
2821                         if(blueflag == 3)
2822                                 blue_icon_prevstatus = "flag_blue_carrying"; // make it more visible
2823                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2824                                 blue_icon_prevstatus = "flag_blue_shielded";
2825                         else
2826                                 blue_icon_prevstatus = string_null;
2827                         break;
2828         }
2829
2830         if(mySize_x > mySize_y) {
2831                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2832                         redflag_pos = pos;
2833                         blueflag_pos = pos + eX * 0.5 * mySize_x;
2834                 } else {
2835                         blueflag_pos = pos;
2836                         redflag_pos = pos + eX * 0.5 * mySize_x;
2837                 }
2838                 flag_size = eX * 0.5 * mySize_x + eY * mySize_y;
2839         } else {
2840                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2841                         redflag_pos = pos;
2842                         blueflag_pos = pos + eY * 0.5 * mySize_y;
2843                 } else {
2844                         blueflag_pos = pos;
2845                         redflag_pos = pos + eY * 0.5 * mySize_y;
2846                 }
2847                 flag_size = eY * 0.5 * mySize_y + eX * mySize_x;
2848         }
2849
2850         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
2851         if(red_icon_prevstatus && f < 1)
2852                 drawpic_aspect_skin_expanding(redflag_pos, red_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2853         if(red_icon)
2854                 drawpic_aspect_skin(redflag_pos, red_icon, flag_size, '1 1 1', panel_fg_alpha * red_alpha * f, DRAWFLAG_NORMAL);
2855
2856         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
2857         if(blue_icon_prevstatus && f < 1)
2858                 drawpic_aspect_skin_expanding(blueflag_pos, blue_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2859         if(blue_icon)
2860                 drawpic_aspect_skin(blueflag_pos, blue_icon, flag_size, '1 1 1', panel_fg_alpha * blue_alpha * f, DRAWFLAG_NORMAL);
2861 }
2862
2863 // Keyhunt HUD modicon section
2864 float kh_runheretime;
2865
2866 void HUD_Mod_KH_Reset(void)
2867 {
2868         kh_runheretime = 0;
2869 }
2870
2871 void HUD_Mod_KH(vector pos, vector mySize)
2872 {
2873         mod_active = 1; // keyhunt should never hide the mod icons panel
2874         float kh_keys;
2875         float keyteam;
2876         float a, aa;
2877         vector p = '0 0 0', pa, kh_size = '0 0 0', kh_asize = '0 0 0';
2878
2879         kh_keys = getstati(STAT_KH_KEYS);
2880
2881         p_x = pos_x;
2882         if(mySize_x > mySize_y)
2883         {
2884                 p_y = pos_y + 0.25 * mySize_y;
2885                 pa = p - eY * 0.25 * mySize_y;
2886
2887                 kh_size_x = mySize_x * 0.25;
2888                 kh_size_y = 0.75 * mySize_y;
2889                 kh_asize_x = mySize_x * 0.25;
2890                 kh_asize_y = mySize_y * 0.25;
2891         }
2892         else
2893         {
2894                 p_y = pos_y + 0.125 * mySize_y;
2895                 pa = p - eY * 0.125 * mySize_y;
2896
2897                 kh_size_x = mySize_x * 0.5;
2898                 kh_size_y = 0.375 * mySize_y;
2899                 kh_asize_x = mySize_x * 0.5;
2900                 kh_asize_y = mySize_y * 0.125;
2901         }
2902
2903         float i, key;
2904
2905         float keycount;
2906         keycount = 0;
2907         for(i = 0; i < 4; ++i)
2908         {
2909                 key = floor(kh_keys / pow(32, i)) & 31;
2910                 keyteam = key - 1;
2911                 if(keyteam == 30 && keycount <= 4)
2912                         keycount += 4;
2913                 if(keyteam == myteam || keyteam == -1 || keyteam == 30)
2914                         keycount += 1;
2915         }
2916
2917         // this yields 8 exactly if "RUN HERE" shows
2918
2919         if(keycount == 8)
2920         {
2921                 if(!kh_runheretime)
2922                         kh_runheretime = time;
2923                 pa_y -= fabs(sin((time - kh_runheretime) * 3.5)) * 6; // make the arrows jump in case of RUN HERE
2924         }
2925         else
2926                 kh_runheretime = 0;
2927
2928         for(i = 0; i < 4; ++i)
2929         {
2930                 key = floor(kh_keys / pow(32, i)) & 31;
2931                 keyteam = key - 1;
2932                 switch(keyteam)
2933                 {
2934                         case 30: // my key
2935                                 keyteam = myteam;
2936                                 a = 1;
2937                                 aa = 1;
2938                                 break;
2939                         case -1: // no key
2940                                 a = 0;
2941                                 aa = 0;
2942                                 break;
2943                         default: // owned or dropped
2944                                 a = 0.2;
2945                                 aa = 0.5;
2946                                 break;
2947                 }
2948                 a = a * panel_fg_alpha;
2949                 aa = aa * panel_fg_alpha;
2950                 if(a > 0)
2951                 {
2952                         switch(keyteam)
2953                         {
2954                                 case NUM_TEAM_1:
2955                                         drawpic_aspect_skin(pa, "kh_redarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2956                                         break;
2957                                 case NUM_TEAM_2:
2958                                         drawpic_aspect_skin(pa, "kh_bluearrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2959                                         break;
2960                                 case NUM_TEAM_3:
2961                                         drawpic_aspect_skin(pa, "kh_yellowarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2962                                         break;
2963                                 case NUM_TEAM_4:
2964                                         drawpic_aspect_skin(pa, "kh_pinkarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2965                                         break;
2966                                 default:
2967                                         break;
2968                         }
2969                         switch(i) // YAY! switch(i) inside a for loop for i. DailyWTF, here we come!
2970                         {
2971                                 case 0:
2972                                         drawpic_aspect_skin(p, "kh_red", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2973                                         break;
2974                                 case 1:
2975                                         drawpic_aspect_skin(p, "kh_blue", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2976                                         break;
2977                                 case 2:
2978                                         drawpic_aspect_skin(p, "kh_yellow", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2979                                         break;
2980                                 case 3:
2981                                         drawpic_aspect_skin(p, "kh_pink", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2982                                         break;
2983                         }
2984                 }
2985                 if(mySize_x > mySize_y)
2986                 {
2987                         p_x += 0.25 * mySize_x;
2988                         pa_x += 0.25 * mySize_x;
2989                 }
2990                 else
2991                 {
2992                         if(i == 1)
2993                         {
2994                                 p_y = pos_y + 0.625 * mySize_y;
2995                                 pa_y = pos_y + 0.5 * mySize_y;
2996                                 p_x = pos_x;
2997                                 pa_x = pos_x;
2998                         }
2999                         else
3000                         {
3001                                 p_x += 0.5 * mySize_x;
3002                                 pa_x += 0.5 * mySize_x;
3003                         }
3004                 }
3005         }
3006 }
3007
3008 // Keepaway HUD mod icon
3009 float kaball_prevstatus; // last remembered status
3010 float kaball_statuschange_time; // time when the status changed
3011
3012 // we don't need to reset for keepaway since it immediately
3013 // autocorrects prevstatus as to if the player has the ball or not
3014
3015 void HUD_Mod_Keepaway(vector pos, vector mySize)
3016 {
3017         mod_active = 1; // keepaway should always show the mod HUD
3018
3019         float BLINK_FACTOR = 0.15;
3020         float BLINK_BASE = 0.85;
3021         float BLINK_FREQ = 5;
3022         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
3023
3024         float stat_items = getstati(STAT_ITEMS, 0, 24);
3025         float kaball = (stat_items/IT_KEY1) & 1;
3026
3027         if(kaball != kaball_prevstatus)
3028         {
3029                 kaball_statuschange_time = time;
3030                 kaball_prevstatus = kaball;
3031         }
3032
3033         vector kaball_pos, kaball_size;
3034
3035         if(mySize_x > mySize_y) {
3036                 kaball_pos = pos + eX * 0.25 * mySize_x;
3037                 kaball_size = eX * 0.5 * mySize_x + eY * mySize_y;
3038         } else {
3039                 kaball_pos = pos + eY * 0.25 * mySize_y;
3040                 kaball_size = eY * 0.5 * mySize_y + eX * mySize_x;
3041         }
3042
3043         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3044         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3045
3046         if(kaball_prevstatus && f < 1)
3047                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3048
3049         if(kaball)
3050                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3051 }
3052
3053
3054 // Nexball HUD mod icon
3055 void HUD_Mod_NexBall(vector pos, vector mySize)
3056 {
3057         float stat_items, nb_pb_starttime, dt, p;
3058
3059         stat_items = getstati(STAT_ITEMS, 0, 24);
3060         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3061
3062         if (stat_items & IT_KEY1)
3063                 mod_active = 1;
3064         else
3065                 mod_active = 0;
3066
3067         //Manage the progress bar if any
3068         if (nb_pb_starttime > 0)
3069         {
3070                 dt = mod(time - nb_pb_starttime, nb_pb_period);
3071                 // one period of positive triangle
3072                 p = 2 * dt / nb_pb_period;
3073                 if (p > 1)
3074                         p = 2 - p;
3075
3076                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize_x <= mySize_y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3077         }
3078
3079         if (stat_items & IT_KEY1)
3080                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3081 }
3082
3083 // Race/CTS HUD mod icons
3084 float crecordtime_prev; // last remembered crecordtime
3085 float crecordtime_change_time; // time when crecordtime last changed
3086 float srecordtime_prev; // last remembered srecordtime
3087 float srecordtime_change_time; // time when srecordtime last changed
3088
3089 float race_status_time;
3090 float race_status_prev;
3091 string race_status_name_prev;
3092 void HUD_Mod_Race(vector pos, vector mySize)
3093 {
3094         mod_active = 1; // race should never hide the mod icons panel
3095         entity me;
3096         me = playerslots[player_localnum];
3097         float t, score;
3098         float f; // yet another function has this
3099         score = me.(scores[ps_primary]);
3100
3101         if not((scores_flags[ps_primary] & SFL_TIME) && !teamplay) // race/cts record display on HUD
3102                 return; // no records in the actual race
3103
3104         // clientside personal record
3105         string rr;
3106         if(gametype == MAPINFO_TYPE_CTS)
3107                 rr = CTS_RECORD;
3108         else
3109                 rr = RACE_RECORD;
3110         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3111
3112         if(score && (score < t || !t)) {
3113                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3114                 if(autocvar_cl_autodemo_delete_keeprecords)
3115                 {
3116                         f = autocvar_cl_autodemo_delete;
3117                         f &~= 1;
3118                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3119                 }
3120         }
3121
3122         if(t != crecordtime_prev) {
3123                 crecordtime_prev = t;
3124                 crecordtime_change_time = time;
3125         }
3126
3127         vector textPos, medalPos;
3128         float squareSize;
3129         if(mySize_x > mySize_y) {
3130                 // text on left side
3131                 squareSize = min(mySize_y, mySize_x/2);
3132                 textPos = pos + eX * 0.5 * max(0, mySize_x/2 - squareSize) + eY * 0.5 * (mySize_y - squareSize);
3133                 medalPos = pos + eX * 0.5 * max(0, mySize_x/2 - squareSize) + eX * 0.5 * mySize_x + eY * 0.5 * (mySize_y - squareSize);
3134         } else {
3135                 // text on top
3136                 squareSize = min(mySize_x, mySize_y/2);
3137                 textPos = pos + eY * 0.5 * max(0, mySize_y/2 - squareSize) + eX * 0.5 * (mySize_x - squareSize);
3138                 medalPos = pos + eY * 0.5 * max(0, mySize_y/2 - squareSize) + eY * 0.5 * mySize_y + eX * 0.5 * (mySize_x - squareSize);
3139         }
3140
3141         f = time - crecordtime_change_time;
3142
3143         if (f > 1) {
3144                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3145                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3146         } else {
3147                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3148                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3149                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3150                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3151         }
3152
3153         // server record
3154         t = race_server_record;
3155         if(t != srecordtime_prev) {
3156                 srecordtime_prev = t;
3157                 srecordtime_change_time = time;
3158         }
3159         f = time - srecordtime_change_time;
3160
3161         if (f > 1) {
3162                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3163                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3164         } else {
3165                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3166                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3167                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3168                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3169         }
3170
3171         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3172                 race_status_time = time + 5;
3173                 race_status_prev = race_status;
3174                 if (race_status_name_prev)
3175                         strunzone(race_status_name_prev);
3176                 race_status_name_prev = strzone(race_status_name);
3177         }
3178
3179         // race "awards"
3180         float a;
3181         a = bound(0, race_status_time - time, 1);
3182
3183         string s;
3184         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3185
3186         float rank;
3187         if(race_status > 0)
3188                 rank = race_CheckName(race_status_name);
3189         else
3190                 rank = 0;
3191         string rankname;
3192         rankname = count_ordinal(rank);
3193
3194         vector namepos;
3195         namepos = medalPos + '0 0.8 0' * squareSize;
3196         vector rankpos;
3197         rankpos = medalPos + '0 0.15 0' * squareSize;
3198
3199         if(race_status == 0)
3200                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3201         else if(race_status == 1) {
3202                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3203                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3204                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3205         } else if(race_status == 2) {
3206                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3207                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3208                 else
3209                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3210                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3211                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3212         } else if(race_status == 3) {
3213                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3214                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3215                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3216         }
3217
3218         if (race_status_time - time <= 0) {
3219                 race_status_prev = -1;
3220                 race_status = -1;
3221                 if(race_status_name)
3222                         strunzone(race_status_name);
3223                 race_status_name = string_null;
3224                 if(race_status_name_prev)
3225                         strunzone(race_status_name_prev);
3226                 race_status_name_prev = string_null;
3227         }
3228 }
3229
3230 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
3231 {
3232         float stat, pps_ratio;
3233         string pic;
3234         vector color;
3235 #ifdef GMQCC
3236         stat = -1;
3237         pic = "";
3238         color = '0 0 0';
3239 #endif
3240         switch(i)
3241         {
3242                 case 0:
3243                         stat = getstatf(STAT_DOM_PPS_RED);
3244                         pic = "dom_icon_red";
3245                         color = '1 0 0';
3246                         break;
3247                 case 1:
3248                         stat = getstatf(STAT_DOM_PPS_BLUE);
3249                         pic = "dom_icon_blue";
3250                         color = '0 0 1';
3251                         break;
3252                 case 2:
3253                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3254                         pic = "dom_icon_yellow";
3255                         color = '1 1 0';
3256                         break;
3257                 default:
3258                 case 3:
3259                         stat = getstatf(STAT_DOM_PPS_PINK);
3260                         pic = "dom_icon_pink";
3261                         color = '1 0 1';
3262                         break;
3263         }
3264         pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3265
3266         if(mySize_x/mySize_y > aspect_ratio)
3267         {
3268                 i = aspect_ratio * mySize_y;
3269                 myPos_x = myPos_x + (mySize_x - i) / 2;
3270                 mySize_x = i;
3271         }
3272         else
3273         {
3274                 i = 1/aspect_ratio * mySize_x;
3275                 myPos_y = myPos_y + (mySize_y - i) / 2;
3276                 mySize_y = i;
3277         }
3278
3279         if (layout) // show text too
3280         {
3281                 //draw the text
3282                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3283                 if (layout == 2) // average pps
3284                         drawstring_aspect(myPos + eX * mySize_y, ftos_decimals(stat, 2), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3285                 else // percentage of average pps
3286                         drawstring_aspect(myPos + eX * mySize_y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3287         }
3288
3289         //draw the icon
3290         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3291         if (stat > 0)
3292         {
3293                 drawsetcliparea(myPos_x, myPos_y + mySize_y * (1 - pps_ratio), mySize_y, mySize_y * pps_ratio);
3294                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3295                 drawresetcliparea();
3296         }
3297 }
3298
3299 void HUD_Mod_Dom(vector myPos, vector mySize)
3300 {
3301         mod_active = 1; // required in each mod function that always shows something
3302         entity tm;
3303         float teams_count = 0;
3304         for(tm = teams.sort_next; tm; tm = tm.sort_next)
3305                 if(tm.team != NUM_SPECTATOR)
3306                         ++teams_count;
3307
3308         float layout = autocvar_hud_panel_modicons_dom_layout;
3309         float rows, columns, aspect_ratio;
3310         rows = mySize_y/mySize_x;
3311         aspect_ratio = (layout) ? 3 : 1;
3312         rows = bound(1, floor((sqrt((4 * aspect_ratio * teams_count + rows) * rows) + rows + 0.5) / 2), teams_count);
3313         columns = ceil(teams_count/rows);
3314
3315         int i;
3316         float row = 0, column = 0;
3317         vector pos, itemSize;
3318         itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
3319         for(i=0; i<teams_count; ++i)
3320         {
3321                 pos = myPos + eX * column * itemSize_x + eY * row * itemSize_y;
3322
3323                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3324
3325                 ++row;
3326                 if(row >= rows)
3327                 {
3328                         row = 0;
3329                         ++column;
3330                 }
3331         }
3332 }
3333
3334 float mod_prev; // previous state of mod_active to check for a change
3335 float mod_alpha;
3336 float mod_change; // "time" when mod_active changed
3337
3338 void HUD_ModIcons(void)
3339 {
3340         if(!autocvar__hud_configure)
3341         {
3342                 if(!autocvar_hud_panel_modicons) return;
3343                 if (gametype != MAPINFO_TYPE_CTF && gametype != MAPINFO_TYPE_KEYHUNT && gametype != MAPINFO_TYPE_NEXBALL && gametype != MAPINFO_TYPE_CTS && gametype != MAPINFO_TYPE_RACE && gametype != MAPINFO_TYPE_CA && gametype != MAPINFO_TYPE_FREEZETAG && gametype != MAPINFO_TYPE_KEEPAWAY && gametype != MAPINFO_TYPE_DOMINATION) return;
3344         }
3345
3346         HUD_Panel_UpdateCvars();
3347         HUD_Panel_ApplyFadeAlpha();
3348
3349         draw_beginBoldFont();
3350
3351         vector pos, mySize;
3352         pos = panel_pos;
3353         mySize = panel_size;
3354
3355         if(mod_active != mod_prev) {
3356                 mod_change = time;
3357                 mod_prev = mod_active;
3358         }
3359
3360         if(mod_active || autocvar__hud_configure)
3361                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3362         else
3363                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3364
3365         if(mod_alpha)
3366                 HUD_Panel_DrawBg(mod_alpha);
3367
3368         if(panel_bg_padding)
3369         {
3370                 pos += '1 1 0' * panel_bg_padding;
3371                 mySize -= '2 2 0' * panel_bg_padding;
3372         }
3373
3374         // these MUST be ran in order to update mod_active
3375         if(gametype == MAPINFO_TYPE_KEYHUNT)
3376                 HUD_Mod_KH(pos, mySize);
3377         else if(gametype == MAPINFO_TYPE_CTF || autocvar__hud_configure)
3378                 HUD_Mod_CTF(pos, mySize); // forcealpha only needed for ctf icons, as only they are shown in config mode
3379         else if(gametype == MAPINFO_TYPE_NEXBALL)
3380                 HUD_Mod_NexBall(pos, mySize);
3381         else if(gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE)
3382                 HUD_Mod_Race(pos, mySize);
3383         else if(gametype == MAPINFO_TYPE_CA || gametype == MAPINFO_TYPE_FREEZETAG)
3384                 HUD_Mod_CA(pos, mySize);
3385         else if(gametype == MAPINFO_TYPE_DOMINATION)
3386                 HUD_Mod_Dom(pos, mySize);
3387         else if(gametype == MAPINFO_TYPE_KEEPAWAY)
3388                 HUD_Mod_Keepaway(pos, mySize);
3389
3390         draw_endBoldFont();
3391 }
3392
3393 // Draw pressed keys (#11)
3394 //
3395 void HUD_PressedKeys(void)
3396 {
3397         if(!autocvar__hud_configure)
3398         {
3399                 if(!autocvar_hud_panel_pressedkeys) return;
3400                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3401         }
3402
3403         HUD_Panel_UpdateCvars();
3404         HUD_Panel_ApplyFadeAlpha();
3405         vector pos, mySize;
3406         pos = panel_pos;
3407         mySize = panel_size;
3408
3409         HUD_Panel_DrawBg(1);
3410         if(panel_bg_padding)
3411         {
3412                 pos += '1 1 0' * panel_bg_padding;
3413                 mySize -= '2 2 0' * panel_bg_padding;
3414         }
3415
3416         // force custom aspect
3417         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3418         if(aspect)
3419         {
3420                 vector newSize = '0 0 0';
3421                 if(mySize_x/mySize_y > aspect)
3422                 {
3423                         newSize_x = aspect * mySize_y;
3424                         newSize_y = mySize_y;
3425
3426                         pos_x = pos_x + (mySize_x - newSize_x) / 2;
3427                 }
3428                 else
3429                 {
3430                         newSize_y = 1/aspect * mySize_x;
3431                         newSize_x = mySize_x;
3432
3433                         pos_y = pos_y + (mySize_y - newSize_y) / 2;
3434                 }
3435                 mySize = newSize;
3436         }
3437
3438         vector keysize;
3439         keysize = eX * mySize_x * (1/3.0) + eY * mySize_y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3440         float pressedkeys;
3441         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3442
3443         if(autocvar_hud_panel_pressedkeys_attack)
3444         {
3445                 drawpic_aspect_skin(pos + eX * keysize_x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3446                 drawpic_aspect_skin(pos + eX * keysize_x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3447                 pos_y += keysize_y;
3448         }
3449
3450         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3451         drawpic_aspect_skin(pos + eX * keysize_x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3452         drawpic_aspect_skin(pos + eX * keysize_x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3453         pos_y += keysize_y;
3454         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3455         drawpic_aspect_skin(pos + eX * keysize_x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3456         drawpic_aspect_skin(pos + eX * keysize_x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3457 }
3458
3459 // Handle chat as a panel (#12)
3460 //
3461 void HUD_Chat(void)
3462 {
3463         if(!autocvar__hud_configure)
3464         {
3465                 if (!autocvar_hud_panel_chat)
3466                 {
3467                         if (!autocvar_con_chatrect)
3468                                 cvar_set("con_chatrect", "0");
3469                         return;
3470                 }
3471                 if(autocvar__con_chat_maximized)
3472                         if(!hud_draw_maximized) return;
3473         }
3474
3475         HUD_Panel_UpdateCvars();
3476         HUD_Panel_ApplyFadeAlpha();
3477
3478         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3479         {
3480                 panel_pos_y = panel_bg_border;
3481                 panel_size_y = vid_conheight - panel_bg_border * 2;
3482                 if(panel_bg == "0") // force a border when maximized
3483                 {
3484                         if(precache_pic(panel_bg) == "") {
3485                                 panel_bg = strcat(hud_skin_path, "/border_default");
3486                                 if(precache_pic(panel_bg) == "") {
3487                                         panel_bg = "gfx/hud/default/border_default";
3488                                 }
3489                         }
3490                 }
3491                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3492         }
3493
3494         vector pos, mySize;
3495         pos = panel_pos;
3496         mySize = panel_size;
3497
3498         HUD_Panel_DrawBg(1);
3499
3500         if(panel_bg_padding)
3501         {
3502                 pos += '1 1 0' * panel_bg_padding;
3503                 mySize -= '2 2 0' * panel_bg_padding;
3504         }
3505
3506         if (!autocvar_con_chatrect)
3507                 cvar_set("con_chatrect", "1");
3508
3509         cvar_set("con_chatrect_x", ftos(pos_x/vid_conwidth));
3510         cvar_set("con_chatrect_y", ftos(pos_y/vid_conheight));
3511
3512         cvar_set("con_chatwidth", ftos(mySize_x/vid_conwidth));
3513         cvar_set("con_chat", ftos(floor(mySize_y/autocvar_con_chatsize - 0.5)));
3514
3515         if(autocvar__hud_configure)
3516         {
3517                 vector chatsize;
3518                 chatsize = '1 1 0' * autocvar_con_chatsize;
3519                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3520                 float i, a;
3521                 for(i = 0; i < autocvar_con_chat; ++i)
3522                 {
3523                         if(i == autocvar_con_chat - 1)
3524                                 a = panel_fg_alpha;
3525                         else
3526                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3527                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize_x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3528                         pos_y += chatsize_y;
3529                 }
3530         }
3531 }
3532
3533 // Engine info panel (#13)
3534 //
3535 float prevfps;
3536 float prevfps_time;
3537 float framecounter;
3538
3539 float frametimeavg;
3540 float frametimeavg1; // 1 frame ago
3541 float frametimeavg2; // 2 frames ago
3542 void HUD_EngineInfo(void)
3543 {
3544         if(!autocvar__hud_configure)
3545         {
3546                 if(!autocvar_hud_panel_engineinfo) return;
3547         }
3548
3549         HUD_Panel_UpdateCvars();
3550         HUD_Panel_ApplyFadeAlpha();
3551         vector pos, mySize;
3552         pos = panel_pos;
3553         mySize = panel_size;
3554
3555         HUD_Panel_DrawBg(1);
3556         if(panel_bg_padding)
3557         {
3558                 pos += '1 1 0' * panel_bg_padding;
3559                 mySize -= '2 2 0' * panel_bg_padding;
3560         }
3561
3562         float currentTime = gettime(GETTIME_REALTIME);
3563         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3564         {
3565                 float currentframetime = currentTime - prevfps_time;
3566                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3567                 frametimeavg2 = frametimeavg1;
3568                 frametimeavg1 = frametimeavg;
3569
3570                 float weight;
3571                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3572                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3573                 {
3574                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3575                                 prevfps = (1/currentframetime);
3576                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3577                 }
3578                 prevfps_time = currentTime;
3579         }
3580         else
3581         {
3582                 framecounter += 1;
3583                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3584                 {
3585                         prevfps = framecounter/(currentTime - prevfps_time);
3586                         framecounter = 0;
3587                         prevfps_time = currentTime;
3588                 }
3589         }
3590
3591         vector color;
3592         color = HUD_Get_Num_Color (prevfps, 100);
3593         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3594 }
3595
3596 // Info messages panel (#14)
3597 //
3598 #define drawInfoMessage(s)\
3599         if(autocvar_hud_panel_infomessages_flip)\
3600                 o_x = pos_x + mySize_x - stringwidth(s, TRUE, fontsize);\
3601         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);\
3602         o_y += fontsize_y;
3603 void HUD_InfoMessages(void)
3604 {
3605         if(!autocvar__hud_configure)
3606         {
3607                 if(!autocvar_hud_panel_infomessages) return;
3608         }
3609
3610         HUD_Panel_UpdateCvars();
3611         HUD_Panel_ApplyFadeAlpha();
3612         vector pos, mySize;
3613         pos = panel_pos;
3614         mySize = panel_size;
3615
3616         HUD_Panel_DrawBg(1);
3617         if(panel_bg_padding)
3618         {
3619                 pos += '1 1 0' * panel_bg_padding;
3620                 mySize -= '2 2 0' * panel_bg_padding;
3621         }
3622
3623         // always force 5:1 aspect
3624         vector newSize = '0 0 0';
3625         if(mySize_x/mySize_y > 5)
3626         {
3627                 newSize_x = 5 * mySize_y;
3628                 newSize_y = mySize_y;
3629
3630                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
3631         }
3632         else
3633         {
3634                 newSize_y = 1/5 * mySize_x;
3635                 newSize_x = mySize_x;
3636
3637                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
3638         }
3639
3640         mySize = newSize;
3641         entity tm;
3642         vector o;
3643         o = pos;
3644
3645         vector fontsize;
3646         fontsize = '0.20 0.20 0' * mySize_y;
3647
3648         float a;
3649         a = panel_fg_alpha;
3650
3651         string s;
3652         if(!autocvar__hud_configure)
3653         {
3654                 if(spectatee_status && !intermission)
3655                 {
3656                         a = 1;
3657                         if(spectatee_status == -1)
3658                                 s = _("^1Observing");
3659                         else
3660 #ifdef COMPAT_XON050_ENGINE
3661                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(spectatee_status - 1));
3662 #else
3663                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(player_localentnum - 1));
3664 #endif
3665                         drawInfoMessage(s)
3666
3667                         if(spectatee_status == -1)
3668                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3669                         else
3670                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3671                         drawInfoMessage(s)
3672
3673                         if(spectatee_status == -1)
3674                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3675                         else
3676                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3677                         drawInfoMessage(s)
3678
3679                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3680                         drawInfoMessage(s)
3681
3682                         if(gametype == MAPINFO_TYPE_ARENA)
3683                                 s = _("^1Wait for your turn to join");
3684                         else if(gametype == MAPINFO_TYPE_LMS)
3685                         {
3686                                 entity sk;
3687                                 sk = playerslots[player_localnum];
3688                                 if(sk.(scores[ps_primary]) >= 666)
3689                                         s = _("^1Match has already begun");
3690                                 else if(sk.(scores[ps_primary]) > 0)
3691                                         s = _("^1You have no more lives left");
3692                                 else
3693                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3694                         }
3695                         else
3696                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3697                         drawInfoMessage(s)
3698
3699                         //show restart countdown:
3700                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3701                                 float countdown;
3702                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3703                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3704                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3705                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3706                                 o_y += fontsize_y;
3707                         }
3708                 }
3709                 if(warmup_stage && !intermission)
3710                 {
3711                         s = _("^2Currently in ^1warmup^2 stage!");
3712                         drawInfoMessage(s)
3713                 }
3714
3715                 string blinkcolor;
3716                 if(mod(time, 1) >= 0.5)
3717                         blinkcolor = "^1";
3718                 else
3719                         blinkcolor = "^3";
3720
3721                 if(ready_waiting && !intermission && !spectatee_status)
3722                 {
3723                         if(ready_waiting_for_me)
3724                         {
3725                                 if(warmup_stage)
3726                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3727                                 else
3728                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3729                         }
3730                         else
3731                         {
3732                                 if(warmup_stage)
3733                                         s = _("^2Waiting for others to ready up to end warmup...");
3734                                 else
3735                                         s = _("^2Waiting for others to ready up...");
3736                         }
3737                         drawInfoMessage(s)
3738                 }
3739                 else if(warmup_stage && !intermission && !spectatee_status)
3740                 {
3741                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3742                         drawInfoMessage(s)
3743                 }
3744
3745                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3746                 {
3747                         float ts_min = 0, ts_max = 0;
3748                         tm = teams.sort_next;
3749                         if (tm)
3750                         {
3751                                 for(; tm.sort_next; tm = tm.sort_next)
3752                                 {
3753                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3754                                                 continue;
3755                                         if(!ts_min) ts_min = tm.team_size;
3756                                         else ts_min = min(ts_min, tm.team_size);
3757                                         if(!ts_max) ts_max = tm.team_size;
3758                                         else ts_max = max(ts_max, tm.team_size);
3759                                 }
3760                                 if ((ts_max - ts_min) > 1)
3761                                 {
3762                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3763                                         tm = GetTeam(myteam, false);
3764                                         if (tm)
3765                                         if (tm.team != NUM_SPECTATOR)
3766                                         if (tm.team_size == ts_max)
3767                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3768                                         drawInfoMessage(s)
3769                                 }
3770                         }
3771                 }
3772         }
3773         else
3774         {
3775                 s = _("^7Press ^3ESC ^7to show HUD options.");
3776                 drawInfoMessage(s)
3777                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3778                 drawInfoMessage(s)
3779                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3780                 drawInfoMessage(s)
3781                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3782                 drawInfoMessage(s)
3783         }
3784 }
3785
3786 // Physics panel (#15)
3787 //
3788 vector acc_prevspeed;
3789 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3790 void HUD_Physics(void)
3791 {
3792         if(!autocvar__hud_configure)
3793         {
3794                 if(!autocvar_hud_panel_physics) return;
3795                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
3796                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
3797         }
3798
3799         HUD_Panel_UpdateCvars();
3800         HUD_Panel_ApplyFadeAlpha();
3801
3802         draw_beginBoldFont();
3803
3804         HUD_Panel_DrawBg(1);
3805         if(panel_bg_padding)
3806         {
3807                 panel_pos += '1 1 0' * panel_bg_padding;
3808                 panel_size -= '2 2 0' * panel_bg_padding;
3809         }
3810
3811         float acceleration_progressbar_scale = 0;
3812         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
3813                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
3814
3815         float text_scale;
3816         if (autocvar_hud_panel_physics_text_scale <= 0)
3817                 text_scale = 1;
3818         else
3819                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
3820
3821         //compute speed
3822         float speed, conversion_factor;
3823         string unit;
3824
3825         switch(autocvar_hud_panel_physics_speed_unit)
3826         {
3827                 default:
3828                 case 1:
3829                         unit = _(" qu/s");
3830                         conversion_factor = 1.0;
3831                         break;
3832                 case 2:
3833                         unit = _(" m/s");
3834                         conversion_factor = 0.0254;
3835                         break;
3836                 case 3:
3837                         unit = _(" km/h");
3838                         conversion_factor = 0.0254 * 3.6;
3839                         break;
3840                 case 4:
3841                         unit = _(" mph");
3842                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
3843                         break;
3844                 case 5:
3845                         unit = _(" knots");
3846                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
3847                         break;
3848         }
3849
3850         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
3851
3852         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
3853         if (autocvar__hud_configure)
3854                 speed = floor( max_speed * 0.65 + 0.5 );
3855         else if(autocvar_hud_panel_physics_speed_vertical)
3856                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
3857         else
3858                 speed = floor( vlen(vel - vel_z * '0 0 1') * conversion_factor + 0.5 );
3859
3860         //compute acceleration
3861         float acceleration, f;
3862         if (autocvar__hud_configure)
3863                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
3864         else
3865         {
3866                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
3867                 f = time - acc_prevtime;
3868                 if(autocvar_hud_panel_physics_acceleration_vertical)
3869                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
3870                 else
3871                         acceleration = (vlen(vel - '0 0 1' * vel_z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed_z));
3872
3873                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
3874
3875                 acc_prevspeed = vel;
3876                 acc_prevtime = time;
3877
3878                 f = bound(0, f * 10, 1);
3879                 acc_avg = acc_avg * (1 - f) + acceleration * f;
3880         }
3881
3882         //compute layout
3883         float panel_ar = panel_size_x/panel_size_y;
3884         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
3885         if (panel_ar >= 5 && !acceleration_progressbar_scale)
3886         {
3887                 panel_size_x *= 0.5;
3888                 if (autocvar_hud_panel_physics_flip)
3889                         speed_offset_x = panel_size_x;
3890                 else
3891                         acceleration_offset_x = panel_size_x;
3892         }
3893         else
3894         {
3895                 panel_size_y *= 0.5;
3896                 if (autocvar_hud_panel_physics_flip)
3897                         speed_offset_y = panel_size_y;
3898                 else
3899                         acceleration_offset_y = panel_size_y;
3900         }
3901         float speed_baralign, acceleration_baralign;
3902         if (autocvar_hud_panel_physics_baralign == 1)
3903                 acceleration_baralign = speed_baralign = 1;
3904     else if(autocvar_hud_panel_physics_baralign == 4)
3905                 acceleration_baralign = speed_baralign = 2;
3906         else if (autocvar_hud_panel_physics_flip)
3907         {
3908                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
3909                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
3910         }
3911         else
3912         {
3913                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
3914                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
3915         }
3916         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
3917                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
3918
3919         //draw speed
3920         if(speed)
3921         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3922                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, autocvar_hud_progressbar_speed_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3923         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
3924         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3925         {
3926                 tmp_size_x = panel_size_x * 0.75;
3927                 tmp_size_y = panel_size_y * text_scale;
3928                 if (speed_baralign)
3929                         tmp_offset_x = panel_size_x - tmp_size_x;
3930                 //else
3931                         //tmp_offset_x = 0;
3932                 tmp_offset_y = (panel_size_y - tmp_size_y) / 2;
3933                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3934
3935                 //draw speed unit
3936                 if (speed_baralign)
3937                         tmp_offset_x = 0;
3938                 else
3939                         tmp_offset_x = tmp_size_x;
3940                 if (autocvar_hud_panel_physics_speed_unit_show)
3941                 {
3942                         //tmp_offset_y = 0;
3943                         tmp_size_x = panel_size_x * (1 - 0.75);
3944                         tmp_size_y = panel_size_y * 0.4 * text_scale;
3945                         tmp_offset_y = (panel_size_y * 0.4 - tmp_size_y) / 2;
3946                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3947                 }
3948         }
3949
3950         //compute and draw top speed
3951         if (autocvar_hud_panel_physics_topspeed)
3952         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3953         {
3954                 if (autocvar__hud_configure)
3955                 {
3956                         top_speed = floor( max_speed * 0.75 + 0.5 );
3957                         f = 1;
3958                 }
3959                 else
3960                 {
3961                         if (speed >= top_speed)
3962                         {
3963                                 top_speed = speed;
3964                                 top_speed_time = time;
3965                         }
3966                         if (top_speed != 0)
3967                         {
3968                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
3969                                 // divide by f to make it start from 1
3970                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
3971                         }
3972             else //hide top speed 0, it would be stupid
3973                                 f = 0;
3974                 }
3975                 if (f > 0)
3976                 {
3977                         //top speed progressbar peak
3978                         if(speed < top_speed)
3979                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3980                         {
3981                                 float peak_offset_x;
3982                                 vector peak_size = '0 0 0';
3983                                 if (speed_baralign == 0)
3984                                         peak_offset_x = min(top_speed, max_speed)/max_speed * panel_size_x;
3985                 else if (speed_baralign == 1)
3986                                         peak_offset_x = (1 - min(top_speed, max_speed)/max_speed) * panel_size_x;
3987                 else // if (speed_baralign == 2)
3988                     peak_offset_x = min(top_speed, max_speed)/max_speed * panel_size_x * 0.5;
3989                                 peak_size_x = floor(panel_size_x * 0.01 + 1.5);
3990                 peak_size_y = panel_size_y;
3991                 if (speed_baralign == 2) // draw two peaks, on both sides
3992                 {
3993                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size_x + peak_offset_x - peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3994                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size_x - peak_offset_x + peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3995                 }
3996                 else
3997                     drawfill(panel_pos + speed_offset + eX * (peak_offset_x - peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3998                         }
3999
4000                         //top speed
4001                         tmp_offset_y = panel_size_y * 0.4;
4002                         tmp_size_x = panel_size_x * (1 - 0.75);
4003                         tmp_size_y = (panel_size_y - tmp_offset_y) * text_scale;
4004                         tmp_offset_y += (panel_size_y - tmp_offset_y - tmp_size_y) / 2;
4005                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
4006                 }
4007                 else
4008                         top_speed = 0;
4009         }
4010
4011         //draw acceleration
4012         if(acceleration)
4013         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
4014         {
4015                 vector progressbar_color;
4016                 if(acceleration < 0)
4017                         progressbar_color = autocvar_hud_progressbar_acceleration_neg_color;
4018                 else
4019                         progressbar_color = autocvar_hud_progressbar_acceleration_color;
4020
4021                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
4022                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
4023                         f = sqrt(f);
4024
4025                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4026                 {
4027                         tmp_size = acceleration_progressbar_scale * panel_size_x * eX + panel_size_y * eY;
4028
4029                         if (acceleration_baralign == 1)
4030                                 tmp_offset_x = panel_size_x - tmp_size_x;
4031                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4032                                 tmp_offset_x = (panel_size_x - tmp_size_x) / 2;
4033                         else
4034                                 tmp_offset_x = 0;
4035                         tmp_offset_y = 0;
4036                 }
4037                 else
4038                 {
4039                         tmp_size = panel_size;
4040                         tmp_offset = '0 0 0';
4041                 }
4042
4043                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4044         }
4045         tmp_size_x = panel_size_x;
4046         tmp_size_y = panel_size_y * text_scale;
4047         tmp_offset_x = 0;
4048         tmp_offset_y = (panel_size_y - tmp_size_y) / 2;
4049         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4050                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(acceleration, 2), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4051
4052         draw_endBoldFont();
4053 }
4054
4055 // CenterPrint (#16)
4056 //
4057 #define CENTERPRINT_MAX_MSGS 10
4058 #define CENTERPRINT_MAX_ENTRIES 50
4059 #define CENTERPRINT_SPACING 0.7
4060 float cpm_index;
4061 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4062 float centerprint_msgID[CENTERPRINT_MAX_MSGS];
4063 float centerprint_time[CENTERPRINT_MAX_MSGS];
4064 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4065 float centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4066 float centerprint_showing;
4067
4068 void centerprint_generic(float new_id, string strMessage, float duration, float countdown_num)
4069 {
4070         //print(sprintf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num));
4071         float i, j;
4072
4073         if(strMessage == "" && new_id == 0)
4074                 return;
4075
4076         // strip trailing newlines
4077         j = strlen(strMessage) - 1;
4078         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4079                 --j;
4080         if (j < strlen(strMessage) - 1)
4081                 strMessage = substring(strMessage, 0, j + 1);
4082
4083         if(strMessage == "" && new_id == 0)
4084                 return;
4085
4086         // strip leading newlines
4087         j = 0;
4088         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4089                 ++j;
4090         if (j > 0)
4091                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4092
4093         if(strMessage == "" && new_id == 0)
4094                 return;
4095
4096         if (!centerprint_showing)
4097                 centerprint_showing = TRUE;
4098
4099         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4100         {
4101                 if (j == CENTERPRINT_MAX_MSGS)
4102                         j = 0;
4103                 if (new_id && new_id == centerprint_msgID[j])
4104                 {
4105                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4106                         {
4107                                 // fade out the current msg (duration and countdown_num are ignored)
4108                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4109                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4110                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4111                                 return;
4112                         }
4113                         break; // found a msg with the same id, at position j
4114                 }
4115         }
4116
4117         if (i == CENTERPRINT_MAX_MSGS)
4118         {
4119                 // a msg with the same id was not found, add the msg at the next position
4120                 --cpm_index;
4121                 if (cpm_index == -1)
4122                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4123                 j = cpm_index;
4124         }
4125         if(centerprint_messages[j])
4126                 strunzone(centerprint_messages[j]);
4127         centerprint_messages[j] = strzone(strMessage);
4128         centerprint_msgID[j] = new_id;
4129         if (duration < 0)
4130         {
4131                 centerprint_time[j] = -1;
4132                 centerprint_expire_time[j] = time;
4133         }
4134         else
4135         {
4136                 if(duration == 0)
4137                         duration = max(1, autocvar_hud_panel_centerprint_time);
4138                 centerprint_time[j] = duration;
4139                 centerprint_expire_time[j] = time + duration;
4140         }
4141         centerprint_countdown_num[j] = countdown_num;
4142 }
4143
4144 void centerprint_hud(string strMessage)
4145 {
4146         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4147 }
4148
4149 void reset_centerprint_messages(void)
4150 {
4151         float i;
4152         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4153         {
4154                 centerprint_expire_time[i] = 0;
4155                 centerprint_time[i] = 1;
4156                 centerprint_msgID[i] = 0;
4157                 if(centerprint_messages[i])
4158                         strunzone(centerprint_messages[i]);
4159                 centerprint_messages[i] = string_null;
4160         }
4161 }
4162 float hud_configure_cp_generation_time;
4163 void HUD_CenterPrint (void)
4164 {
4165         if(!autocvar__hud_configure)
4166         {
4167                 if(!autocvar_hud_panel_centerprint) return;
4168
4169                 if (hud_configure_prev && hud_configure_prev != -1)
4170                         reset_centerprint_messages();
4171         }
4172         else
4173         {
4174                 if (!hud_configure_prev)
4175                         reset_centerprint_messages();
4176                 if (time > hud_configure_cp_generation_time)
4177                 {
4178                         float r;
4179                         r = random();
4180                         if (r > 0.9)
4181                                 centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: %d"), 1, 10);
4182                         else if (r > 0.8)
4183                                 centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4184                         else
4185                                 centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4186                         hud_configure_cp_generation_time = time + 1 + random()*4;
4187                 }
4188         }
4189
4190         HUD_Panel_UpdateCvars();
4191
4192         // this panel doesn't fade when showing the scoreboard
4193         if(autocvar__menu_alpha)
4194                 HUD_Panel_ApplyFadeAlpha();
4195
4196         if(scoreboard_fade_alpha)
4197         {
4198                 // move the panel below the scoreboard
4199                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4200                         return;
4201                 vector target_pos;
4202
4203                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size_x);
4204
4205                 if(target_pos_y > panel_pos_y)
4206                 {
4207                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4208                         panel_size_y = min(panel_size_y, vid_conheight - scoreboard_bottom);
4209                 }
4210         }
4211
4212         HUD_Panel_DrawBg(1);
4213
4214         if (!centerprint_showing)
4215                 return;
4216
4217         if(panel_bg_padding)
4218         {
4219                 panel_pos += '1 1 0' * panel_bg_padding;
4220                 panel_size -= '2 2 0' * panel_bg_padding;
4221         }
4222
4223         float entries, height;
4224         vector fontsize;
4225         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4226         // height = panel_size_y/entries;
4227         // fontsize = '1 1 0' * height;
4228         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4229         fontsize = '1 1 0' * height;
4230         entries = bound(1, floor(panel_size_y/height), CENTERPRINT_MAX_ENTRIES);
4231
4232         float i, j, k, n, g;
4233         float a, sz, align, current_msg_pos_y = 0, msg_size;
4234         vector pos;
4235         string ts;
4236
4237         n = -1; // if no msg will be displayed, n stays -1
4238
4239         pos = panel_pos;
4240         if (autocvar_hud_panel_centerprint_flip)
4241                 pos_y += panel_size_y;
4242         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4243         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4244         {
4245                 if (j == CENTERPRINT_MAX_MSGS)
4246                         j = 0;
4247                 if (centerprint_expire_time[j] <= time)
4248                 {
4249                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4250                         {
4251                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4252                                 if (centerprint_countdown_num[j] == 0)
4253                                         continue;
4254                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4255                         }
4256                         else if(centerprint_time[j] != -1)
4257                                 continue;
4258                 }
4259
4260
4261                 // fade the centerprint_hud in/out
4262                 if(centerprint_time[j] < 0)
4263                         a = bound(0, (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in), 1);
4264                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)
4265                         a = bound(0, (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in), 1);
4266                 else if(centerprint_expire_time[j] > time)
4267                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4268                 else
4269                         a = 0;
4270
4271                 // set the size from fading in/out before subsequent fading
4272                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4273
4274                 // also fade it based on positioning
4275                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4276                 {
4277                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4278                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4279                 }
4280
4281                 // finally set the size based on the new theAlpha from subsequent fading
4282                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4283                 drawfontscale = sz * '1 1 0';
4284
4285                 if (centerprint_countdown_num[j])
4286                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4287                 else
4288                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4289
4290                 if (autocvar_hud_panel_centerprint_flip)
4291                 {
4292                         // check if the message can be entirely shown
4293                         for(k = 0; k < n; ++k)
4294                         {
4295                                 getWrappedLine_remaining = argv(k);
4296                                 while(getWrappedLine_remaining)
4297                                 {
4298                                         ts = getWrappedLine(panel_size_x * sz, fontsize, stringwidth_colors);
4299                                         if (ts != "")
4300                                                 pos_y -= fontsize_y;
4301                                         else
4302                                                 pos_y -= fontsize_y * CENTERPRINT_SPACING/2;
4303                                 }
4304                         }
4305                         current_msg_pos_y = pos_y; // save starting pos (first line) of the current message
4306                 }
4307
4308                 msg_size = pos_y;
4309                 for(k = 0; k < n; ++k)
4310                 {
4311                         getWrappedLine_remaining = argv(k);
4312                         while(getWrappedLine_remaining)
4313                         {
4314                                 ts = getWrappedLine(panel_size_x * sz, fontsize, stringwidth_colors);
4315                                 if (ts != "")
4316                                 {
4317                                         if (align)
4318                                                 pos_x = panel_pos_x + (panel_size_x - stringwidth(ts, TRUE, fontsize)) * align;
4319                                         drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize_y, ts, fontsize, a * panel_fg_alpha, DRAWFLAG_NORMAL);
4320                                         pos_y += fontsize_y;
4321                                 }
4322                                 else
4323                                         pos_y += fontsize_y * CENTERPRINT_SPACING/2;
4324                         }
4325                 }
4326
4327                 ++g; // move next position number up
4328
4329                 msg_size = pos_y - msg_size;
4330                 if (autocvar_hud_panel_centerprint_flip)
4331                 {
4332                         pos_y = current_msg_pos_y - CENTERPRINT_SPACING * fontsize_y;
4333                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4334                                 pos_y += (msg_size + CENTERPRINT_SPACING * fontsize_y) * (1 - sqrt(sz));
4335
4336                         if (pos_y < panel_pos_y) // check if the next message can be shown
4337                         {
4338                                 drawfontscale = '1 1 0';
4339                                 return;
4340                         }
4341                 }
4342                 else
4343                 {
4344                         pos_y += CENTERPRINT_SPACING * fontsize_y;
4345                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4346                                 pos_y -= (msg_size + CENTERPRINT_SPACING * fontsize_y) * (1 - sqrt(sz));
4347
4348                         if(pos_y > panel_pos_y + panel_size_y - fontsize_y) // check if the next message can be shown
4349                         {
4350                                 drawfontscale = '1 1 0';
4351                                 return;
4352                         }
4353                 }
4354         }
4355         drawfontscale = '1 1 0';
4356         if (n == -1)
4357         {
4358                 centerprint_showing = FALSE;
4359                 reset_centerprint_messages();
4360         }
4361 }
4362
4363 /*
4364 ==================
4365 Main HUD system
4366 ==================
4367 */
4368
4369 void HUD_Reset (void)
4370 {
4371         // reset gametype specific icons
4372         if(gametype == MAPINFO_TYPE_KEYHUNT)
4373                 HUD_Mod_KH_Reset();
4374         else if(gametype == MAPINFO_TYPE_CTF)
4375                 HUD_Mod_CTF_Reset();
4376 }
4377
4378 void HUD_Main (void)
4379 {
4380         float i;
4381         // global hud theAlpha fade
4382         if(menu_enabled == 1)
4383                 hud_fade_alpha = 1;
4384         else
4385                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4386
4387         if(scoreboard_fade_alpha)
4388                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4389
4390         HUD_Configure_Frame();
4391
4392         if(intermission == 2) // no hud during mapvote
4393                 hud_fade_alpha = 0;
4394         else if(autocvar__menu_alpha == 0 && scoreboard_fade_alpha == 0)
4395                 hud_fade_alpha = 1;
4396
4397         // panels that we want to be active together with the scoreboard
4398         // they must call HUD_Panel_ApplyFadeAlpha(); only when showing the menu
4399         if(scoreboard_fade_alpha == 1)
4400         {
4401                 (panel = HUD_PANEL(CENTERPRINT)).panel_draw();
4402                 return;
4403         }
4404
4405         if(!autocvar__hud_configure && !hud_fade_alpha)
4406                 return;
4407
4408         // Drawing stuff
4409         if (hud_skin_prev != autocvar_hud_skin)
4410         {
4411                 if (hud_skin_path)
4412                         strunzone(hud_skin_path);
4413                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4414                 if (hud_skin_prev)
4415                         strunzone(hud_skin_prev);
4416                 hud_skin_prev = strzone(autocvar_hud_skin);
4417         }
4418
4419 #ifdef COMPAT_XON050_ENGINE
4420     current_player = (spectatee_status > 0) ? spectatee_status : player_localentnum;
4421 #else
4422     current_player = player_localentnum;
4423 #endif
4424
4425         // draw the dock
4426         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4427         {
4428                 float f;
4429                 vector color;
4430                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4431                 if((teamplay) && hud_dock_color_team) {
4432                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4433                                 color = '1 0 0' * hud_dock_color_team;
4434                         else
4435                                 color = myteamcolors * hud_dock_color_team;
4436                 }
4437                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4438                         color = '1 0 0' * hud_dock_color_team;
4439                 }
4440                 else
4441                 {
4442                         string hud_dock_color = autocvar_hud_dock_color;
4443                         if(hud_dock_color == "shirt") {
4444                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4445                                 color = colormapPaletteColor(floor(f / 16), 0);
4446                         }
4447                         else if(hud_dock_color == "pants") {
4448                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4449                                 color = colormapPaletteColor(mod(f, 16), 1);
4450                         }
4451                         else
4452                                 color = stov(hud_dock_color);
4453                 }
4454
4455                 string pic;
4456                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4457                 if(precache_pic(pic) == "") {
4458                         pic = strcat(hud_skin_path, "/dock_medium");
4459                         if(precache_pic(pic) == "") {
4460                                 pic = "gfx/hud/default/dock_medium";
4461                         }
4462                 }
4463                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4464         }
4465
4466         // cache the panel order into the panel_order array
4467         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4468                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4469                         panel_order[i] = -1;
4470                 string s = "";
4471                 float p_num, warning = false;
4472                 float argc = tokenize_console(autocvar__hud_panelorder);
4473                 if (argc > HUD_PANEL_NUM)
4474                         warning = true;
4475                 //first detect wrong/missing panel numbers
4476                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4477                         p_num = stof(argv(i));
4478                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4479                                 if (panel_order[p_num] == -1) //found for the first time?
4480                                         s = strcat(s, ftos(p_num), " ");
4481                                 panel_order[p_num] = 1; //mark as found
4482                         }
4483                         else
4484                                 warning = true;
4485                 }
4486                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4487                         if (panel_order[i] == -1) {
4488                                 warning = true;
4489                                 s = strcat(s, ftos(i), " "); //add missing panel number
4490                         }
4491                 }
4492                 if (warning)
4493                         print(_("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n"));
4494
4495                 cvar_set("_hud_panelorder", s);
4496                 if(hud_panelorder_prev)
4497                         strunzone(hud_panelorder_prev);
4498                 hud_panelorder_prev = strzone(s);
4499
4500                 //now properly set panel_order
4501                 tokenize_console(s);
4502                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4503                         panel_order[i] = stof(argv(i));
4504                 }
4505         }
4506
4507         hud_draw_maximized = 0;
4508         // draw panels in order specified by panel_order array
4509         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4510                 (panel = hud_panel[panel_order[i]]).panel_draw();
4511
4512         hud_draw_maximized = 1; // panels that may be maximized must check this var
4513         // draw maximized panels on top
4514         if(hud_panel_radar_maximized)
4515                 (panel = HUD_PANEL(RADAR)).panel_draw();
4516         if(autocvar__con_chat_maximized)
4517                 (panel = HUD_PANEL(CHAT)).panel_draw();
4518
4519         HUD_Configure_PostDraw();
4520
4521         hud_configure_prev = autocvar__hud_configure;
4522 }