qcsrc/client/hud/panel/centerprint.qc

   1 // CenterPrint (#16)
   2
   3 const int CENTERPRINT_MAX_MSGS = 10;
   4 const int CENTERPRINT_MAX_ENTRIES = 50;
   5 const float CENTERPRINT_SPACING = 0.7;
   6 int cpm_index;
   7 string centerprint_messages[CENTERPRINT_MAX_MSGS];
   8 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
   9 float centerprint_time[CENTERPRINT_MAX_MSGS];
  10 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
  11 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
  12 bool centerprint_showing;
  13
  14 void centerprint_generic(int new_id, string strMessage, float duration, int countdown_num)
  15 {
  16         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
  17         int i, j;
  18
  19         if(strMessage == "" && new_id == 0)
  20                 return;
  21
  22         // strip trailing newlines
  23         j = strlen(strMessage) - 1;
  24         while(substring(strMessage, j, 1) == "\n" && j >= 0)
  25                 --j;
  26         if (j < strlen(strMessage) - 1)
  27                 strMessage = substring(strMessage, 0, j + 1);
  28
  29         if(strMessage == "" && new_id == 0)
  30                 return;
  31
  32         // strip leading newlines
  33         j = 0;
  34         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
  35                 ++j;
  36         if (j > 0)
  37                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
  38
  39         if(strMessage == "" && new_id == 0)
  40                 return;
  41
  42         if (!centerprint_showing)
  43                 centerprint_showing = true;
  44
  45         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
  46         {
  47                 if (j == CENTERPRINT_MAX_MSGS)
  48                         j = 0;
  49                 if (new_id && new_id == centerprint_msgID[j])
  50                 {
  51                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
  52                         {
  53                                 // fade out the current msg (duration and countdown_num are ignored)
  54                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
  55                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
  56                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
  57                                 return;
  58                         }
  59                         break; // found a msg with the same id, at position j
  60                 }
  61         }
  62
  63         if (i == CENTERPRINT_MAX_MSGS)
  64         {
  65                 // a msg with the same id was not found, add the msg at the next position
  66                 --cpm_index;
  67                 if (cpm_index == -1)
  68                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
  69                 j = cpm_index;
  70         }
  71         if(centerprint_messages[j])
  72                 strunzone(centerprint_messages[j]);
  73         centerprint_messages[j] = strzone(strMessage);
  74         centerprint_msgID[j] = new_id;
  75         if (duration < 0)
  76         {
  77                 centerprint_time[j] = -1;
  78                 centerprint_expire_time[j] = time;
  79         }
  80         else
  81         {
  82                 if(duration == 0)
  83                         duration = max(1, autocvar_hud_panel_centerprint_time);
  84                 centerprint_time[j] = duration;
  85                 centerprint_expire_time[j] = time + duration;
  86         }
  87         centerprint_countdown_num[j] = countdown_num;
  88 }
  89
  90 void centerprint_hud(string strMessage)
  91 {
  92         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
  93 }
  94
  95 void reset_centerprint_messages()
  96 {
  97         int i;
  98         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
  99         {
 100                 centerprint_expire_time[i] = 0;
 101                 centerprint_time[i] = 1;
 102                 centerprint_msgID[i] = 0;
 103                 if(centerprint_messages[i])
 104                         strunzone(centerprint_messages[i]);
 105                 centerprint_messages[i] = string_null;
 106         }
 107 }
 108 float hud_configure_cp_generation_time;
 109 void HUD_CenterPrint ()
 110 {
 111         if(!autocvar__hud_configure)
 112         {
 113                 if(!autocvar_hud_panel_centerprint) return;
 114
 115                 if(hud_configure_prev)
 116                         reset_centerprint_messages();
 117         }
 118         else
 119         {
 120                 if(!hud_configure_prev)
 121                         reset_centerprint_messages();
 122                 if (time > hud_configure_cp_generation_time)
 123                 {
 124                         if(highlightedPanel == HUD_PANEL(CENTERPRINT))
 125                         {
 126                                 float r;
 127                                 r = random();
 128                                 if (r > 0.8)
 129                                         centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
 130                                 else if (r > 0.55)
 131                                         centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
 132                                 else
 133                                         centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
 134                                 hud_configure_cp_generation_time = time + 1 + random()*4;
 135                         }
 136                         else
 137                         {
 138                                 centerprint_generic(0, sprintf("Centerprint message", seconds_tostring(time)), 10, 0);
 139                                 hud_configure_cp_generation_time = time + 10 - random()*3;
 140                         }
 141                 }
 142         }
 143
 144         // this panel fades only when the menu does
 145         float hud_fade_alpha_save = 0;
 146         if(scoreboard_fade_alpha)
 147         {
 148                 hud_fade_alpha_save = hud_fade_alpha;
 149                 hud_fade_alpha = 1 - autocvar__menu_alpha;
 150         }
 151         HUD_Panel_UpdateCvars();
 152
 153         if ( HUD_Radar_Clickable() )
 154         {
 155                 if (hud_panel_radar_bottom >= 0.96 * vid_conheight)
 156                         return;
 157
 158                 panel_pos = eY * hud_panel_radar_bottom + eX * 0.5 * (vid_conwidth - panel_size_x);
 159                 panel_size_y = min(panel_size_y, vid_conheight - hud_panel_radar_bottom);
 160         }
 161         else if(scoreboard_fade_alpha)
 162         {
 163                 hud_fade_alpha = hud_fade_alpha_save;
 164
 165                 // move the panel below the scoreboard
 166                 if (scoreboard_bottom >= 0.96 * vid_conheight)
 167                         return;
 168                 vector target_pos;
 169
 170                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size.x);
 171
 172                 if(target_pos.y > panel_pos.y)
 173                 {
 174                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
 175                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
 176                 }
 177         }
 178
 179         HUD_Panel_DrawBg(1);
 180
 181         if (!centerprint_showing)
 182                 return;
 183
 184         if(panel_bg_padding)
 185         {
 186                 panel_pos += '1 1 0' * panel_bg_padding;
 187                 panel_size -= '2 2 0' * panel_bg_padding;
 188         }
 189
 190         int entries;
 191         float height;
 192         vector fontsize;
 193         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
 194         // height = panel_size_y/entries;
 195         // fontsize = '1 1 0' * height;
 196         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
 197         fontsize = '1 1 0' * height;
 198         entries = bound(1, floor(panel_size.y/height), CENTERPRINT_MAX_ENTRIES);
 199
 200         int i, j, k, n, g;
 201         float a, sz, align, current_msg_posY = 0, msg_size;
 202         vector pos;
 203         string ts;
 204         bool all_messages_expired = true;
 205
 206         pos = panel_pos;
 207         if (autocvar_hud_panel_centerprint_flip)
 208                 pos.y += panel_size.y;
 209         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
 210         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
 211         {
 212                 if (j == CENTERPRINT_MAX_MSGS)
 213                         j = 0;
 214                 if (centerprint_expire_time[j] <= time)
 215                 {
 216                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
 217                         {
 218                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
 219                                 if (centerprint_countdown_num[j] == 0)
 220                                         continue;
 221                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
 222                         }
 223                         else if(centerprint_time[j] != -1)
 224                                 continue;
 225                 }
 226
 227                 all_messages_expired = false;
 228
 229                 // fade the centerprint_hud in/out
 230                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
 231                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
 232                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
 233                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
 234                 else // Expiring soon, so fade it out.
 235                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
 236
 237                 // while counting down show it anyway in order to hold the current message position
 238                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
 239                         continue;
 240                 if (a > 1)
 241                         a = 1;
 242
 243                 // set the size from fading in/out before subsequent fading
 244                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
 245
 246                 // also fade it based on positioning
 247                 if(autocvar_hud_panel_centerprint_fade_subsequent)
 248                 {
 249                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
 250                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
 251                 }
 252                 a *= panel_fg_alpha;
 253
 254                 // finally set the size based on the new theAlpha from subsequent fading
 255                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
 256                 drawfontscale = sz * '1 1 0';
 257
 258                 if (centerprint_countdown_num[j])
 259                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
 260                 else
 261                         n = tokenizebyseparator(centerprint_messages[j], "\n");
 262
 263                 if (autocvar_hud_panel_centerprint_flip)
 264                 {
 265                         // check if the message can be entirely shown
 266                         for(k = 0; k < n; ++k)
 267                         {
 268                                 getWrappedLine_remaining = argv(k);
 269                                 while(getWrappedLine_remaining)
 270                                 {
 271                                         ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
 272                                         if (ts != "")
 273                                                 pos.y -= fontsize.y;
 274                                         else
 275                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
 276                                 }
 277                         }
 278                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
 279                 }
 280
 281                 msg_size = pos.y;
 282                 for(k = 0; k < n; ++k)
 283                 {
 284                         getWrappedLine_remaining = argv(k);
 285                         while(getWrappedLine_remaining)
 286                         {
 287                                 ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
 288                                 if (ts != "")
 289                                 {
 290                                         if (align)
 291                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize)) * align;
 292                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
 293                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
 294                                         pos.y += fontsize.y;
 295                                 }
 296                                 else
 297                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
 298                         }
 299                 }
 300
 301                 ++g; // move next position number up
 302
 303                 msg_size = pos.y - msg_size;
 304                 if (autocvar_hud_panel_centerprint_flip)
 305                 {
 306                         pos.y = current_msg_posY - CENTERPRINT_SPACING * fontsize.y;
 307                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
 308                                 pos.y += (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
 309
 310                         if (pos.y < panel_pos.y) // check if the next message can be shown
 311                         {
 312                                 drawfontscale = '1 1 0';
 313                                 return;
 314                         }
 315                 }
 316                 else
 317                 {
 318                         pos.y += CENTERPRINT_SPACING * fontsize.y;
 319                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
 320                                 pos.y -= (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
 321
 322                         if(pos.y > panel_pos.y + panel_size.y - fontsize.y) // check if the next message can be shown
 323                         {
 324                                 drawfontscale = '1 1 0';
 325                                 return;
 326                         }
 327                 }
 328         }
 329         drawfontscale = '1 1 0';
 330         if (all_messages_expired)
 331         {
 332                 centerprint_showing = false;
 333                 reset_centerprint_messages();
 334         }
 335 }