data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         makevectors(self.angles);\r
  22         vore_w_shotorg = self.origin;\r
  23         vore_w_shotdir = v_forward;\r
  24 \r
  25         if(self.antilag_debug)\r
  26                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  27         else\r
  28                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  29         if(trace_fraction < 1)\r
  30         if(trace_ent.classname == "player")\r
  31                 return trace_ent;\r
  32         return world;\r
  33 }\r
  34 \r
  35 float Swallow_condition_check(entity prey)\r
  36 {\r
  37         // checks the necessary conditions for swallowing a player\r
  38 \r
  39         if(prey != self)\r
  40         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  41         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  42         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  43         {\r
  44                 string swallow_complain;\r
  45                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  46                         swallow_complain = "You cannot swallow your team mates\n";\r
  47                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  48                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  49                 else if(self.stomach_load >= self.stomach_maxload)\r
  50                         swallow_complain = "You do not have any more room to swallow this player.\n";\r
  51                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  52                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  53                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  54                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  55 \r
  56                 if(swallow_complain != "")\r
  57                 {\r
  58                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  59                         {\r
  60                                 play2(self, "misc/forbidden.wav");\r
  61                                 sprint(self, swallow_complain);\r
  62                                 self.complain_vore = time + complain_delay_time;\r
  63                         }\r
  64                         return FALSE;\r
  65                 }\r
  66                 return TRUE;\r
  67         }\r
  68         return FALSE;\r
  69 }\r
  70 \r
  71 float Stomach_TeamMates_check(entity pred)\r
  72 {\r
  73         // checks if a player's stomach contains any team mates\r
  74 \r
  75         entity head;\r
  76         if(teams_matter)\r
  77         {\r
  78                 FOR_EACH_PLAYER(head)\r
  79                 {\r
  80                         if(head.predator == pred && head.team == pred.team)\r
  81                                 return TRUE;\r
  82                 }\r
  83         }\r
  84         return FALSE;\r
  85 }\r
  86 \r
  87 float Vore_CanLeave()\r
  88 {\r
  89         if(self.stat_eaten)\r
  90         {\r
  91                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  92                         return TRUE;\r
  93                 if(teams_matter && self.team == self.predator.team)\r
  94                         return TRUE;\r
  95                 if(g_rpg && cvar("g_rpg_canleave"))\r
  96                         return TRUE;\r
  97         }\r
  98         return FALSE;\r
  99 }\r
 100 \r
 101 // position the camera properly for prey\r
 102 void Vore_SetPreyPositions()\r
 103 {\r
 104         // self is the predator and head is the prey\r
 105 \r
 106         local entity head;\r
 107         local vector origin_apply;\r
 108         local float position_counter;\r
 109 \r
 110         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 111         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 112         // For each player, the origin is updated, then a new origin is used for the next player.\r
 113         // This requires that no more than 9 players may be in the stomach at a time!\r
 114         FOR_EACH_PLAYER(head)\r
 115         {\r
 116                 if(head.predator == self)\r
 117                 {\r
 118                         switch(position_counter)\r
 119                         {\r
 120                                 case 0:\r
 121                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 122                                         break;\r
 123                                 case 1:\r
 124                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 125                                         break;\r
 126                                 case 2:\r
 127                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 128                                         break;\r
 129                                 case 3:\r
 130                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 131                                         break;\r
 132                                 case 4:\r
 133                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 134                                         break;\r
 135                                 case 5:\r
 136                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 137                                         break;\r
 138                                 case 6:\r
 139                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 140                                         break;\r
 141                                 case 7:\r
 142                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 143                                         break;\r
 144                                 case 8:\r
 145                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 146                                         break;\r
 147                                 default:\r
 148                                         break;\r
 149                         }\r
 150 \r
 151                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 152                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 153                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 154 \r
 155                         // change prey height based on scale\r
 156                         float prey_height;\r
 157                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 158                         head.view_ofs_z += prey_height;\r
 159 \r
 160                         position_counter += 1;\r
 161                 }\r
 162         }\r
 163 }\r
 164 \r
 165 .float gurgle_oldstomachload;\r
 166 void Vore_GurgleSound()\r
 167 {\r
 168         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 169         {\r
 170                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 171 \r
 172                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 173                 self.gurgle_oldstomachload = self.stomach_load;\r
 174         }\r
 175 }\r
 176 \r
 177 void Vore_StomachLoad_Apply()\r
 178 {\r
 179         // apply stomach weight that makes you heavier and larger the more you eat\r
 180         // slowing the player is done in cl_physics.qc\r
 181 \r
 182         entity e;\r
 183         float vore_mass;\r
 184 \r
 185         // apply the stomach capacity of the predator\r
 186         self.stomach_maxload = cvar("g_balance_vore_load_pred_capacity");\r
 187         if(cvar("g_healthsize"))\r
 188                 self.stomach_maxload *= self.scale;\r
 189         self.stomach_maxload = floor(self.stomach_maxload);\r
 190 \r
 191         self.stomach_load = 0; // start from zero\r
 192         FOR_EACH_PLAYER(e)\r
 193         {\r
 194                 if(e.predator == self && e.classname == "player")\r
 195                 {\r
 196                         vore_mass = cvar("g_balance_vore_load_prey_mass");\r
 197                         if(cvar("g_healthsize"))\r
 198                                 vore_mass *= e.scale;\r
 199                         self.stomach_load += floor(vore_mass);\r
 200                 }\r
 201         }\r
 202 \r
 203         // apply weight\r
 204         self.gravity = 1 + (self.stomach_load / self.stomach_maxload) * cvar("g_balance_vore_load_pred_weight");\r
 205         if(!self.gravity && self.stomach_load)\r
 206                 self.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 207 }\r
 208 \r
 209 void Vore_AutoDigest(entity e)\r
 210 {\r
 211         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 212 \r
 213         if(!cvar("g_vore_digestion") || e.digesting)\r
 214                 return;\r
 215         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 216                 return; // this feature is only for players, not bots\r
 217         if(e.stomach_load > 1)\r
 218                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 219         if(Stomach_TeamMates_check(e))\r
 220                 return; // never begin automatic digestion if we've swallowed a team mate\r
 221 \r
 222         e.digesting = TRUE;\r
 223 }\r
 224 \r
 225 .entity swallow_model;\r
 226 float Vore_SwallowModel_CustomizeEntityForClient()\r
 227 {\r
 228         // use the same system as the weapon model\r
 229 \r
 230         self.viewmodelforclient = self.owner;\r
 231         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 232 \r
 233         if(other.classname == "spectator")\r
 234         if(other.enemy == self.owner)\r
 235         {\r
 236                 self.viewmodelforclient = other;\r
 237                 self.alpha = other.cvar_cl_vore_swallowmodel;\r
 238         }\r
 239 \r
 240         return TRUE;\r
 241 }\r
 242 \r
 243 void Vore_SwallowModel_Think()\r
 244 {\r
 245         // update the position of the swallow model to match our swallow progress\r
 246         float dist;\r
 247         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 248         if(cvar("g_healthsize"))\r
 249                 dist *= self.scale;\r
 250         self.view_ofs = '1 0 0' * dist;\r
 251 \r
 252         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 253         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 254         {\r
 255                 remove(self.owner.swallow_model);\r
 256                 self.owner.swallow_model = world;\r
 257                 return;\r
 258         }\r
 259 \r
 260         // properties that should update whenever possible, but when the predator is not available\r
 261         self.nextthink = time;\r
 262 }\r
 263 \r
 264 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 265 {\r
 266         // if we don't have a swallow model already, spawn one\r
 267         if(!prey.swallow_model)\r
 268         {\r
 269                 prey.swallow_model = spawn();\r
 270                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 271                 prey.swallow_model.solid = SOLID_NOT;\r
 272                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 273                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 274                 prey.swallow_model.owner = prey;\r
 275                 prey.swallow_model.customizeentityforclient = Vore_SwallowModel_CustomizeEntityForClient;\r
 276                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 277                 prey.swallow_model.nextthink = time;\r
 278         }\r
 279 \r
 280         // properties that should update whenever possible, but when the predator is available\r
 281         string player_swallowmodel;\r
 282         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 283         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 284                 setmodel(prey.swallow_model, player_swallowmodel);\r
 285         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 286                 prey.swallow_model.skin = pred.skin;\r
 287         if(cvar("g_healthsize"))\r
 288                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 289         if(prey.swallow_model.enemy != pred)\r
 290                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 291         if(prey.swallow_model.colormap != pred.colormap)\r
 292                 prey.swallow_model.colormap = pred.colormap; // pants and shirt color\r
 293         if(prey.swallow_model.glowmod != pred.glowmod)\r
 294                 prey.swallow_model.glowmod = pred.glowmod; // glow color\r
 295 }\r
 296 \r
 297 .entity pusher;\r
 298 .float pushltime;\r
 299 void Vore_Swallow(entity e)\r
 300 {\r
 301         // this player is being swallowed by another player, apply the proper changes\r
 302 \r
 303         e.vore_oldmovetype = e.movetype;\r
 304         e.vore_oldsolid = e.solid;\r
 305 \r
 306         e.predator = self;\r
 307         setorigin(e, e.predator.origin);\r
 308         e.velocity = '0 0 0';\r
 309         e.movetype = MOVETYPE_FOLLOW;\r
 310         e.solid = SOLID_NOT;\r
 311         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 312 \r
 313         // drop keys (KH) and flags (CTF) when we get swallowed\r
 314         kh_Key_DropAll(e, FALSE);\r
 315         if(e.flagcarried)\r
 316                 DropFlag(e.flagcarried, world, e.predator);\r
 317 \r
 318         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 319                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 320 \r
 321         if(teams_matter && e.team == e.predator.team)\r
 322         {\r
 323                 if(cvar("g_vore_kick"))\r
 324                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 325                 if(cvar("g_vore_digestion"))\r
 326                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 327         }\r
 328 \r
 329         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 330         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 331         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 332         e.predator.regurgitate_prepare = 0;\r
 333         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 334         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 335         Vore_AutoDigest(e.predator);\r
 336 \r
 337         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 338         e.predator.weapon_delay = time + button_delay_time;\r
 339         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 340         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 341         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 342 }\r
 343 \r
 344 void Vore_SwallowStep(entity e)\r
 345 {\r
 346         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 347         {\r
 348                 Vore_Swallow(e);\r
 349                 return;\r
 350         }\r
 351 \r
 352         Vore_SwallowModel_Update(e, self);\r
 353 \r
 354         // increase the progress value until it reaches 1, then swallow the player\r
 355         if(e.swallow_progress_prey < 1)\r
 356         {\r
 357                 float fill;\r
 358                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 359                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 360                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
 361                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 362                         fill /= e.stomach_load;\r
 363 \r
 364                 e.swallow_progress_prey += fill;\r
 365         }\r
 366         else\r
 367         {\r
 368                 Vore_Swallow(e);\r
 369                 e.swallow_progress_prey = 0;\r
 370         }\r
 371 \r
 372         // the predator's progress is how much the prey got swallowed\r
 373         self.swallow_progress_pred = e.swallow_progress_prey;\r
 374 }\r
 375 \r
 376 void Vore_Regurgitate(entity e)\r
 377 {\r
 378         // this player is being regurgitated by their predator, apply the proper changes\r
 379 \r
 380         e.movetype = e.vore_oldmovetype;\r
 381         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 382                 e.solid = e.vore_oldsolid;\r
 383         e.view_ofs_z = PL_VIEW_OFS_z;\r
 384 \r
 385         // apply velocities\r
 386         local vector oldforward, oldright, oldup;\r
 387         oldforward = v_forward;\r
 388         oldright = v_right;\r
 389         oldup = v_up;\r
 390         makevectors(e.predator.v_angle);\r
 391         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 392         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 393         v_forward = oldforward;\r
 394         v_right = oldright;\r
 395         v_up = oldup;\r
 396 \r
 397         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 398         e.pushltime = time + cvar("g_maxpushtime");\r
 399 \r
 400         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 401         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 402         {\r
 403                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 404                 Vore_SwallowModel_Update(e, e.predator);\r
 405         }\r
 406 \r
 407         // apply regurgitation damage to the predator\r
 408         if(cvar("g_balance_vore_regurgitate_damage"))\r
 409         {\r
 410                 float regurgitate_dmg;\r
 411                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 412                 if(cvar("g_healthsize"))\r
 413                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 414                 Damage(e.predator, e.predator, e.predator, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 415         }\r
 416 \r
 417         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 418         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 419         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
 420         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 421         e.predator.regurgitate_prepare = 0;\r
 422         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 423 \r
 424         // block firing for a small amount of time, or we'll be firing the next frame\r
 425         e.weapon_delay = time + button_delay_time;\r
 426         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 427         e.predator = world;\r
 428 }\r
 429 \r
 430 void Vore_DeadPrey_Configure(entity e)\r
 431 {\r
 432         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 433 \r
 434         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 435                 return;\r
 436 \r
 437         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 438         e.fakepredator = e.predator;\r
 439         e.fakeprey = TRUE;\r
 440 \r
 441         // first release the prey from the predator, as dead prey needs to be attached differently\r
 442         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 443         e.predator = world;\r
 444 \r
 445         // now put our dead prey inside the predator's stomach, but only as an effect\r
 446         e.movetype = MOVETYPE_FOLLOW;\r
 447         e.takedamage = DAMAGE_NO;\r
 448         e.solid = SOLID_NOT;\r
 449         e.aiment = e.fakepredator;\r
 450 }\r
 451 \r
 452 void Vore_DeadPrey_Detach(entity e)\r
 453 {\r
 454         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 455         // should only execute after Vore_DeadPrey_Configure has ran first\r
 456 \r
 457         if not(cvar("g_vore_keepdeadprey"))\r
 458                 return;\r
 459 \r
 460         e.fakepredator = world;\r
 461         e.fakeprey = TRUE; // keep fakeprey status\r
 462         e.stat_eaten = 0;\r
 463         e.aiment = world;\r
 464         e.movetype = MOVETYPE_TOSS;\r
 465 }\r
 466 \r
 467 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 468 {\r
 469         if(pred_disconnect)\r
 470         {\r
 471                 if(e.fakeprey)\r
 472                         Vore_DeadPrey_Detach(e);\r
 473                 else\r
 474                         Vore_Regurgitate(e);\r
 475         }\r
 476         else if(self.stat_eaten && !self.fakeprey)\r
 477         {\r
 478                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 479                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 480                         Vore_DeadPrey_Configure(e);\r
 481                 else\r
 482                         Vore_Regurgitate(e);\r
 483         }\r
 484 }\r
 485 \r
 486 void Vore_Disconnect()\r
 487 {\r
 488         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 489 \r
 490         // prey disconnects or goes spectating while inside someone's belly\r
 491         if(self.stat_eaten)\r
 492                 Vore_PreyRelease(self, TRUE);\r
 493 \r
 494         // pred disconnects or goes spectating with players in their belly\r
 495         entity head;\r
 496         FOR_EACH_PLAYER(head)\r
 497         {\r
 498                 if(head.predator == self || head.fakepredator == self)\r
 499                         Vore_PreyRelease(head, TRUE);\r
 500         }\r
 501         Vore_GurgleSound(); // stop the gurgling sound\r
 502 \r
 503         self.stomach_load = self.gravity = 0; // prevents a bug\r
 504 }\r
 505 \r
 506 .float digestion_step;\r
 507 void Vore_Digest()\r
 508 {\r
 509         // apply digestion to prey\r
 510 \r
 511         if(time > self.digestion_step)\r
 512         {\r
 513                 // if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach\r
 514                 float vore_offset;\r
 515                 if(cvar("g_balance_vore_digestion_distribute"))\r
 516                         vore_offset = self.predator.stomach_maxload / self.predator.stomach_load;\r
 517                 else\r
 518                         vore_offset = 1;\r
 519 \r
 520                 float damage;\r
 521                 damage = cvar("g_balance_vore_digestion_damage") / vore_offset;\r
 522 \r
 523                 // apply player scale to digestion damage\r
 524                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff"))\r
 525                         damage *= pow(self.predator.scale / self.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 526 \r
 527                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 528                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 529                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / vore_offset;\r
 530 \r
 531                 if (self.predator.digestsound_finished < time)\r
 532                 {\r
 533                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 534                         self.predator.digestsound_finished = time + 0.5;\r
 535                 }\r
 536                 self.digestion_step = time + steptime;\r
 537         }\r
 538 \r
 539         if(self.deadflag != DEAD_NO)\r
 540         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 541                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 542 }\r
 543 \r
 544 .float teamheal_step;\r
 545 void Vore_Teamheal()\r
 546 {\r
 547         // apply teamheal\r
 548 \r
 549         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 550         if(time > self.teamheal_step)\r
 551         {\r
 552                 self.health += cvar("g_balance_vore_teamheal");\r
 553                 self.teamheal_step = time + steptime;\r
 554 \r
 555                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 556                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 557                 {\r
 558                         play2(self, "misc/beep.wav");\r
 559                         play2(self.predator, "misc/beep.wav");\r
 560                 }\r
 561         }\r
 562 }\r
 563 \r
 564 .float kick_pressed;\r
 565 void Vore_StomachKick()\r
 566 {\r
 567         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 568 \r
 569         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 570         {\r
 571                 float damage, vol;\r
 572                 vector force;\r
 573                 damage = cvar("g_balance_vore_kick_damage");\r
 574                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 575                 vol = VOL_BASE;\r
 576 \r
 577                 // apply player scale to the damage / force of the kick\r
 578                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 579                 {\r
 580                         damage *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 581                         force *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 582                         vol *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff")); // kick sound volume based on the same scale\r
 583                 }\r
 584                 vol = bound(0, vol, 1);\r
 585 \r
 586                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 587                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM);\r
 588                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 589                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 590 \r
 591                 // abort the predator's scheduled regurgitation\r
 592                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 593                         self.predator.regurgitate_prepare = 0;\r
 594 \r
 595                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 596                 if(cvar("g_balance_vore_kick_repress"))\r
 597                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 598                         self.kick_pressed = TRUE;\r
 599         }\r
 600 }\r
 601 \r
 602 void Vore_StomachLeave()\r
 603 {\r
 604         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 605 \r
 606         if(Vore_CanLeave())\r
 607                 Vore_Regurgitate(self);\r
 608         else if(time > self.complain_vore)\r
 609         {\r
 610                 play2(self, "misc/forbidden.wav");\r
 611                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 612                 self.complain_vore = time + complain_delay_time;\r
 613         }\r
 614 }\r
 615 \r
 616 void Vore_AutoTaunt()\r
 617 {\r
 618         // triggers ambient vore taunts, for both pred and prey\r
 619 \r
 620         float taunt_time;\r
 621 \r
 622         // predator taunts\r
 623         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 624         {\r
 625                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 626                 {\r
 627                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 628                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 629                 }\r
 630         }\r
 631         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 632         {\r
 633                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 634                 SetAutoTaunt(self, 0, 0);\r
 635         }\r
 636 \r
 637         // prey taunts\r
 638         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 639         {\r
 640                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 641                 {\r
 642                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 643                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 644                 }\r
 645         }\r
 646         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 647         {\r
 648                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 649                 SetAutoTaunt(self, 0, 0);\r
 650         }\r
 651 }\r
 652 \r
 653 void Vore_SetSbarRings()\r
 654 {\r
 655         // first clear the ring stats, then configure them if needed\r
 656         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 657         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 658 \r
 659         if(self.stat_eaten)\r
 660         {\r
 661                 if(time <= self.stomachkick_delay)\r
 662                 {\r
 663                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 664                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 665                 }\r
 666         }\r
 667         else\r
 668         {\r
 669                 if(self.swallow_progress_pred)\r
 670                 {\r
 671                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 672                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 673                 }\r
 674                 else if(time <= self.action_delay)\r
 675                 {\r
 676                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 677                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 678                 }\r
 679 \r
 680                 if(self.swallow_progress_prey)\r
 681                 {\r
 682                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 683                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 684                 }\r
 685                 else if(time <= self.regurgitate_prepare)\r
 686                 {\r
 687                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 688                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 689                 }\r
 690         }\r
 691 }\r
 692 \r
 693 void Vore()\r
 694 {\r
 695         // main vore code, this is where it all happens\r
 696 \r
 697         Vore_AutoTaunt();\r
 698 \r
 699         // wash the goo away from players once they leave the stomach\r
 700         if(!self.stat_eaten)\r
 701         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 702         if(self.colormod)\r
 703         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 704         {\r
 705                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 706                 if(self.colormod_x > 1)\r
 707                         self.colormod_x = 1;\r
 708                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 709                 if(self.colormod_y > 1)\r
 710                         self.colormod_y = 1;\r
 711                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 712                 if(self.colormod_z > 1)\r
 713                         self.colormod_z = 1;\r
 714         }\r
 715 \r
 716         // set all vore stats\r
 717         Vore_SetSbarRings();\r
 718         if(self.fakepredator.classname == "player")\r
 719                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 720         else if(self.predator.classname == "player")\r
 721         {\r
 722                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 723                 self.stat_stomachmaxload = self.predator.stomach_maxload; // necessary for the stomach board\r
 724                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 725                 self.stat_eaten = num_for_edict(self.predator);\r
 726         }\r
 727         else\r
 728         {\r
 729                 self.stat_stomachload = self.stomach_load;\r
 730                 self.stat_stomachmaxload = self.stomach_maxload;\r
 731                 self.stat_digesting = self.digesting;\r
 732                 self.stat_eaten = 0;\r
 733         }\r
 734         self.stat_canleave = Vore_CanLeave();\r
 735 \r
 736         // don't allow a player inside a player inside another player :)\r
 737         // prevent this by checking if such has happened, and taking the proper measures\r
 738         // this code has a high priority and must not be stopped by any delay, so run it here\r
 739         if(self.predator.stat_eaten)\r
 740         {\r
 741                 entity target_predator, target_predator_predator, oldself;\r
 742                 target_predator = self.predator;\r
 743                 target_predator_predator = self.predator.predator;\r
 744 \r
 745                 Vore_Regurgitate(self);\r
 746 \r
 747                 // now steal our prey's prey if this probability applies\r
 748                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 749                 {\r
 750                         oldself = self;\r
 751                         self = target_predator_predator;\r
 752                         if(Swallow_condition_check(oldself))\r
 753                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 754                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 755                                 Vore_Swallow(oldself);\r
 756                         self = oldself;\r
 757                 }\r
 758         }\r
 759 \r
 760         // the swallow progress of prey and preds idly decrease by this amount\r
 761         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 762         {\r
 763                 if(self.swallow_progress_pred)\r
 764                 {\r
 765                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 766                         if(self.swallow_progress_pred < 0)\r
 767                                 self.swallow_progress_pred = 0;\r
 768                 }\r
 769                 if(self.swallow_progress_prey)\r
 770                 {\r
 771                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 772                         if(self.swallow_progress_prey < 0)\r
 773                                 self.swallow_progress_prey = 0;\r
 774                 }\r
 775         }\r
 776 \r
 777         // apply delays and skip the vore system under some circumstances\r
 778         if(!cvar("g_vore")) // the vore system is disabled\r
 779         {\r
 780                 Vore_Disconnect();\r
 781                 return;\r
 782         }\r
 783         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 784         {\r
 785                 Vore_Disconnect();\r
 786                 return;\r
 787         }\r
 788         if(self.spectatee_status)\r
 789                 return;\r
 790         if(time < self.system_delay)\r
 791                 return;\r
 792 \r
 793 // --------------------------------\r
 794 // Code that addresses predators:\r
 795 // --------------------------------\r
 796 \r
 797         entity prey;\r
 798         prey = Swallow_player_check();\r
 799 \r
 800         // set the predator's stomach load and capacity\r
 801         Vore_StomachLoad_Apply();\r
 802 \r
 803         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 804         self.stat_canswallow = 0;\r
 805         if(Swallow_condition_check(prey))\r
 806         {\r
 807                 // canswallow stat, used by the HUD\r
 808                 if(teams_matter && prey.team == self.team)\r
 809                         self.stat_canswallow = 2;\r
 810                 else\r
 811                         self.stat_canswallow = 1;\r
 812 \r
 813                 if(self.BUTTON_ATCK)\r
 814                         Vore_SwallowStep(prey);\r
 815         }\r
 816         else if(prey != world)\r
 817                 self.stat_canswallow = -1;\r
 818 \r
 819         // toggle digestion, if the player has someone in their stomach\r
 820         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 821         {\r
 822                 if(self.stomach_load)\r
 823                 {\r
 824                         if(time > self.digest_button_delay_time)\r
 825                         {\r
 826                                 self.digesting = !self.digesting;\r
 827                                 self.digest_button_delay_time = time + button_delay_time;\r
 828                         }\r
 829                 }\r
 830                 else if(time > self.complain_vore)\r
 831                 {\r
 832                         play2(self, "misc/forbidden.wav");\r
 833                         sprint(self, "There is nothing to digest\n");\r
 834                         self.complain_vore = time + complain_delay_time;\r
 835                 }\r
 836         }\r
 837         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 838                 self.digesting = FALSE;\r
 839 \r
 840         // predator wishes to regurgitate his prey\r
 841         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 842         {\r
 843                 if(self.stomach_load)\r
 844                 {\r
 845                         if(time > self.regurgitate_button_delay_time)\r
 846                         {\r
 847                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 848                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 849                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 850                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 851                         }\r
 852                 }\r
 853                 else if(time > self.complain_vore)\r
 854                 {\r
 855                         play2(self, "misc/forbidden.wav");\r
 856                         sprint(self, "There is nothing to regurgitate\n");\r
 857                         self.complain_vore = time + complain_delay_time;\r
 858                 }\r
 859         }\r
 860 \r
 861         if(cvar("g_vore_gurglesound"))\r
 862                 Vore_GurgleSound();\r
 863 \r
 864 // --------------------------------\r
 865 // Code that addresses the prey:\r
 866 // --------------------------------\r
 867 \r
 868         Vore_SetPreyPositions();\r
 869 \r
 870         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 871         if(self.fakeprey)\r
 872         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 873                 Vore_DeadPrey_Detach(self);\r
 874 \r
 875         if(!self.stat_eaten)\r
 876                 return;\r
 877 \r
 878         if(self.deadflag != DEAD_NO)\r
 879         {\r
 880                 Vore_PreyRelease(self, FALSE);\r
 881                 return;\r
 882         }\r
 883 \r
 884         if(self.predator.deadflag != DEAD_NO)\r
 885                 Vore_Regurgitate(self);\r
 886         else if(cvar("g_balance_vore_load_pred_speedcap") && vlen(self.predator.velocity) >= cvar("g_balance_vore_load_pred_speedcap") / (self.predator.stomach_load / self.predator.stomach_maxload))\r
 887                 Vore_Regurgitate(self);\r
 888 \r
 889         // apply delayed regurgitating if it was scheduled\r
 890         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 891         {\r
 892                 self.predator.regurgitate_prepare = 0;\r
 893                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 894                 Vore_Regurgitate(self);\r
 895         }\r
 896 \r
 897         // execute digesting and team healing\r
 898         if(self.predator.digesting == TRUE)\r
 899                 Vore_Digest();\r
 900         if(teams_matter && self.team == self.predator.team)\r
 901         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 902                 Vore_Teamheal();\r
 903 \r
 904         // execute prey commands\r
 905         if(self.BUTTON_ATCK)\r
 906         {\r
 907                 if(cvar("g_vore_kick"))\r
 908                         Vore_StomachKick();\r
 909         }\r
 910         else\r
 911                 self.kick_pressed = FALSE;\r
 912         if(self.BUTTON_JUMP)\r
 913                 Vore_StomachLeave();\r
 914 \r
 915         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 916         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 917         kh_Key_DropAll(self, FALSE);\r
 918 }