qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         makevectors(view_angles);
 166
 167         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 168         {
 169                 if(intermission) { curspeed = 0; }
 170                 else
 171                 {
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 203 {
 204         float fovx, fovy;
 205         float width = (ov_worldmax_x - ov_worldmin_x);
 206         float height = (ov_worldmax_y - ov_worldmin_y);
 207         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 210         return '1 0 0' * fovx + '0 1 0' * fovy;
 211 }
 212
 213 // this function must match W_SetupShot!
 214 float zoomscript_caught;
 215
 216 vector wcross_origin;
 217 float wcross_scale_prev, wcross_alpha_prev;
 218 vector wcross_color_prev;
 219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 220 vector wcross_color_goal_prev;
 221 float wcross_changedonetime;
 222
 223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 225 float wcross_name_changestarttime, wcross_name_changedonetime;
 226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 227
 228 float wcross_ring_prev;
 229
 230 entity trueaim;
 231 entity trueaim_rifle;
 232
 233 #define SHOTTYPE_HITTEAM 1
 234 #define SHOTTYPE_HITOBSTRUCTION 2
 235 #define SHOTTYPE_HITWORLD 3
 236 #define SHOTTYPE_HITENEMY 4
 237
 238 void TrueAim_Init()
 239 {
 240         trueaim = spawn();
 241         trueaim.classname = "trueaim";
 242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 243         trueaim_rifle = spawn();
 244         trueaim_rifle.classname = "trueaim_rifle";
 245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 246 }
 247
 248 float EnemyHitCheck()
 249 {
 250         float t, n;
 251         wcross_origin = project_3d_to_2d(trace_endpos);
 252         wcross_origin_z = 0;
 253         if(trace_ent)
 254                 n = trace_ent.entnum;
 255         else
 256                 n = trace_networkentity;
 257         if(n < 1)
 258                 return SHOTTYPE_HITWORLD;
 259         if(n > maxclients)
 260                 return SHOTTYPE_HITWORLD;
 261         t = GetPlayerColor(n - 1);
 262         if(teamplay)
 263                 if(t == myteam)
 264                         return SHOTTYPE_HITTEAM;
 265         if(t == NUM_SPECTATOR)
 266                 return SHOTTYPE_HITWORLD;
 267         return SHOTTYPE_HITENEMY;
 268 }
 269
 270 float TrueAimCheck()
 271 {
 272         float nudge = 1; // added to traceline target and subtracted from result
 273         vector vecs, trueaimpoint, w_shotorg;
 274         vector mi, ma, dv;
 275         float shottype;
 276         entity ta;
 277         float mv;
 278
 279         mi = ma = '0 0 0';
 280         ta = trueaim;
 281         mv = MOVE_NOMONSTERS;
 282
 283         switch(activeweapon)
 284         {
 285                 case WEP_TUBA: // no aim
 286                 case WEP_PORTO: // shoots from eye
 287                 case WEP_HOOK: // no trueaim
 288                 case WEP_GRENADE_LAUNCHER: // toss curve
 289                         return SHOTTYPE_HITWORLD;
 290                 case WEP_NEX:
 291                 case WEP_MINSTANEX:
 292                         mv = MOVE_NORMAL;
 293                         break;
 294                 case WEP_RIFLE:
 295                         ta = trueaim_rifle;
 296                         mv = MOVE_NORMAL;
 297                         if(zoomscript_caught)
 298                         {
 299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 300                                 return EnemyHitCheck();
 301                         }
 302                         break;
 303                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 304                         mi = '-3 -3 -3';
 305                         ma = '3 3 3';
 306                         break;
 307                 case WEP_FIREBALL: // projectile has a size!
 308                         mi = '-16 -16 -16';
 309                         ma = '16 16 16';
 310                         break;
 311                 case WEP_SEEKER: // projectile has a size!
 312                         mi = '-2 -2 -2';
 313                         ma = '2 2 2';
 314                         break;
 315                 case WEP_ELECTRO: // projectile has a size!
 316                         mi = '0 0 -3';
 317                         ma = '0 0 -3';
 318                         break;
 319         }
 320
 321         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 322
 323         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 324
 325         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 326         trueaimpoint = trace_endpos;
 327
 328         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 329                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 330
 331         if(vecs_x > 0)
 332                 vecs_y = -vecs_y;
 333         else
 334                 vecs = '0 0 0';
 335
 336         dv = view_right * vecs_y + view_up * vecs_z;
 337         w_shotorg = traceorigin + dv;
 338
 339         // now move the vecs forward as much as requested if possible
 340         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 341         w_shotorg = trace_endpos - view_forward * nudge;
 342
 343         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 344         shottype = EnemyHitCheck();
 345         if(shottype != SHOTTYPE_HITWORLD)
 346                 return shottype;
 347
 348 #if 0
 349         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 350         // or rather, I know why, but see no fix
 351         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 352                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 353                 return SHOTTYPE_HITOBSTRUCTION;
 354 #endif
 355
 356         return SHOTTYPE_HITWORLD;
 357 }
 358
 359 void CSQC_common_hud(void);
 360
 361 void PostInit(void);
 362 void CSQC_Demo_Camera();
 363 float HUD_WouldDrawScoreboard();
 364 float camera_mode;
 365 const float CAMERA_FREE = 1;
 366 const float CAMERA_CHASE = 2;
 367 float reticle_type;
 368 string NextFrameCommand;
 369
 370 vector freeze_org, freeze_ang;
 371 entity nightvision_noise, nightvision_noise2;
 372
 373 #define MAX_TIME_DIFF 5
 374 float pickup_crosshair_time, pickup_crosshair_size;
 375 float hit_time, typehit_time;
 376 float nextsound_hit_time, nextsound_typehit_time;
 377 float hitindication_crosshair_time, hitindication_crosshair_size;
 378 float use_nex_chargepool;
 379
 380 float myhealth, myhealth_prev;
 381 float myhealth_flash;
 382
 383 float old_blurradius, old_bluralpha;
 384 float old_sharpen_intensity;
 385
 386 vector myhealth_gentlergb;
 387
 388 float contentavgalpha, liquidalpha_prev;
 389 vector liquidcolor_prev;
 390
 391 float eventchase_current_distance;
 392
 393 vector damage_blurpostprocess, content_blurpostprocess;
 394
 395 float checkfail[16];
 396
 397 float rainbow_last_flicker;
 398 vector rainbow_prev_color;
 399
 400 #define BUTTON_3 4
 401 #define BUTTON_4 8
 402 float cl_notice_run();
 403 float prev_myteam;
 404 void CSQC_UpdateView(float w, float h)
 405 {
 406         entity e;
 407         float fov;
 408         float f, i, j;
 409         vector v;
 410         vector vf_size, vf_min;
 411         float a;
 412
 413         execute_next_frame();
 414
 415         ++framecount;
 416
 417         hud = getstati(STAT_HUD);
 418
 419         if(autocvar__hud_showbinds_reload) // menu can set this one
 420         {
 421                 db_close(binddb);
 422                 binddb = db_create();
 423                 cvar_set("_hud_showbinds_reload", "0");
 424         }
 425
 426         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 427                 view_quality = getproperty(VF_MINFPS_QUALITY);
 428         else
 429                 view_quality = 1;
 430
 431         button_attack2 = (input_buttons & BUTTON_3);
 432         button_zoom = (input_buttons & BUTTON_4);
 433
 434 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 435         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 436         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 437         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 438         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 439         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 440         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 441         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 442
 443         vf_size = getpropertyvec(VF_SIZE);
 444         vf_min = getpropertyvec(VF_MIN);
 445         vid_width = vf_size_x;
 446         vid_height = vf_size_y;
 447
 448         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 449         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 450
 451         WaypointSprite_Load();
 452
 453         CSQCPlayer_SetCamera();
 454
 455 #ifdef COMPAT_XON050_ENGINE
 456         if(spectatee_status)
 457                 myteam = GetPlayerColor(spectatee_status - 1);
 458         else
 459 #endif
 460                 myteam = GetPlayerColor(player_localentnum - 1);
 461
 462         if(myteam != prev_myteam)
 463         {
 464                 myteamcolors = colormapPaletteColor(myteam, 1);
 465                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 466                         hud_panel[i].update_time = time;
 467                 prev_myteam = myteam;
 468         }
 469
 470         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 471
 472         float is_dead = (getstati(STAT_HEALTH) <= 0);
 473
 474         // FIXME do we need this hack?
 475         if(isdemo())
 476         {
 477                 // in demos, input_buttons do not work
 478                 button_zoom = (autocvar__togglezoom == "-");
 479         }
 480         else if(button_zoom
 481                 && autocvar_cl_unpress_zoom_on_death
 482                 && (spectatee_status >= 0)
 483                 && (is_dead || intermission))
 484         {
 485                 // no zoom while dead or in intermission please
 486                 localcmd("-zoom\n");
 487                 button_zoom = FALSE;
 488         }
 489
 490         // event chase camera
 491         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 492         {
 493                 WepSet weapons_stat = WepSet_GetFromStat();
 494                 if(((spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead)) || intermission) && !autocvar_cl_orthoview || (autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(weapons_stat & WepSet_FromWeapon(WEP_PORTO))))
 495                 {
 496                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 497                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 498
 499                         // detect maximum viewoffset and use it
 500                         if(autocvar_cl_eventchase_viewoffset)
 501                         {
 502                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 503                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
 504                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 505                         }
 506
 507                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 508                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 509                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 510                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 511
 512                         // make the camera smooth back
 513                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 514                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 515                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 516                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 517
 518                         makevectors(view_angles);
 519
 520                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 521                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 522
 523                         // If the boxtrace fails, revert back to line tracing.
 524                         if(trace_startsolid)
 525                         {
 526                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 527                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 528                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 529                         }
 530                         else { setproperty(VF_ORIGIN, trace_endpos); }
 531
 532                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 533                 }
 534                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 535                 {
 536                         cvar_set("chase_active", "0");
 537                         eventchase_current_distance = 0; // start from 0 next time
 538                 }
 539         }
 540         // workaround for camera stuck between player's legs when using chase_active 1
 541         // because the engine stops updating the chase_active camera when the game ends
 542         else if(intermission)
 543         {
 544                 cvar_settemp("chase_active", "-1");
 545                 eventchase_current_distance = 0;
 546         }
 547
 548         // do lockview after event chase camera so that it still applies whenever necessary.
 549         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 550         {
 551                 setproperty(VF_ORIGIN, freeze_org);
 552                 setproperty(VF_ANGLES, freeze_ang);
 553         }
 554         else
 555         {
 556                 freeze_org = getpropertyvec(VF_ORIGIN);
 557                 freeze_ang = getpropertyvec(VF_ANGLES);
 558         }
 559
 560         WarpZone_FixView();
 561         //WarpZone_FixPMove();
 562
 563         vector ov_org = '0 0 0';
 564         vector ov_mid = '0 0 0';
 565         vector ov_worldmin = '0 0 0';
 566         vector ov_worldmax = '0 0 0';
 567         if(autocvar_cl_orthoview)
 568         {
 569                 ov_worldmin = mi_picmin;
 570                 ov_worldmax = mi_picmax;
 571
 572                 float ov_width = (ov_worldmax_x - ov_worldmin_x);
 573                 float ov_height = (ov_worldmax_y - ov_worldmin_y);
 574                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
 575
 576                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
 577                 ov_org = vec3(ov_mid_x, ov_mid_y, (ov_mid_z + ov_distance));
 578
 579                 float ov_nearest = vlen(ov_org - vec3(
 580                         bound(ov_worldmin_x, ov_org_x, ov_worldmax_x),
 581                         bound(ov_worldmin_y, ov_org_y, ov_worldmax_y),
 582                         bound(ov_worldmin_z, ov_org_z, ov_worldmax_z)
 583                 ));
 584
 585                 float ov_furthest = 0;
 586                 float dist = 0;
 587
 588                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 589                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 590                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 591                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 592                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 593                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 594                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 595                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 596
 597                 cvar_settemp("r_nearclip", ftos(ov_nearest));
 598                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
 599                 cvar_settemp("r_farclip_world", "0");
 600                 cvar_settemp("r_novis", "1");
 601                 cvar_settemp("r_useportalculling", "0");
 602                 cvar_settemp("r_useinfinitefarclip", "0");
 603
 604                 setproperty(VF_ORIGIN, ov_org);
 605                 setproperty(VF_ANGLES, '90 0 0');
 606
 607                 #if 0
 608                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
 609                         vtos(ov_org),
 610                         vtos(getpropertyvec(VF_ANGLES)),
 611                         ov_distance,
 612                         ov_nearest,
 613                         ov_furthest);
 614                 #endif
 615         }
 616
 617         // Render the Scene
 618         view_origin = getpropertyvec(VF_ORIGIN);
 619         view_angles = getpropertyvec(VF_ANGLES);
 620         makevectors(view_angles);
 621         view_forward = v_forward;
 622         view_right = v_right;
 623         view_up = v_up;
 624
 625 #ifdef BLURTEST
 626         if(time > blurtest_time0 && time < blurtest_time1)
 627         {
 628                 float r, t;
 629
 630                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 631                 r = t * blurtest_radius;
 632                 f = 1 / pow(t, blurtest_power) - 1;
 633
 634                 cvar_set("r_glsl_postprocess", "1");
 635                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 636         }
 637         else
 638         {
 639                 cvar_set("r_glsl_postprocess", "0");
 640                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 641         }
 642 #endif
 643
 644         TargetMusic_Advance();
 645         Fog_Force();
 646
 647         if(drawtime == 0)
 648                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 649         else
 650                 drawframetime = bound(0.000001, time - drawtime, 1);
 651         drawtime = time;
 652
 653         // watch for gametype changes here...
 654         // in ParseStuffCMD the cmd isn't executed yet :/
 655         // might even be better to add the gametype to TE_CSQC_INIT...?
 656         if(!postinit)
 657                 PostInit();
 658
 659         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 660         {
 661                 if(calledhooks & HOOK_START)
 662                 {
 663                         localcmd("\ncl_hook_gameend\n");
 664                         calledhooks |= HOOK_END;
 665                 }
 666         }
 667
 668         Announcer();
 669
 670         fov = autocvar_fov;
 671         if(fov <= 59.5)
 672         {
 673                 if(!zoomscript_caught)
 674                 {
 675                         localcmd("+button9\n");
 676                         zoomscript_caught = 1;
 677                 }
 678         }
 679         else
 680         {
 681                 if(zoomscript_caught)
 682                 {
 683                         localcmd("-button9\n");
 684                         zoomscript_caught = 0;
 685                 }
 686         }
 687
 688         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 689
 690         // next WANTED weapon (for HUD)
 691         switchweapon = getstati(STAT_SWITCHWEAPON);
 692
 693         // currently switching-to weapon (for crosshair)
 694         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 695
 696         // actually active weapon (for zoom)
 697         activeweapon = getstati(STAT_ACTIVEWEAPON);
 698
 699         f = (serverflags & SERVERFLAG_TEAMPLAY);
 700         if(f != teamplay)
 701         {
 702                 teamplay = f;
 703                 HUD_InitScores();
 704         }
 705
 706         if(last_switchweapon != switchweapon)
 707         {
 708                 weapontime = time;
 709                 last_switchweapon = switchweapon;
 710                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 711                 {
 712                         localcmd("-zoom\n");
 713                         button_zoom = FALSE;
 714                 }
 715                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 716                 {
 717                         localcmd("-fire\n");
 718                         localcmd("-fire2\n");
 719                         button_attack2 = FALSE;
 720                 }
 721         }
 722         if(last_activeweapon != activeweapon)
 723         {
 724                 last_activeweapon = activeweapon;
 725
 726                 e = get_weaponinfo(activeweapon);
 727                 if(e.netname != "")
 728                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 729                 else
 730                         localcmd("\ncl_hook_activeweapon none\n");
 731         }
 732
 733         // ALWAYS Clear Current Scene First
 734         clearscene();
 735 #ifdef WORKAROUND_XON010
 736         if(checkextension("DP_CSQC_ROTATEMOVES"))
 737         {
 738 #endif
 739         setproperty(VF_ORIGIN, view_origin);
 740         setproperty(VF_ANGLES, view_angles);
 741 #ifdef WORKAROUND_XON010
 742         }
 743 #endif
 744
 745         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 746         setproperty(VF_SIZE, vf_size);
 747         setproperty(VF_MIN, vf_min);
 748
 749         // Assign Standard Viewflags
 750         // Draw the World (and sky)
 751         setproperty(VF_DRAWWORLD, 1);
 752
 753         // Set the console size vars
 754         vid_conwidth = autocvar_vid_conwidth;
 755         vid_conheight = autocvar_vid_conheight;
 756         vid_pixelheight = autocvar_vid_pixelheight;
 757
 758         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
 759         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
 760
 761         // Camera for demo playback
 762         if(camera_active)
 763         {
 764                 if(autocvar_camera_enable)
 765                         CSQC_Demo_Camera();
 766                 else
 767                 {
 768                         cvar_set("chase_active", ftos(chase_active_backup));
 769                         cvar_set("cl_demo_mousegrab", "0");
 770                         camera_active = FALSE;
 771                 }
 772         }
 773 #ifdef CAMERATEST
 774         else if(autocvar_camera_enable)
 775 #else
 776         else if(autocvar_camera_enable && isdemo())
 777 #endif
 778         {
 779                 // Enable required Darkplaces cvars
 780                 chase_active_backup = autocvar_chase_active;
 781                 cvar_set("chase_active", "2");
 782                 cvar_set("cl_demo_mousegrab", "1");
 783                 camera_active = TRUE;
 784                 camera_mode = FALSE;
 785         }
 786
 787         // Draw the Crosshair
 788         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 789
 790         // Draw the Engine Status Bar (the default Quake HUD)
 791         setproperty(VF_DRAWENGINESBAR, 0);
 792
 793         // Update the mouse position
 794         /*
 795            mousepos_x = vid_conwidth;
 796            mousepos_y = vid_conheight;
 797            mousepos = mousepos*0.5 + getmousepos();
 798          */
 799
 800         e = self;
 801         for(self = world; (self = nextent(self)); )
 802                 if(self.draw)
 803                         self.draw();
 804         self = e;
 805
 806         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 807         renderscene();
 808
 809         // now switch to 2D drawing mode by calling a 2D drawing function
 810         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 811         // next R_RenderScene call
 812         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 813
 814         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 815         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
 816         {
 817                 // apply night vision effect
 818                 vector tc_00, tc_01, tc_10, tc_11;
 819                 vector rgb;
 820                 rgb_x = 0; // fteqcc sucks
 821                 rgb_y = 0; // fteqcc sucks
 822                 rgb_z = 0; // fteqcc sucks
 823
 824                 if(!nightvision_noise)
 825                 {
 826                         nightvision_noise = spawn();
 827                         nightvision_noise.classname = "nightvision_noise";
 828                 }
 829                 if(!nightvision_noise2)
 830                 {
 831                         nightvision_noise2 = spawn();
 832                         nightvision_noise2.classname = "nightvision_noise2";
 833                 }
 834
 835                 // color tint in yellow
 836                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 837
 838                 // draw BG
 839                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 840                 rgb = '1 1 1';
 841                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 842                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 843                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 844                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 845                 tc_11 = tc_01 + tc_10 - tc_00;
 846                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 847                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 848                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 849                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 850                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 851                 R_EndPolygon();
 852
 853                 // draw FG
 854                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 855                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 856                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 857                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 858                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 859                 tc_11 = tc_01 + tc_10 - tc_00;
 860                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 861                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 862                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 863                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 864                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 865                 R_EndPolygon();
 866         }
 867
 868         // Draw the aiming reticle for weapons that use it
 869         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 870         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 871         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 872         if(spectatee_status || is_dead || hud != HUD_NORMAL)
 873                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 874         else if((activeweapon == WEP_NEX || activeweapon == WEP_RIFLE || activeweapon == WEP_MINSTANEX) && (button_zoom || zoomscript_caught))
 875                 reticle_type = 2; // nex zoom
 876         else if(button_zoom || zoomscript_caught)
 877                 reticle_type = 1; // normal zoom
 878         else if((activeweapon == WEP_NEX) && button_attack2)
 879                 reticle_type = 2; // nex zoom
 880
 881         if(reticle_type && autocvar_cl_reticle)
 882         {
 883                 if(autocvar_cl_reticle_stretch)
 884                 {
 885                         reticle_size_x = vid_conwidth;
 886                         reticle_size_y = vid_conheight;
 887                         reticle_pos_x = 0;
 888                         reticle_pos_y = 0;
 889                 }
 890                 else
 891                 {
 892                         reticle_size_x = max(vid_conwidth, vid_conheight);
 893                         reticle_size_y = max(vid_conwidth, vid_conheight);
 894                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 895                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 896                 }
 897
 898                 f = current_zoomfraction;
 899                 if(zoomscript_caught)
 900                         f = 1;
 901                 if(autocvar_cl_reticle_item_normal)
 902                 {
 903                         if(reticle_type == 1 && f)
 904                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 905                 }
 906                 if(autocvar_cl_reticle_item_nex)
 907                 {
 908                         if(reticle_type == 2 && f)
 909                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 910                 }
 911         }
 912
 913
 914         // improved polyblend
 915         if(autocvar_hud_contents)
 916         {
 917                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 918                 vector liquidcolor;
 919
 920                 switch(pointcontents(view_origin))
 921                 {
 922                         case CONTENT_WATER:
 923                                 liquidalpha = autocvar_hud_contents_water_alpha;
 924                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 925                                 incontent = 1;
 926                                 break;
 927
 928                         case CONTENT_LAVA:
 929                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 930                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 931                                 incontent = 1;
 932                                 break;
 933
 934                         case CONTENT_SLIME:
 935                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 936                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 937                                 incontent = 1;
 938                                 break;
 939
 940                         default:
 941                                 liquidalpha = 0;
 942                                 liquidcolor = '0 0 0';
 943                                 incontent = 0;
 944                                 break;
 945                 }
 946
 947                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 948                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 949                         contentfadetime = autocvar_hud_contents_fadeintime;
 950                         liquidalpha_prev = liquidalpha;
 951                         liquidcolor_prev = liquidcolor;
 952                 }
 953                 else
 954                         contentfadetime = autocvar_hud_contents_fadeouttime;
 955
 956                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 957                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 958
 959                 if(contentavgalpha)
 960                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 961
 962                 if(autocvar_hud_postprocessing)
 963                 {
 964                         if(autocvar_hud_contents_blur && contentavgalpha)
 965                         {
 966                                 content_blurpostprocess_x = 1;
 967                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 968                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 969                         }
 970                         else
 971                         {
 972                                 content_blurpostprocess_x = 0;
 973                                 content_blurpostprocess_y = 0;
 974                                 content_blurpostprocess_z = 0;
 975                         }
 976                 }
 977         }
 978
 979         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 980         {
 981                 splash_size_x = max(vid_conwidth, vid_conheight);
 982                 splash_size_y = max(vid_conwidth, vid_conheight);
 983                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 984                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 985
 986                 float myhealth_flash_temp;
 987                 myhealth = getstati(STAT_HEALTH);
 988
 989                 // fade out
 990                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 991                 // add new damage
 992                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 993
 994                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 995                 pain_threshold = autocvar_hud_damage_pain_threshold;
 996                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 997                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 998
 999                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1000                 {
1001                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1002                 }
1003
1004                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1005
1006                 if(myhealth_prev < 1)
1007                 {
1008                         if(myhealth >= 1)
1009                         {
1010                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1011                                 myhealth_flash_temp = 0;
1012                         }
1013                         else
1014                         {
1015                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1016                         }
1017                 }
1018
1019                 if(spectatee_status == -1 || intermission)
1020                 {
1021                         myhealth_flash = 0; // observing, or match ended
1022                         myhealth_flash_temp = 0;
1023                 }
1024
1025                 myhealth_prev = myhealth;
1026
1027                 // IDEA: change damage color/picture based on player model for robot/alien species?
1028                 // pro: matches model better
1029                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1030                 // maybe different reddish pics?
1031                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1032                 {
1033                         if(autocvar_cl_gentle_damage == 2)
1034                         {
1035                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1036                                 {
1037                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1038                                 }
1039                         }
1040                         else
1041                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1042
1043                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1044                 }
1045                 else
1046                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1047
1048                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1049                 {
1050                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1051                         {
1052                                 damage_blurpostprocess_x = 1;
1053                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1054                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1055                         }
1056                         else
1057                         {
1058                                 damage_blurpostprocess_x = 0;
1059                                 damage_blurpostprocess_y = 0;
1060                                 damage_blurpostprocess_z = 0;
1061                         }
1062                 }
1063         }
1064
1065         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1066         float e2 = (autocvar_hud_powerup != 0);
1067         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1068         {
1069                 // enable or disable rendering types if they are used or not
1070                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1071                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1072
1073                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1074                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1075                 {
1076                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1077                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1078                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1079                         {
1080                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1081                                 old_blurradius = blurradius;
1082                                 old_bluralpha = bluralpha;
1083                         }
1084                 }
1085                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1086                 {
1087                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1088                         old_blurradius = 0;
1089                         old_bluralpha = 0;
1090                 }
1091
1092                 // edge detection postprocess handling done second (used by hud_powerup)
1093                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1094                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1095                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1096
1097                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1098
1099                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1100                 {
1101                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1102                         {
1103                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1104                                 old_sharpen_intensity = sharpen_intensity;
1105                         }
1106                 }
1107                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1108                 {
1109                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1110                         old_sharpen_intensity = 0;
1111                 }
1112
1113                 if(cvar("r_glsl_postprocess") == 0)
1114                         cvar_set("r_glsl_postprocess", "2");
1115         }
1116         else if(cvar("r_glsl_postprocess") == 2)
1117                 cvar_set("r_glsl_postprocess", "0");
1118
1119         if(menu_visible)
1120                 menu_show();
1121
1122         /*if(gametype == MAPINFO_TYPE_CTF)
1123           {
1124           ctf_view();
1125           } else */
1126
1127         // draw 2D entities
1128         e = self;
1129         for(self = world; (self = nextent(self)); )
1130                 if(self.draw2d)
1131                         self.draw2d();
1132         self = e;
1133         Draw_ShowNames_All();
1134
1135         scoreboard_active = HUD_WouldDrawScoreboard();
1136
1137         hit_time = getstatf(STAT_HIT_TIME);
1138         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1139         {
1140                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1141                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTEN_NONE);
1142
1143                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1144         }
1145         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1146         if(typehit_time > nextsound_typehit_time)
1147         {
1148                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1149                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTEN_NONE);
1150
1151                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1152         }
1153
1154         //else
1155         {
1156                 if(getstati(STAT_FROZEN))
1157                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1158                 else if (getstatf(STAT_HEALING_ORB)>time)
1159                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
1160                 if(!intermission)
1161                 if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1162                 {
1163                         DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1164                         drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1165                 }
1166                 else if(getstatf(STAT_REVIVE_PROGRESS))
1167                 {
1168                         DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1169                         drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1170                 }
1171
1172                 if(autocvar_r_letterbox == 0)
1173                         if(autocvar_viewsize < 120)
1174                                 CSQC_common_hud();
1175
1176                 // crosshair goes VERY LAST
1177                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1178                 {
1179                         if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1180                                 return;
1181
1182                         string wcross_style;
1183                         float wcross_alpha, wcross_resolution;
1184                         wcross_style = autocvar_crosshair;
1185                         if (wcross_style == "0")
1186                                 return;
1187                         wcross_resolution = autocvar_crosshair_size;
1188                         if (wcross_resolution == 0)
1189                                 return;
1190                         wcross_alpha = autocvar_crosshair_alpha;
1191                         if (wcross_alpha == 0)
1192                                 return;
1193
1194                         // TrueAim check
1195                         float shottype;
1196
1197                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1198                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1199                         wcross_origin_z = 0;
1200                         if(autocvar_crosshair_hittest)
1201                         {
1202                                 vector wcross_oldorigin;
1203                                 wcross_oldorigin = wcross_origin;
1204                                 shottype = TrueAimCheck();
1205                                 if(shottype == SHOTTYPE_HITWORLD)
1206                                 {
1207                                         v = wcross_origin - wcross_oldorigin;
1208                                         v_x /= vid_conwidth;
1209                                         v_y /= vid_conheight;
1210                                         if(vlen(v) > 0.01)
1211                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1212                                 }
1213                                 if(!autocvar_crosshair_hittest_showimpact)
1214                                         wcross_origin = wcross_oldorigin;
1215                         }
1216                         else
1217                                 shottype = SHOTTYPE_HITWORLD;
1218
1219                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1220                         string wcross_wep = "", wcross_name;
1221                         float wcross_scale, wcross_blur;
1222
1223                         if (autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1224                         {
1225                                 e = get_weaponinfo(switchingweapon);
1226                                 if (e && e.netname != "")
1227                                 {
1228                                         wcross_wep = e.netname;
1229                                         if(autocvar_crosshair_per_weapon)
1230                                         {
1231                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1232                                                 if (wcross_resolution == 0)
1233                                                         return;
1234                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1235                                                 if (wcross_alpha == 0)
1236                                                         return;
1237
1238                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1239                                                 if(wcross_style == "" || wcross_style == "0")
1240                                                         wcross_style = wcross_wep;
1241                                         }
1242                                 }
1243                         }
1244
1245                         //printf("crosshair style: %s\n", wcross_style);
1246                         wcross_name = strcat("gfx/crosshair", wcross_style);
1247
1248                         // MAIN CROSSHAIR COLOR DECISION
1249                         switch(autocvar_crosshair_color_special)
1250                         {
1251                                 case 1: // crosshair_color_per_weapon
1252                                 {
1253                                         if(wcross_wep != "")
1254                                         {
1255                                                 wcross_color = stov(cvar_string(sprintf("crosshair_%s_color", wcross_wep)));
1256                                                 break;
1257                                         }
1258                                         else { goto normalcolor; }
1259                                 }
1260
1261                                 case 2: // crosshair_color_by_health
1262                                 {
1263                                         float x = getstati(STAT_HEALTH);
1264
1265                                         //x = red
1266                                         //y = green
1267                                         //z = blue
1268
1269                                         wcross_color_z = 0;
1270
1271                                         if(x > 200)
1272                                         {
1273                                                 wcross_color_x = 0;
1274                                                 wcross_color_y = 1;
1275                                         }
1276                                         else if(x > 150)
1277                                         {
1278                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1279                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1280                                         }
1281                                         else if(x > 100)
1282                                         {
1283                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1284                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1285                                                 wcross_color_z = 1 - (x-100)*0.02;
1286                                         }
1287                                         else if(x > 50)
1288                                         {
1289                                                 wcross_color_x = 1;
1290                                                 wcross_color_y = 1;
1291                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1292                                         }
1293                                         else if(x > 20)
1294                                         {
1295                                                 wcross_color_x = 1;
1296                                                 wcross_color_y = (x-20)*90/27/100;
1297                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1298                                         }
1299                                         else
1300                                         {
1301                                                 wcross_color_x = 1;
1302                                                 wcross_color_y = 0;
1303                                         }
1304                                         break;
1305                                 }
1306
1307                                 case 3: // crosshair_color_rainbow
1308                                 {
1309                                         if(time >= rainbow_last_flicker)
1310                                         {
1311                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1312                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1313                                         }
1314                                         wcross_color = rainbow_prev_color;
1315                                         break;
1316                                 }
1317                                 :normalcolor
1318                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1319                         }
1320
1321                         if(autocvar_crosshair_effect_scalefade)
1322                         {
1323                                 wcross_scale = wcross_resolution;
1324                                 wcross_resolution = 1;
1325                         }
1326                         else
1327                         {
1328                                 wcross_scale = 1;
1329                         }
1330
1331                         if(autocvar_crosshair_pickup)
1332                         {
1333                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1334
1335                                 if(pickup_crosshair_time < stat_pickup_time)
1336                                 {
1337                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1338                                                 pickup_crosshair_size = 1;
1339
1340                                         pickup_crosshair_time = stat_pickup_time;
1341                                 }
1342
1343                                 if(pickup_crosshair_size > 0)
1344                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1345                                 else
1346                                         pickup_crosshair_size = 0;
1347
1348                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1349                         }
1350
1351                         if(autocvar_crosshair_hitindication)
1352                         {
1353                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1354
1355                                 if(hitindication_crosshair_time < hit_time)
1356                                 {
1357                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1358                                                 hitindication_crosshair_size = 1;
1359
1360                                         hitindication_crosshair_time = hit_time;
1361                                 }
1362
1363                                 if(hitindication_crosshair_size > 0)
1364                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1365                                 else
1366                                         hitindication_crosshair_size = 0;
1367
1368                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1369                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1370                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1371                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1372                         }
1373
1374                         if(shottype == SHOTTYPE_HITENEMY)
1375                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1376                         if(shottype == SHOTTYPE_HITTEAM)
1377                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1378
1379                         f = fabs(autocvar_crosshair_effect_time);
1380                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1381                         {
1382                                 wcross_changedonetime = time + f;
1383                         }
1384                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1385                         {
1386                                 wcross_name_changestarttime = time;
1387                                 wcross_name_changedonetime = time + f;
1388                                 if(wcross_name_goal_prev_prev)
1389                                         strunzone(wcross_name_goal_prev_prev);
1390                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1391                                 wcross_name_goal_prev = strzone(wcross_name);
1392                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1393                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1394                                 wcross_resolution_goal_prev = wcross_resolution;
1395                         }
1396
1397                         wcross_scale_goal_prev = wcross_scale;
1398                         wcross_alpha_goal_prev = wcross_alpha;
1399                         wcross_color_goal_prev = wcross_color;
1400
1401                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1402                         {
1403                                 wcross_blur = 1;
1404                                 wcross_alpha *= 0.75;
1405                         }
1406                         else
1407                                 wcross_blur = 0;
1408                         // *_prev is at time-frametime
1409                         // * is at wcross_changedonetime+f
1410                         // what do we have at time?
1411                         if(time < wcross_changedonetime)
1412                         {
1413                                 f = frametime / (wcross_changedonetime - time + frametime);
1414                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1415                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1416                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1417                         }
1418
1419                         wcross_scale_prev = wcross_scale;
1420                         wcross_alpha_prev = wcross_alpha;
1421                         wcross_color_prev = wcross_color;
1422
1423                         wcross_scale *= 1 - autocvar__menu_alpha;
1424                         wcross_alpha *= 1 - autocvar__menu_alpha;
1425                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1426
1427                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1428                         {
1429                                 // crosshair rings for weapon stats
1430                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1431                                 {
1432                                         // declarations and stats
1433                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1434                                         string ring_image = string_null, ring_inner_image = string_null;
1435                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1436
1437                                         ring_scale = autocvar_crosshair_ring_size;
1438
1439                                         float weapon_clipload, weapon_clipsize;
1440                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1441                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1442
1443                                         float nex_charge, nex_chargepool;
1444                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1445                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1446
1447                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1448                                                 nex_charge_movingavg = nex_charge;
1449
1450
1451                                         // handle the values
1452                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1453                                         {
1454                                                 if (nex_chargepool || use_nex_chargepool) {
1455                                                         use_nex_chargepool = 1;
1456                                                         ring_inner_value = nex_chargepool;
1457                                                 } else {
1458                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1459                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1460                                                 }
1461
1462                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1463                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1464                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1465
1466                                                 // draw the outer ring to show the current charge of the weapon
1467                                                 ring_value = nex_charge;
1468                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1469                                                 ring_rgb = wcross_color;
1470                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1471                                         }
1472                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1473                                         {
1474                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1475                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1476                                                 ring_rgb = wcross_color;
1477                                                 ring_image = "gfx/crosshair_ring.tga";
1478                                         }
1479                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1480                                         {
1481                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1482                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1483                                                 ring_rgb = wcross_color;
1484                                                 ring_image = "gfx/crosshair_ring.tga";
1485                                         }
1486
1487                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1488                                         {
1489                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1490                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1491                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1492                                                 ring_rgb = wcross_color;
1493
1494                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1495                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1496                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1497                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1498                                                 else
1499                                                         ring_image = "gfx/crosshair_ring.tga";
1500                                         }
1501
1502                                         // if in weapon switch animation, fade ring out/in
1503                                         if(autocvar_crosshair_effect_time > 0)
1504                                         {
1505                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1506                                                 if (!(f < 1))
1507                                                 {
1508                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1509                                                 }
1510
1511                                                 if(wcross_ring_prev)
1512                                                 {
1513                                                         if(f < 1)
1514                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1515                                                 }
1516                                                 else
1517                                                 {
1518                                                         if(f < 1)
1519                                                                 ring_alpha *= bound(0, f, 1);
1520                                                 }
1521                                         }
1522
1523                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1524                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1525
1526                                         if (ring_value)
1527                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1528                                 }
1529
1530 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1531                                 do \
1532                                 { \
1533                                         if(wcross_blur > 0) \
1534                                         { \
1535                                                 for(i = -2; i <= 2; ++i) \
1536                                                 for(j = -2; j <= 2; ++j) \
1537                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1538                                         } \
1539                                         else \
1540                                         { \
1541                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1542                                         } \
1543                                 } \
1544                                 while(0)
1545
1546 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1547                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1548
1549 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1550                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1551
1552                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1553                                 {
1554                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1555                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1556                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1557                                         f = 1 - f;
1558                                 }
1559                                 else
1560                                 {
1561                                         f = 1;
1562                                 }
1563                                 wcross_name_alpha_goal_prev = f;
1564
1565                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1566                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1567
1568                                 if(autocvar_crosshair_dot)
1569                                 {
1570                                         vector wcross_color_old;
1571                                         wcross_color_old = wcross_color;
1572
1573                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1574                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1575
1576                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1577                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1578                                         wcross_color = wcross_color_old;
1579                                 }
1580                         }
1581                 }
1582                 else
1583                 {
1584                         wcross_scale_prev = 0;
1585                         wcross_alpha_prev = 0;
1586                         wcross_scale_goal_prev = 0;
1587                         wcross_alpha_goal_prev = 0;
1588                         wcross_changedonetime = 0;
1589                         if(wcross_name_goal_prev)
1590                                 strunzone(wcross_name_goal_prev);
1591                         wcross_name_goal_prev = string_null;
1592                         if(wcross_name_goal_prev_prev)
1593                                 strunzone(wcross_name_goal_prev_prev);
1594                         wcross_name_goal_prev_prev = string_null;
1595                         wcross_name_changestarttime = 0;
1596                         wcross_name_changedonetime = 0;
1597                         wcross_name_alpha_goal_prev = 0;
1598                         wcross_name_alpha_goal_prev_prev = 0;
1599                         wcross_resolution_goal_prev = 0;
1600                         wcross_resolution_goal_prev_prev = 0;
1601                 }
1602         }
1603
1604         if(NextFrameCommand)
1605         {
1606                 localcmd("\n", NextFrameCommand, "\n");
1607                 NextFrameCommand = string_null;
1608         }
1609
1610         // we must do this check AFTER a frame was rendered, or it won't work
1611         if(cs_project_is_b0rked == 0)
1612         {
1613                 string w0, h0;
1614                 w0 = ftos(autocvar_vid_conwidth);
1615                 h0 = ftos(autocvar_vid_conheight);
1616                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1617                 //setproperty(VF_FOV, '90 90 0');
1618                 setproperty(VF_ORIGIN, '0 0 0');
1619                 setproperty(VF_ANGLES, '0 0 0');
1620                 setproperty(VF_PERSPECTIVE, 1);
1621                 makevectors('0 0 0');
1622                 vector v1, v2;
1623                 cvar_set("vid_conwidth", "800");
1624                 cvar_set("vid_conheight", "600");
1625                 v1 = cs_project(v_forward);
1626                 cvar_set("vid_conwidth", "640");
1627                 cvar_set("vid_conheight", "480");
1628                 v2 = cs_project(v_forward);
1629                 if(v1 == v2)
1630                         cs_project_is_b0rked = 1;
1631                 else
1632                         cs_project_is_b0rked = -1;
1633                 cvar_set("vid_conwidth", w0);
1634                 cvar_set("vid_conheight", h0);
1635         }
1636
1637         if(autocvar__hud_configure)
1638                 HUD_Panel_Mouse();
1639
1640     if(hud && !intermission)
1641                 VEH_ACTION(hud, VR_HUD);
1642
1643         cl_notice_run();
1644
1645         // let's reset the view back to normal for the end
1646         setproperty(VF_MIN, '0 0 0');
1647         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1648 }
1649
1650
1651 void CSQC_common_hud(void)
1652 {
1653         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1654                 Accuracy_LoadLevels();
1655
1656         HUD_Main(); // always run these functions for alpha checks
1657         HUD_DrawScoreboard();
1658
1659         if (scoreboard_active) // scoreboard/accuracy
1660                 HUD_Reset();
1661         else if (intermission == 2) // map voting screen
1662         {
1663                 MapVote_Draw();
1664                 HUD_Reset();
1665         }
1666 }
1667
1668
1669 // following vectors must be global to allow seamless switching between camera modes
1670 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1671 void CSQC_Demo_Camera()
1672 {
1673         float speed, attenuation, dimensions;
1674         vector tmp, delta;
1675
1676         if( autocvar_camera_reset || !camera_mode )
1677         {
1678                 camera_offset = '0 0 0';
1679                 current_angles = '0 0 0';
1680                 camera_direction = '0 0 0';
1681                 camera_offset_z += 30;
1682                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1683                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1684                 current_origin = view_origin;
1685                 current_camera_offset  = camera_offset;
1686                 cvar_set("camera_reset", "0");
1687                 camera_mode = CAMERA_CHASE;
1688         }
1689
1690         // Camera angles
1691         if( camera_roll )
1692                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1693
1694         if(autocvar_camera_look_player)
1695         {
1696                 vector dir;
1697                 float n;
1698
1699                 dir = normalize(view_origin - current_position);
1700                 n = mouse_angles_z;
1701                 mouse_angles = vectoangles(dir);
1702                 mouse_angles_x = mouse_angles_x * -1;
1703                 mouse_angles_z = n;
1704         }
1705         else
1706         {
1707                 tmp = getmousepos() * 0.1;
1708                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1709                 {
1710                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1711                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1712                 }
1713         }
1714
1715         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1716         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1717         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1718         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1719
1720         // Fix difference when angles don't have the same sign
1721         delta = '0 0 0';
1722         if(mouse_angles_y < -60 && current_angles_y > 60)
1723                 delta = '0 360 0';
1724         if(mouse_angles_y > 60 && current_angles_y < -60)
1725                 delta = '0 -360 0';
1726
1727         if(autocvar_camera_look_player)
1728                 attenuation = autocvar_camera_look_attenuation;
1729         else
1730                 attenuation = autocvar_camera_speed_attenuation;
1731
1732         attenuation = 1 / max(1, attenuation);
1733         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1734
1735         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1736         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1737         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1738         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1739
1740         // Camera position
1741         tmp = '0 0 0';
1742         dimensions = 0;
1743
1744         if( camera_direction_x )
1745         {
1746                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1747                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1748                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1749                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1750                 ++dimensions;
1751         }
1752
1753         if( camera_direction_y )
1754         {
1755                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1756                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1757                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1758                 ++dimensions;
1759         }
1760
1761         if( camera_direction_z )
1762         {
1763                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1764                 ++dimensions;
1765         }
1766
1767         if(autocvar_camera_free)
1768                 speed = autocvar_camera_speed_free;
1769         else
1770                 speed = autocvar_camera_speed_chase;
1771
1772         if(dimensions)
1773         {
1774                 speed = speed * sqrt(1 / dimensions);
1775                 camera_offset += tmp * speed;
1776         }
1777
1778         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1779
1780         // Camera modes
1781         if( autocvar_camera_free )
1782         {
1783                 if ( camera_mode == CAMERA_CHASE )
1784                 {
1785                         current_camera_offset = current_origin + current_camera_offset;
1786                         camera_offset = current_origin + camera_offset;
1787                 }
1788
1789                 camera_mode = CAMERA_FREE;
1790                 current_position = current_camera_offset;
1791         }
1792         else
1793         {
1794                 if ( camera_mode == CAMERA_FREE )
1795                 {
1796                         current_origin = view_origin;
1797                         camera_offset = camera_offset - current_origin;
1798                         current_camera_offset = current_camera_offset - current_origin;
1799                 }
1800
1801                 camera_mode = CAMERA_CHASE;
1802
1803                 if(autocvar_camera_chase_smoothly)
1804                         current_origin += (view_origin - current_origin) * attenuation;
1805                 else
1806                         current_origin = view_origin;
1807
1808                 current_position = current_origin + current_camera_offset;
1809         }
1810
1811         setproperty(VF_ANGLES, current_angles);
1812         setproperty(VF_ORIGIN, current_position);
1813 }