qcsrc/client/announcer.qc

   1 float previous_announcement_time;
   2 float previous_game_starttime;
   3 string previous_announcement;
   4
   5 // remaining maptime announcer sounds, true when sound was already played
   6 float announcer_1min;
   7 float announcer_5min;
   8
   9 void Announcer_Play(string announcement)
  10 {
  11         if((announcement != previous_announcement) || (time >= (previous_announcement_time + autocvar_cl_announcer_antispam)))
  12         {
  13                 sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/", announcement, ".wav"), VOL_BASEVOICE, ATTN_NONE);
  14
  15                 previous_announcement = announcement;
  16                 previous_announcement_time = time;
  17         }
  18         print(strcat("announcement: '", announcement, "' at time: ", ftos(time), ". \n"));
  19 }
  20
  21 void Announcer_Countdown()
  22 {
  23         float starttime = getstatf(STAT_GAMESTARTTIME);
  24         float countdown = (starttime - time);
  25         float countdown_rounded = floor(0.5 + countdown);
  26
  27         if(countdown <= 0) // countdown has finished, starttime is now
  28         {
  29                 if (!spectatee_status)
  30                         centerprint_generic(CPID_GAME_STARTING, _("^1Begin!"), 1, 0);
  31
  32                 Announcer_Play("begin");
  33                 announcer_5min = announcer_1min = FALSE; // reset maptime announcers now as well
  34                 remove(self);
  35                 return;
  36         }
  37         else // countdown is still going
  38         {
  39                 if (!spectatee_status)
  40                         centerprint_generic(CPID_GAME_STARTING, _("^1Game starts in %d seconds"), 1, countdown_rounded);
  41
  42                 if(countdown_rounded <= 3 && countdown_rounded >= 1)
  43                         Announcer_Play(ftos(countdown_rounded));
  44
  45                 self.nextthink = (starttime - (countdown - 1));
  46         }
  47 }
  48
  49 /**
  50  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  51  *
  52  * TODO: Use a better solution where a common shared entitiy is used that contains
  53  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  54  * and STAT_FRAGLIMIT to be auto-sent)
  55  */
  56 void Announcer_Gamestart()
  57 {
  58         float startTime = getstatf(STAT_GAMESTARTTIME);
  59
  60         if(previous_game_starttime != startTime)
  61         {
  62                 if((time + 5.0) < startTime) // if connecting to server while restart was active don't always play prepareforbattle
  63                         Announcer_Play("prepareforbattle");
  64
  65                 if(time < startTime)
  66                 {
  67                         entity e;
  68                         e = spawn();
  69                         e.think = Announcer_Countdown;
  70                         e.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
  71                 }
  72         }
  73
  74         previous_game_starttime = startTime;
  75 }
  76
  77
  78 // Plays the 1 minute or 5 minutes (of maptime) remaining sound, if client wants it
  79 void Announcer_Time()
  80 {
  81         float timelimit = getstatf(STAT_TIMELIMIT);
  82         float timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
  83         float warmup_timeleft;
  84
  85         if(warmup_stage)
  86                 if(autocvar_g_warmup_limit > 0)
  87                         warmup_timeleft = max(0, autocvar_g_warmup_limit + getstatf(STAT_GAMESTARTTIME) - time);
  88
  89         // 5 minute check
  90         if(autocvar_cl_announcer_maptime >= 2)
  91         {
  92                 // make sure that after connect (and e.g. 4 minutes left) we will not get a wrong sound
  93                 if(announcer_5min)
  94                 {
  95                         if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timeleft > 300)
  96                                 || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft > 300))
  97                                         announcer_5min = FALSE;
  98                 }
  99                 else
 100                 {
 101                         if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timelimit > 0 && timeleft < 300 && timeleft > 299)
 102                                 || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft < 300 && warmup_timeleft > 299))
 103                         {
 104                                 //if we're in warmup mode, check whether there's a warmup timelimit
 105                                 if not(autocvar_g_warmup_limit == -1 && warmup_stage)
 106                                 {
 107                                         announcer_5min = TRUE;
 108                                         Announcer_Play("5minutesremain");
 109                                 }
 110                         }
 111                 }
 112         }
 113
 114         // 1 minute check
 115         if((autocvar_cl_announcer_maptime == 1) || (autocvar_cl_announcer_maptime == 3))
 116         {
 117                 if (announcer_1min)
 118                 {
 119                         if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timeleft > 60)
 120                                 || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft > 60))
 121                                         announcer_1min = FALSE;
 122                 }
 123                 else if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timelimit > 0 && timeleft < 60)
 124                         || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft < 60))
 125                 {
 126                         // if we're in warmup mode, check whether there's a warmup timelimit
 127                         if not(autocvar_g_warmup_limit == -1 && warmup_stage)
 128                         {
 129                                 announcer_1min = TRUE;
 130                                 Announcer_Play("1minuteremains");
 131                         }
 132                 }
 133         }
 134 }
 135
 136 float redflag_prev;
 137 float blueflag_prev;
 138 void carrierAnnouncer() {
 139         float stat_items, redflag, blueflag;
 140         float pickup;
 141         string item;
 142
 143         if not(autocvar_cl_notify_carried_items)
 144                 return;
 145
 146         stat_items = getstati(STAT_ITEMS);
 147
 148         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
 149         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
 150
 151         if (redflag == 3 && redflag != redflag_prev) {
 152                 item = _("^1RED^7 flag");
 153                 pickup = (redflag_prev == 2);
 154         }
 155
 156         if (blueflag == 3 && blueflag != blueflag_prev) {
 157                 item = _("^4BLUE^7 flag");
 158                 pickup = (blueflag_prev == 2);
 159         }
 160
 161         if (item)
 162         {
 163                 if (pickup) {
 164                         if (autocvar_cl_notify_carried_items & 2)
 165                                 centerprint(sprintf(_("You picked up the %s!"), item));
 166                 }
 167                 else {
 168                         if (autocvar_cl_notify_carried_items & 1)
 169                                 centerprint(sprintf(_("You got the %s!"), item));
 170                 }
 171         }
 172
 173         blueflag_prev = blueflag;
 174         redflag_prev = redflag;
 175 }
 176
 177 void Announcer()
 178 {
 179         Announcer_Gamestart();
 180         Announcer_Time();
 181         carrierAnnouncer();
 182 }
 183
 184 void Announcer_Precache ()
 185 {
 186         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1minuteremains.wav"));
 187         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5minutesremain.wav"));
 188
 189         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/electrobitch.wav"));
 190         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/airshot.wav"));
 191         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/03kills.wav"));
 192         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/05kills.wav"));
 193         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10kills.wav"));
 194         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/15kills.wav"));
 195         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/20kills.wav"));
 196         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/25kills.wav"));
 197         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/30kills.wav"));
 198         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/botlike.wav"));
 199         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/yoda.wav"));
 200         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/amazing.wav"));
 201         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/awesome.wav"));
 202         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/headshot.wav"));
 203         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/impressive.wav"));
 204
 205         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"));
 206         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/begin.wav"));
 207         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/timeoutcalled.wav"));
 208         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1fragleft.wav"));
 209         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2fragsleft.wav"));
 210         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3fragsleft.wav"));
 211         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/terminated.wav"));
 212
 213         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1.wav"));
 214         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2.wav"));
 215         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3.wav"));
 216         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/4.wav"));
 217         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5.wav"));
 218         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/6.wav"));
 219         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/7.wav"));
 220         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/8.wav"));
 221         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/9.wav"));
 222         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10.wav"));
 223
 224         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/lastsecond.wav"));
 225         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/narrowly.wav"));
 226
 227         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/voteaccept.wav"));
 228         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votecall.wav"));
 229         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votefail.wav"));
 230 }