qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 string forcefog;
  36 void WaypointSprite_Load();
  37 void ConsoleCommand_macro_init();
  38 void CSQC_Init(void)
  39 {
  40         prvm_language = cvar_string("prvm_language");
  41 #ifdef USE_FTE
  42 #pragma target ID
  43         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  44         if(!__engine_check)
  45         {
  46                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  47                 localcmd("\ndisconnect\n");
  48                 return;
  49         }
  50 #pragma target FTE
  51 #endif
  52
  53         check_unacceptable_compiler_bugs();
  54
  55 #ifdef WATERMARK
  56         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK));
  57 #endif
  58
  59         float i;
  60
  61 #ifdef COMPAT_XON050_ENGINE
  62         // old engine lacks implementation of player_localnum
  63         player_localnum = player_localentnum - 1;
  64 #endif
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69         compressShortVector_init();
  70
  71         draw_endBoldFont();
  72         menu_visible = FALSE;
  73         menu_show = menu_show_error;
  74         menu_action = func_null;
  75
  76         for(i = 0; i < 255; ++i)
  77                 if(getplayerkeyvalue(i, "viewentity") == "")
  78                         break;
  79         maxclients = i;
  80
  81         //registercommand("hud_configure");
  82         //registercommand("hud_save");
  83         //registercommand("menu_action");
  84
  85         ConsoleCommand_macro_init();
  86
  87         registercvar("hud_usecsqc", "1");
  88         registercvar("scoreboard_columns", "default");
  89
  90         gametype = 0;
  91
  92         // hud_fields uses strunzone on the titles!
  93         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  94                 hud_title[i] = strzone("(null)");
  95
  96         postinit = false;
  97
  98         calledhooks = 0;
  99
 100         teams = Sort_Spawn();
 101         players = Sort_Spawn();
 102
 103         GetTeam(NUM_SPECTATOR, true); // add specs first
 104
 105         // needs to be done so early because of the constants they create
 106         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 107         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 108         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 109         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 110         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 111
 112         WaypointSprite_Load();
 113
 114         // precaches
 115         precache_model("null");
 116         precache_sound("misc/hit.wav");
 117         precache_sound("misc/typehit.wav");
 118
 119         Projectile_Precache();
 120         Hook_Precache();
 121         GibSplash_Precache();
 122         Casings_Precache();
 123         DamageInfo_Precache();
 124         Vehicles_Precache();
 125         turrets_precache();
 126         Tuba_Precache();
 127         CSQCPlayer_Precache();
 128
 129         if(autocvar_cl_reticle)
 130         {
 131                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 132                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 133         }
 134
 135         get_mi_min_max_texcoords(1); // try the CLEVER way first
 136         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 137         shortmapname = mi_shortname;
 138
 139         if(precache_pic(minimapname) == "")
 140         {
 141                 // but maybe we have a non-clever minimap
 142                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 143                 if(precache_pic(minimapname) == "")
 144                         minimapname = ""; // FAIL
 145                 else
 146                         get_mi_min_max_texcoords(0); // load new texcoords
 147         }
 148
 149         mi_center = (mi_min + mi_max) * 0.5;
 150         mi_scale = mi_max - mi_min;
 151         minimapname = strzone(minimapname);
 152
 153         WarpZone_Init();
 154
 155         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 156         hud_configure_prev = -1;
 157
 158         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 159 }
 160
 161 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 162 void Shutdown(void)
 163 {
 164 #ifdef USE_FTE
 165 #pragma TARGET id
 166         if(!__engine_check)
 167                 return 0;
 168 #pragma TARGET fte
 169 #endif
 170
 171         WarpZone_Shutdown();
 172
 173         remove(teams);
 174         remove(players);
 175         db_close(binddb);
 176         db_close(tempdb);
 177         if(autocvar_cl_db_saveasdump)
 178                 db_dump(ClientProgsDB, "client.db");
 179         else
 180                 db_save(ClientProgsDB, "client.db");
 181         db_close(ClientProgsDB);
 182
 183         if(camera_active)
 184                 cvar_set("chase_active",ftos(chase_active_backup));
 185
 186         // unset the event chasecam's chase_active
 187         if(autocvar_chase_active < 0)
 188                 cvar_set("chase_active", "0");
 189
 190         if not(isdemo())
 191         {
 192                 if not(calledhooks & HOOK_START)
 193                         localcmd("\n_cl_hook_gamestart nop\n");
 194                 if not(calledhooks & HOOK_END)
 195                         localcmd("\ncl_hook_gameend\n");
 196         }
 197 }
 198
 199 .float has_team;
 200 float SetTeam(entity o, float Team)
 201 {
 202         entity tm;
 203         if(teamplay)
 204         {
 205                 switch(Team)
 206                 {
 207                         case -1:
 208                         case NUM_TEAM_1:
 209                         case NUM_TEAM_2:
 210                         case NUM_TEAM_3:
 211                         case NUM_TEAM_4:
 212                                 break;
 213                         default:
 214                                 if(GetTeam(Team, false) == world)
 215                                 {
 216                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 217                                         Team = NUM_SPECTATOR;
 218                                 }
 219                                 break;
 220                 }
 221         }
 222         else
 223         {
 224                 switch(Team)
 225                 {
 226                         case -1:
 227                         case 0:
 228                                 break;
 229                         default:
 230                                 if(GetTeam(Team, false) == world)
 231                                 {
 232                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 233                                         Team = NUM_SPECTATOR;
 234                                 }
 235                                 break;
 236                 }
 237         }
 238         if(Team == -1) // leave
 239         {
 240                 if(o.has_team)
 241                 {
 242                         tm = GetTeam(o.team, false);
 243                         tm.team_size -= 1;
 244                         o.has_team = 0;
 245                         return TRUE;
 246                 }
 247         }
 248         else
 249         {
 250                 if not(o.has_team)
 251                 {
 252                         o.team = Team;
 253                         tm = GetTeam(Team, true);
 254                         tm.team_size += 1;
 255                         o.has_team = 1;
 256                         return TRUE;
 257                 }
 258                 else if(Team != o.team)
 259                 {
 260                         tm = GetTeam(o.team, false);
 261                         tm.team_size -= 1;
 262                         o.team = Team;
 263                         tm = GetTeam(Team, true);
 264                         tm.team_size += 1;
 265                         return TRUE;
 266                 }
 267         }
 268         return FALSE;
 269 }
 270
 271 void Playerchecker_Think()
 272 {
 273         float i;
 274         entity e;
 275         for(i = 0; i < maxclients; ++i)
 276         {
 277                 e = playerslots[i];
 278                 if(GetPlayerName(i) == "")
 279                 {
 280                         if(e.sort_prev)
 281                         {
 282                                 // player disconnected
 283                                 SetTeam(e, -1);
 284                                 RemovePlayer(e);
 285                                 e.sort_prev = world;
 286                                 //e.gotscores = 0;
 287                         }
 288                 }
 289                 else
 290                 {
 291                         if not(e.sort_prev)
 292                         {
 293                                 // player connected
 294                                 if not(e)
 295                                         playerslots[i] = e = spawn();
 296                                 e.sv_entnum = i;
 297                                 e.ping = 0;
 298                                 e.ping_packetloss = 0;
 299                                 e.ping_movementloss = 0;
 300                                 //e.gotscores = 0; // we might already have the scores...
 301                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 302                                 RegisterPlayer(e);
 303                                 HUD_UpdatePlayerPos(e);
 304                         }
 305                 }
 306         }
 307         self.nextthink = time + 0.2;
 308 }
 309
 310 void Porto_Init();
 311 void TrueAim_Init();
 312 void PostInit(void)
 313 {
 314         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 315
 316         entity playerchecker;
 317         playerchecker = spawn();
 318         playerchecker.think = Playerchecker_Think;
 319         playerchecker.nextthink = time + 0.2;
 320
 321         Porto_Init();
 322         TrueAim_Init();
 323
 324         postinit = true;
 325 }
 326
 327 float button_zoom;
 328
 329 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 330 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 331 // All keys are in ascii.
 332 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 333 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 334 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 335 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 336 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 337 {
 338         float bSkipKey;
 339         bSkipKey = false;
 340
 341         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 342                 return true;
 343
 344         if (HUD_QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 345                 return true;
 346
 347         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 348                 return true;
 349
 350         if(menu_visible && menu_action)
 351                 if(menu_action(bInputType, nPrimary, nSecondary))
 352                         return TRUE;
 353
 354         return bSkipKey;
 355 }
 356
 357 // END REQUIRED CSQC FUNCTIONS
 358 // --------------------------------------------------------------------------
 359
 360 // --------------------------------------------------------------------------
 361 // BEGIN OPTIONAL CSQC FUNCTIONS
 362 void Ent_RemoveEntCS()
 363 {
 364         entcs_receiver[self.sv_entnum] = world;
 365 }
 366 void Ent_ReadEntCS()
 367 {
 368         float sf;
 369         InterpolateOrigin_Undo();
 370
 371         self.classname = "entcs_receiver";
 372         sf = ReadByte();
 373
 374         if(sf & 1)
 375                 self.sv_entnum = ReadByte();
 376         if(sf & 2)
 377         {
 378                 self.origin_x = ReadShort();
 379                 self.origin_y = ReadShort();
 380                 self.origin_z = ReadShort();
 381                 setorigin(self, self.origin);
 382         }
 383         if(sf & 4)
 384         {
 385                 self.angles_y = ReadByte() * 360.0 / 256;
 386                 self.angles_x = self.angles_z = 0;
 387         }
 388         if(sf & 8)
 389                 self.healthvalue = ReadByte() * 10;
 390         if(sf & 16)
 391                 self.armorvalue = ReadByte() * 10;
 392
 393         entcs_receiver[self.sv_entnum] = self;
 394         self.entremove = Ent_RemoveEntCS;
 395         self.iflags |= IFLAG_ORIGIN;
 396
 397         InterpolateOrigin_Note();
 398 }
 399
 400 void Ent_Remove();
 401
 402 void Ent_RemovePlayerScore()
 403 {
 404         float i;
 405
 406         if(self.owner)
 407         {
 408                 SetTeam(self.owner, -1);
 409                 self.owner.gotscores = 0;
 410                 for(i = 0; i < MAX_SCORE; ++i)
 411                         self.owner.(scores[i]) = 0; // clear all scores
 412         }
 413 }
 414
 415 void Ent_ReadPlayerScore()
 416 {
 417         float i, n;
 418         float isNew;
 419         entity o;
 420
 421         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 422         // (no I've never heard of M-x replace-string, sed, or anything like that)
 423         isNew = !self.owner; // workaround for DP bug
 424         n = ReadByte()-1;
 425
 426 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 427         if(!isNew && n != self.sv_entnum)
 428         {
 429                 //print("A CSQC entity changed its owner!\n");
 430                 print(sprintf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname));
 431                 isNew = true;
 432                 Ent_Remove();
 433                 self.enttype = ENT_CLIENT_SCORES;
 434         }
 435 #endif
 436
 437         self.sv_entnum = n;
 438
 439         if not(playerslots[self.sv_entnum])
 440                 playerslots[self.sv_entnum] = spawn();
 441         o = self.owner = playerslots[self.sv_entnum];
 442         o.sv_entnum = self.sv_entnum;
 443         o.gotscores = 1;
 444
 445         //if not(o.sort_prev)
 446         //      RegisterPlayer(o);
 447         //playerchecker will do this for us later, if it has not already done so
 448
 449         float sf, lf;
 450 #if MAX_SCORE <= 8
 451         sf = ReadByte();
 452         lf = ReadByte();
 453 #else
 454         sf = ReadShort();
 455         lf = ReadShort();
 456 #endif
 457         float p;
 458         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 459                 if(sf & p)
 460                 {
 461                         if(lf & p)
 462                                 o.(scores[i]) = ReadInt24_t();
 463                         else
 464                                 o.(scores[i]) = ReadChar();
 465                 }
 466
 467         if(o.sort_prev)
 468                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 469
 470         self.entremove = Ent_RemovePlayerScore;
 471 }
 472
 473 void Ent_ReadTeamScore()
 474 {
 475         float i;
 476         entity o;
 477
 478         self.team = ReadByte();
 479         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 480
 481         float sf, lf;
 482 #if MAX_TEAMSCORE <= 8
 483         sf = ReadByte();
 484         lf = ReadByte();
 485 #else
 486         sf = ReadShort();
 487         lf = ReadShort();
 488 #endif
 489         float p;
 490         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 491                 if(sf & p)
 492                 {
 493                         if(lf & p)
 494                                 o.(teamscores[i]) = ReadInt24_t();
 495                         else
 496                                 o.(teamscores[i]) = ReadChar();
 497                 }
 498
 499         HUD_UpdateTeamPos(o);
 500 }
 501
 502 void Ent_ClientData()
 503 {
 504         float f;
 505         float newspectatee_status;
 506
 507         f = ReadByte();
 508
 509         scoreboard_showscores_force = (f & 1);
 510
 511         if(f & 2)
 512         {
 513                 newspectatee_status = ReadByte();
 514                 if(newspectatee_status == player_localnum + 1)
 515                         newspectatee_status = -1; // observing
 516         }
 517         else
 518                 newspectatee_status = 0;
 519
 520         spectatorbutton_zoom = (f & 4);
 521
 522         if(f & 8)
 523         {
 524                 angles_held_status = 1;
 525                 angles_held_x = ReadAngle();
 526                 angles_held_y = ReadAngle();
 527                 angles_held_z = 0;
 528         }
 529         else
 530                 angles_held_status = 0;
 531
 532         if(newspectatee_status != spectatee_status)
 533         {
 534                 // clear race stuff
 535                 race_laptime = 0;
 536                 race_checkpointtime = 0;
 537         }
 538         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 539         {
 540                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 541                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 542                 )
 543                         prev_p_health = -1;
 544                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 545                         prev_health = -1;
 546         }
 547         spectatee_status = newspectatee_status;
 548
 549         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 550 }
 551
 552 void Ent_Nagger()
 553 {
 554         float nags, i, j, b, f;
 555
 556         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 557
 558         if(!(nags & 4))
 559         {
 560                 if(vote_called_vote)
 561                         strunzone(vote_called_vote);
 562                 vote_called_vote = string_null;
 563                 vote_active = 0;
 564         }
 565         else
 566         {
 567                 vote_active = 1;
 568         }
 569
 570         if(nags & 64)
 571         {
 572                 vote_yescount = ReadByte();
 573                 vote_nocount = ReadByte();
 574                 vote_needed = ReadByte();
 575                 vote_highlighted = ReadChar();
 576         }
 577
 578         if(nags & 128)
 579         {
 580                 if(vote_called_vote)
 581                         strunzone(vote_called_vote);
 582                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 583         }
 584
 585         if(nags & 1)
 586         {
 587                 for(j = 0; j < maxclients; ++j)
 588                         if(playerslots[j])
 589                                 playerslots[j].ready = 1;
 590                 for(i = 1; i <= maxclients; i += 8)
 591                 {
 592                         f = ReadByte();
 593                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 594                                 if not(f & b)
 595                                         if(playerslots[j])
 596                                                 playerslots[j].ready = 0;
 597                 }
 598         }
 599
 600         ready_waiting = (nags & 1);
 601         ready_waiting_for_me = (nags & 2);
 602         vote_waiting = (nags & 4);
 603         vote_waiting_for_me = (nags & 8);
 604         warmup_stage = (nags & 16);
 605 }
 606
 607 void Ent_RandomSeed()
 608 {
 609         float s;
 610         prandom_debug();
 611         s = ReadShort();
 612         psrandom(s);
 613 }
 614
 615 void Ent_ReadAccuracy(void)
 616 {
 617         float sf, f, w, b;
 618         sf = ReadInt24_t();
 619         if(sf == 0)
 620         {
 621                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 622                         weapon_accuracy[w] = -1;
 623                 return;
 624         }
 625
 626         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 627         {
 628                 if(sf & f)
 629                 {
 630                         b = ReadByte();
 631                         if(b == 0)
 632                                 weapon_accuracy[w] = -1;
 633                         else if(b == 255)
 634                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 635                         else
 636                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 637                 }
 638                 if(f == 0x800000)
 639                         f = 1;
 640                 else
 641                         f *= 2;
 642         }
 643 }
 644
 645 void Spawn_Draw(void)
 646 {
 647         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 648 }
 649
 650 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 651 {
 652         float teamnum = (ReadByte() - 1);
 653         vector spn_origin;
 654         spn_origin_x = ReadShort();
 655         spn_origin_y = ReadShort();
 656         spn_origin_z = ReadShort();
 657
 658         if(is_new)
 659         {
 660                 self.origin = spn_origin;
 661                 setsize(self, PL_MIN, PL_MAX);
 662                 droptofloor();
 663
 664                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 665                 {
 666                         self.mdl = "models/spawnpoint.md3";
 667                         self.colormod = Team_ColorRGB(teamnum);
 668                         precache_model(self.mdl);
 669                         setmodel(self, self.mdl);
 670                         self.drawmask = MASK_NORMAL;
 671                         //self.movetype = MOVETYPE_NOCLIP;
 672                         //self.draw = Spawn_Draw;
 673                 }*/
 674                 if(autocvar_cl_spawn_point_particles)
 675                 {
 676                         if((serverflags & SERVERFLAG_TEAMPLAY))
 677                         {
 678                                 switch(teamnum)
 679                                 {
 680                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 681                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 682                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 683                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 684                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 685                                 }
 686                         }
 687                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 688
 689                         self.draw = Spawn_Draw;
 690                 }
 691         }
 692
 693         //print(sprintf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt));
 694 }
 695
 696 void Ent_ReadSpawnEvent(float is_new)
 697 {
 698         // If entnum is 0, ONLY do the local spawn actions
 699         // this way the server can disable the sending of
 700         // spawn origin or such to clients if wanted.
 701         float entnum = ReadByte();
 702
 703         if(entnum)
 704         {
 705                 self.origin_x = ReadShort();
 706                 self.origin_y = ReadShort();
 707                 self.origin_z = ReadShort();
 708
 709                 if(is_new)
 710                 {
 711                         float teamnum = GetPlayerColor(entnum - 1);
 712
 713                         if(autocvar_cl_spawn_event_particles)
 714                         {
 715                                 switch(teamnum)
 716                                 {
 717                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 718                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 719                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 720                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 721                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 722                                 }
 723                         }
 724                         if(autocvar_cl_spawn_event_sound)
 725                         {
 726                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 727                         }
 728                 }
 729         }
 730
 731         // local spawn actions
 732         if(is_new && (!entnum || (entnum == player_localentnum)))
 733         {
 734                 zoomin_effect = 1;
 735                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 736
 737                 if(autocvar_cl_unpress_zoom_on_spawn)
 738                 {
 739                         localcmd("-zoom\n");
 740                         button_zoom = FALSE;
 741                 }
 742         }
 743
 744         //print(sprintf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum));
 745 }
 746
 747 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 748 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 749 void Ent_RadarLink();
 750 void Ent_Init();
 751 void Ent_ScoresInfo();
 752 void CSQC_Ent_Update(float bIsNewEntity)
 753 {
 754         float t;
 755         float savetime;
 756         t = ReadByte();
 757
 758         if(autocvar_developer_csqcentities)
 759                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 760
 761         // set up the "time" global for received entities to be correct for interpolation purposes
 762         savetime = time;
 763         if(servertime)
 764         {
 765                 time = servertime;
 766         }
 767         else
 768         {
 769                 serverprevtime = time;
 770                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 771                 time = serverprevtime + serverdeltatime;
 772         }
 773
 774 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 775         if(self.enttype)
 776         {
 777                 if(t != self.enttype || bIsNewEntity)
 778                 {
 779                         //print("A CSQC entity changed its type!\n");
 780                         print(sprintf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t));
 781                         Ent_Remove();
 782                         clearentity(self);
 783                         bIsNewEntity = 1;
 784                 }
 785         }
 786         else
 787         {
 788                 if(!bIsNewEntity)
 789                 {
 790                         print(sprintf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t));
 791                         bIsNewEntity = 1;
 792                 }
 793         }
 794 #endif
 795         self.enttype = t;
 796         switch(t)
 797         {
 798                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 799                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 800                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 801                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 802                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 803                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 804                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 805                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 806                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 807                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 808                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 809                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 810                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 811                 case ENT_CLIENT_INIT: Ent_Init(); break;
 812                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 813                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 814                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 815                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 816                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 817                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 818                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 819                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 820                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 821                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 822                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 823                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 824                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 825                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 826                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 827                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 828                 case ENT_CLIENT_TURRET: ent_turret(); break;
 829                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 830                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 831                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 832                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 833                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 834                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 835
 836                 default:
 837                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 838                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 839                         break;
 840         }
 841
 842         time = savetime;
 843 }
 844 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 845 // used when an entity changes its type. For an entity that someone interacts
 846 // with others, make sure it can no longer do so.
 847 void Ent_Remove()
 848 {
 849         if(self.entremove)
 850                 self.entremove();
 851
 852         if(self.skeletonindex)
 853         {
 854                 skel_delete(self.skeletonindex);
 855                 self.skeletonindex = 0;
 856         }
 857
 858         if(self.snd_looping > 0)
 859         {
 860                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 861                 self.snd_looping = 0;
 862         }
 863
 864         self.enttype = 0;
 865         self.classname = "";
 866         self.draw = menu_sub_null;
 867         self.entremove = menu_sub_null;
 868         // TODO possibly set more stuff to defaults
 869 }
 870 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 871 void CSQC_Ent_Remove()
 872 {
 873         if(autocvar_developer_csqcentities)
 874                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 875
 876         if(wasfreed(self))
 877         {
 878                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 879                 return;
 880         }
 881         if(self.enttype)
 882                 Ent_Remove();
 883         remove(self);
 884 }
 885
 886 void Gamemode_Init()
 887 {
 888         if not(isdemo())
 889         {
 890                 if(!(calledhooks & HOOK_START))
 891                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 892                 calledhooks |= HOOK_START;
 893         }
 894 }
 895 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 896 void CSQC_Parse_StuffCmd(string strMessage)
 897 {
 898         if(autocvar_developer_csqcentities)
 899                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 900
 901         localcmd(strMessage);
 902 }
 903 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 904 void CSQC_Parse_Print(string strMessage)
 905 {
 906         if(autocvar_developer_csqcentities)
 907                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 908
 909         print(ColorTranslateRGB(strMessage));
 910 }
 911
 912 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 913 void CSQC_Parse_CenterPrint(string strMessage)
 914 {
 915         if(autocvar_developer_csqcentities)
 916                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 917
 918         centerprint_hud(strMessage);
 919 }
 920
 921 string notranslate_fogcmd1 = "\nfog ";
 922 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 923 void Fog_Force()
 924 {
 925         // TODO somehow thwart prvm_globalset client ...
 926
 927         if(forcefog != "")
 928                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 929 }
 930
 931 void Gamemode_Init();
 932 void Ent_ScoresInfo()
 933 {
 934         float i;
 935         self.classname = "ent_client_scores_info";
 936         gametype = ReadInt24_t();
 937         for(i = 0; i < MAX_SCORE; ++i)
 938         {
 939                 scores_label[i] = strzone(ReadString());
 940                 scores_flags[i] = ReadByte();
 941         }
 942         for(i = 0; i < MAX_TEAMSCORE; ++i)
 943         {
 944                 teamscores_label[i] = strzone(ReadString());
 945                 teamscores_flags[i] = ReadByte();
 946         }
 947         HUD_InitScores();
 948         Gamemode_Init();
 949 }
 950
 951 void Ent_Init()
 952 {
 953         self.classname = "ent_client_init";
 954
 955         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 956
 957         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 958         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 959         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 960         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 961         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 962         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 963         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 964         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 965         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 966         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 967         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 968         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 969
 970         if(forcefog)
 971                 strunzone(forcefog);
 972         forcefog = strzone(ReadString());
 973
 974         armorblockpercent = ReadByte() / 255.0;
 975
 976         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 977         g_balance_grenadelauncher_bouncestop = ReadCoord();
 978         g_balance_electro_secondary_bouncefactor = ReadCoord();
 979         g_balance_electro_secondary_bouncestop = ReadCoord();
 980
 981         nex_scope = !ReadByte();
 982         rifle_scope = !ReadByte();
 983
 984         serverflags = ReadByte();
 985
 986         minelayer_maxmines = ReadByte();
 987
 988         hagar_maxrockets = ReadByte();
 989
 990         g_trueaim_minrange = ReadCoord();
 991         g_balance_porto_secondary = ReadByte();
 992
 993         if(!postinit)
 994                 PostInit();
 995 }
 996
 997 void Net_ReadRace()
 998 {
 999         float b;
1000
1001         b = ReadByte();
1002
1003         switch(b)
1004         {
1005                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1006                         race_checkpoint = ReadByte();
1007                         race_time = ReadInt24_t();
1008                         race_previousbesttime = ReadInt24_t();
1009                         if(race_previousbestname)
1010                                 strunzone(race_previousbestname);
1011                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1012
1013                         race_checkpointtime = time;
1014
1015                         if(race_checkpoint == 0 || race_checkpoint == 254)
1016                         {
1017                                 race_penaltyaccumulator = 0;
1018                                 race_laptime = time; // valid
1019                         }
1020
1021                         break;
1022
1023                 case RACE_NET_CHECKPOINT_CLEAR:
1024                         race_laptime = 0;
1025                         race_checkpointtime = 0;
1026                         break;
1027
1028                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1029                         race_laptime = ReadCoord();
1030                         race_checkpointtime = -99999;
1031                         // fall through
1032                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1033                         race_nextcheckpoint = ReadByte();
1034
1035                         race_nextbesttime = ReadInt24_t();
1036                         if(race_nextbestname)
1037                                 strunzone(race_nextbestname);
1038                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1039                         break;
1040
1041                 case RACE_NET_CHECKPOINT_HIT_RACE:
1042                         race_mycheckpoint = ReadByte();
1043                         race_mycheckpointtime = time;
1044                         race_mycheckpointdelta = ReadInt24_t();
1045                         race_mycheckpointlapsdelta = ReadByte();
1046                         if(race_mycheckpointlapsdelta >= 128)
1047                                 race_mycheckpointlapsdelta -= 256;
1048                         if(race_mycheckpointenemy)
1049                                 strunzone(race_mycheckpointenemy);
1050                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1051                         break;
1052
1053                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1054                         race_othercheckpoint = ReadByte();
1055                         race_othercheckpointtime = time;
1056                         race_othercheckpointdelta = ReadInt24_t();
1057                         race_othercheckpointlapsdelta = ReadByte();
1058                         if(race_othercheckpointlapsdelta >= 128)
1059                                 race_othercheckpointlapsdelta -= 256;
1060                         if(race_othercheckpointenemy)
1061                                 strunzone(race_othercheckpointenemy);
1062                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1063                         break;
1064
1065                 case RACE_NET_PENALTY_RACE:
1066                         race_penaltyeventtime = time;
1067                         race_penaltytime = ReadShort();
1068                         //race_penaltyaccumulator += race_penaltytime;
1069                         if(race_penaltyreason)
1070                                 strunzone(race_penaltyreason);
1071                         race_penaltyreason = strzone(ReadString());
1072                         break;
1073
1074                 case RACE_NET_PENALTY_QUALIFYING:
1075                         race_penaltyeventtime = time;
1076                         race_penaltytime = ReadShort();
1077                         race_penaltyaccumulator += race_penaltytime;
1078                         if(race_penaltyreason)
1079                                 strunzone(race_penaltyreason);
1080                         race_penaltyreason = strzone(ReadString());
1081                         break;
1082
1083                 case RACE_NET_SERVER_RECORD:
1084                         race_server_record = ReadInt24_t();
1085                         break;
1086                 case RACE_NET_SPEED_AWARD:
1087                         race_speedaward = ReadInt24_t();
1088                         if(race_speedaward_holder)
1089                                 strunzone(race_speedaward_holder);
1090                         race_speedaward_holder = strzone(ReadString());
1091                         break;
1092                 case RACE_NET_SPEED_AWARD_BEST:
1093                         race_speedaward_alltimebest = ReadInt24_t();
1094                         if(race_speedaward_alltimebest_holder)
1095                                 strunzone(race_speedaward_alltimebest_holder);
1096                         race_speedaward_alltimebest_holder = strzone(ReadString());
1097                         break;
1098                 case RACE_NET_SERVER_RANKINGS:
1099                         float pos, prevpos, del;
1100                         pos = ReadShort();
1101                         prevpos = ReadShort();
1102                         del = ReadShort();
1103
1104                         // move other rankings out of the way
1105                         float i;
1106                         if (prevpos) {
1107                                 for (i=prevpos-1;i>pos-1;--i) {
1108                                         grecordtime[i] = grecordtime[i-1];
1109                                         if(grecordholder[i])
1110                                                 strunzone(grecordholder[i]);
1111                                         grecordholder[i] = strzone(grecordholder[i-1]);
1112                                 }
1113                         } else if (del) { // a record has been deleted by the admin
1114                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1115                                         if (i == RANKINGS_CNT-1) { // clear out last record
1116                                                 grecordtime[i] = 0;
1117                                                 if (grecordholder[i])
1118                                                         strunzone(grecordholder[i]);
1119                                                 grecordholder[i] = string_null;
1120                                         }
1121                                         else {
1122                                                 grecordtime[i] = grecordtime[i+1];
1123                                                 if (grecordholder[i])
1124                                                         strunzone(grecordholder[i]);
1125                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1126                                         }
1127                                 }
1128                         } else { // player has no ranked record yet
1129                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1130                                         grecordtime[i] = grecordtime[i-1];
1131                                         if(grecordholder[i])
1132                                                 strunzone(grecordholder[i]);
1133                                         grecordholder[i] = strzone(grecordholder[i-1]);
1134                                 }
1135                         }
1136
1137                         // store new ranking
1138                         if(grecordholder[pos-1] != "")
1139                                 strunzone(grecordholder[pos-1]);
1140                         grecordholder[pos-1] = strzone(ReadString());
1141                         grecordtime[pos-1] = ReadInt24_t();
1142                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1143                                 race_myrank = pos;
1144                         break;
1145                 case RACE_NET_SERVER_STATUS:
1146                         race_status = ReadShort();
1147                         if(race_status_name)
1148                                 strunzone(race_status_name);
1149                         race_status_name = strzone(ReadString());
1150         }
1151 }
1152
1153 void Net_TeamNagger()
1154 {
1155         teamnagger = 1;
1156 }
1157
1158 void Net_ReadPingPLReport()
1159 {
1160         float e, pi, pl, ml;
1161         e = ReadByte();
1162         pi = ReadShort();
1163         pl = ReadByte();
1164         ml = ReadByte();
1165         if not(playerslots[e])
1166                 return;
1167         playerslots[e].ping = pi;
1168         playerslots[e].ping_packetloss = pl / 255.0;
1169         playerslots[e].ping_movementloss = ml / 255.0;
1170 }
1171
1172 void Net_WeaponComplain()
1173 {
1174         complain_weapon = ReadByte();
1175
1176         if(complain_weapon_name)
1177                 strunzone(complain_weapon_name);
1178         complain_weapon_name = strzone(ReadString());
1179
1180         complain_weapon_type = ReadByte();
1181
1182         complain_weapon_time = time;
1183         weapontime = time; // ping the weapon panel
1184
1185         switch(complain_weapon_type)
1186         {
1187                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1188                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1189                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1190         }
1191 }
1192
1193 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1194 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1195 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1196 float CSQC_Parse_TempEntity()
1197 {
1198         float bHandled;
1199                 bHandled  = true;
1200         // Acquire TE ID
1201         float nTEID;
1202                 nTEID = ReadByte();
1203
1204         if(autocvar_developer_csqcentities)
1205                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1206
1207                 // NOTE: Could just do return instead of break...
1208         switch(nTEID)
1209         {
1210                 case TE_CSQC_TARGET_MUSIC:
1211                         Net_TargetMusic();
1212                         bHandled = true;
1213                         break;
1214                 case TE_CSQC_PICTURE:
1215                         Net_MapVote_Picture();
1216                         bHandled = true;
1217                         break;
1218                 case TE_CSQC_RACE:
1219                         Net_ReadRace();
1220                         bHandled = true;
1221                         break;
1222                 case TE_CSQC_ZCURVEPARTICLES:
1223                         Net_ReadZCurveParticles();
1224                         bHandled = true;
1225                         break;
1226                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1227                         Net_ReadNexgunBeamParticle();
1228                         bHandled = true;
1229                         break;
1230                 case TE_CSQC_TEAMNAGGER:
1231                         Net_TeamNagger();
1232                         bHandled = true;
1233                         break;
1234                 case TE_CSQC_LIGHTNINGARC:
1235                         Net_ReadLightningarc();
1236                         bHandled = true;
1237                         break;
1238                 case TE_CSQC_PINGPLREPORT:
1239                         Net_ReadPingPLReport();
1240                         bHandled = true;
1241                         break;
1242                 case TE_CSQC_WEAPONCOMPLAIN:
1243                         Net_WeaponComplain();
1244                         bHandled = true;
1245                         break;
1246                 case TE_CSQC_VEHICLESETUP:
1247                         Net_VehicleSetup();
1248                         bHandled = true;
1249                         break;
1250                 case TE_CSQC_SVNOTICE:
1251                         cl_notice_read();
1252                         bHandled = true;
1253                         break;
1254                 default:
1255                         // No special logic for this temporary entity; return 0 so the engine can handle it
1256                         bHandled = false;
1257                         break;
1258         }
1259
1260         return bHandled;
1261 }
1262
1263 string getcommandkey(string text, string command)
1264 {
1265         string keys;
1266         float n, j, k, l = 0;
1267
1268         if (!autocvar_hud_showbinds)
1269                 return text;
1270
1271         keys = db_get(binddb, command);
1272         if (keys == "")
1273         {
1274                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1275                 for(j = 0; j < n; ++j)
1276                 {
1277                         k = stof(argv(j));
1278                         if(k != -1)
1279                         {
1280                                 if ("" == keys)
1281                                         keys = keynumtostring(k);
1282                                 else
1283                                         keys = strcat(keys, ", ", keynumtostring(k));
1284
1285                                 ++l;
1286                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1287                                         break;
1288                         }
1289
1290                 }
1291                 if (keys == "")
1292                         keys = "NO_KEY";
1293                 db_put(binddb, command, keys);
1294         }
1295
1296         if (keys == "NO_KEY") {
1297                 if (autocvar_hud_showbinds > 1)
1298                         return sprintf(_("%s (not bound)"), text);
1299                 else
1300                         return text;
1301         }
1302         else if (autocvar_hud_showbinds > 1)
1303                 return sprintf(_("%s (%s)"), text, keys);
1304         else
1305                 return keys;
1306 }