CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3 project(NetRadiant C CXX)
   4
   5 option(BUILD_RADIANT "Build the GUI" ON)
   6 option(BUILD_TOOLS "Build the tools" ON)
   7 option(BUILD_CRUNCH "Build Crunch image support" OFF)
   8 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
   9 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  10 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  11
  12 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  13 if (BUILD_RADIANT OR BUILD_TOOLS)
  14     set(BUILD_BINARIES ON)
  15 endif ()
  16
  17 #-----------------------------------------------------------------------
  18 # Paths
  19 #-----------------------------------------------------------------------
  20
  21 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  22     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
  23 endif ()
  24
  25 set(RADIANT_BASENAME netradiant CACHE INTERNAL "...")
  26 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
  27
  28 set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  29 set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  30 set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  31
  32 if (FHS_INSTALL)
  33     set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX}/lib/${RADIANT_BASENAME})
  34     set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX}/bin)
  35     set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX}/share/${RADIANT_BASENAME})
  36 endif ()
  37
  38 #-----------------------------------------------------------------------
  39 # Version
  40 #-----------------------------------------------------------------------
  41
  42 # CMake 3.0+ would allow this in project()
  43 set(RADIANT_VERSION_MAJOR 1)
  44 set(RADIANT_VERSION_MINOR 5)
  45 set(RADIANT_VERSION_PATCH 0)
  46 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
  47
  48 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  49
  50 find_package(Git REQUIRED)
  51
  52 execute_process(
  53      COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  54      WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  55      OUTPUT_VARIABLE GIT_VERSION
  56      OUTPUT_STRIP_TRAILING_WHITESPACE
  57 )
  58
  59 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
  60
  61 if (GIT_VERSION)
  62     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  63 endif ()
  64
  65 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  66
  67 #-----------------------------------------------------------------------
  68 # Language standard
  69 #-----------------------------------------------------------------------
  70
  71 if (BUILD_BINARIES)
  72     set(CMAKE_CXX_STANDARD 11)
  73     set(CMAKE_CXX_STANDARD_REQUIRED ON)
  74     set(CMAKE_CXX_EXTENSIONS OFF)
  75
  76     if (CMAKE_VERSION VERSION_LESS "3.1")
  77         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  78             include(CheckCXXCompilerFlag)
  79             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  80             if (STD_CXX)
  81                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  82             else ()
  83                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  84             endif ()
  85         else ()
  86             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  87         endif ()
  88     endif ()
  89 endif ()
  90
  91 #-----------------------------------------------------------------------
  92 # Flags
  93 #-----------------------------------------------------------------------
  94
  95 if (BUILD_BINARIES)
  96     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  97
  98     macro (addflags_c args)
  99         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 100     endmacro ()
 101
 102     macro (addflags_cxx args)
 103         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 104     endmacro ()
 105
 106     macro (addflags args)
 107         addflags_c("${args}")
 108         addflags_cxx("${args}")
 109     endmacro ()
 110
 111     addflags("-fno-strict-aliasing")
 112     if (NOT WIN32)
 113         addflags("-fvisibility=hidden")
 114     endif ()
 115
 116     if (USE_WERROR)
 117         addflags("-Werror")
 118         addflags("-pedantic-errors")
 119     endif ()
 120
 121     addflags("-Wall")
 122     addflags("-Wextra")
 123     addflags("-pedantic")
 124
 125     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 126
 127     addflags("-Wno-unused-function")
 128     addflags("-Wno-unused-variable")
 129     addflags("-Wno-unused-parameter")
 130
 131     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 132 endif ()
 133
 134 if (BUILD_RADIANT)
 135     set(GTK_TARGET 2 CACHE STRING "GTK target")
 136     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 137 endif ()
 138
 139 #-----------------------------------------------------------------------
 140 # Defs
 141 #-----------------------------------------------------------------------
 142
 143 if (BUILD_BINARIES)
 144     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 145
 146     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 147         add_definitions(-D_DEBUG=1)
 148     endif ()
 149 endif ()
 150
 151 if (BUILD_RADIANT)
 152     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 153
 154     macro (disable_deprecated name gtk2only)
 155         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 156         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 157             add_definitions(-D${name}_DISABLE_DEPRECATED)
 158         endif ()
 159     endmacro ()
 160
 161     disable_deprecated(ATK 0)
 162     disable_deprecated(G 0)
 163     disable_deprecated(GDK 0)
 164     disable_deprecated(GDK_PIXBUF 0)
 165     disable_deprecated(GTK 1)
 166     disable_deprecated(PANGO 0)
 167 endif ()
 168
 169 if (BUILD_BINARIES)
 170     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 171         link_directories(
 172             /usr/local/lib
 173         )
 174     endif ()
 175
 176     if (WIN32)
 177         add_definitions(
 178             -DWIN32=1
 179             -D_WIN32=1
 180         )
 181     else ()
 182         add_definitions(
 183             -DPOSIX=1
 184         )
 185     endif ()
 186 endif ()
 187
 188 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 189     set(XWINDOWS ON)
 190     find_package(X11 REQUIRED)
 191     include_directories(${X11_INCLUDE_DIR})
 192     add_definitions(-DXWINDOWS=1)
 193 endif ()
 194
 195 if (BUILD_BINARIES)
 196     include_directories("${PROJECT_SOURCE_DIR}/include")
 197     include_directories("${PROJECT_SOURCE_DIR}/libs")
 198
 199     if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
 200         set(BUNDLE_LIBRARIES_DEFAULT ON)
 201     else ()
 202         set(BUNDLE_LIBRARIES_DEFAULT OFF)
 203     endif ()
 204
 205     option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 206
 207     macro (copy_dlls target)
 208         if (BUNDLE_LIBRARIES AND WIN32)
 209             add_custom_command(TARGET ${target} POST_BUILD
 210                 COMMAND bash
 211                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | egrep -i '\\.dll ' | grep -iv '/c/Windows' | awk '{ print $1 }' | while read dll; do dllbasename=\"$(which \"$dll\")\"; [ -f \"${PROJECT_BINARY_DIR}/$dllbasename\" ] || cp --preserve=timestamps \"$dllbasename\" '${PROJECT_BINARY_DIR}'; done"
 212                 VERBATIM
 213         )
 214         endif ()
 215     endmacro ()
 216
 217     macro (bundle_stuff target)
 218         if (BUNDLE_LIBRARIES AND WIN32)
 219             add_custom_command(TARGET ${target} POST_BUILD
 220                 COMMAND bash
 221                 ARGS -c "mkdir -p '${PROJECT_BINARY_DIR}/share/themes'; mkdir -p '${PROJECT_BINARY_DIR}/lib'; mingw=\"$(echo '${CMAKE_C_COMPILER}' | sed -e 's|/bin/.*||')\"; [ -d '${PROJECT_BINARY_DIR}/share/themes/MS-Windows' ] || cp -r --preserve=timestamps \"$mingw/share/themes/MS-Windows\" '${PROJECT_BINARY_DIR}/share/themes/'; [ -d '${PROJECT_BINARY_DIR}/lib/gdk-pixbuf-2.0' ] || cp -r --preserve=timestamps \"$mingw/lib/gdk-pixbuf-2.0\" '${PROJECT_BINARY_DIR}/lib/'; [ -d '${PROJECT_BINARY_DIR}/lib/gtk-2.0' ] || cp -r --preserve=timestamps \"$mingw/lib/gtk-2.0\" '${PROJECT_BINARY_DIR}/lib/'"
 222                 VERBATIM
 223         )
 224
 225         file(GLOB DLL_FILES ${PROJECT_BINARY_DIR}/*.dll)
 226
 227         install(FILES
 228             ${DLL_FILES}
 229             DESTINATION ${CMAKE_INSTALL_PREFIX}
 230         )
 231
 232         install(DIRECTORY
 233             ${PROJECT_BINARY_DIR}/lib
 234             ${PROJECT_BINARY_DIR}/share
 235             DESTINATION ${CMAKE_INSTALL_PREFIX}
 236         )
 237         endif ()
 238     endmacro ()
 239 endif ()
 240
 241 #-----------------------------------------------------------------------
 242 # Libraries
 243 #-----------------------------------------------------------------------
 244
 245 if (BUILD_BINARIES)
 246     add_subdirectory(libs)
 247 endif ()
 248
 249 if (BUILD_RADIANT)
 250     add_subdirectory(include)
 251 endif ()
 252
 253 #-----------------------------------------------------------------------
 254 # Plugins
 255 #-----------------------------------------------------------------------
 256
 257 if (BUILD_RADIANT)
 258     add_subdirectory(contrib)
 259 endif ()
 260
 261 #-----------------------------------------------------------------------
 262 # Modules
 263 #-----------------------------------------------------------------------
 264
 265 if (BUILD_RADIANT)
 266     add_subdirectory(plugins)
 267 endif ()
 268
 269 #-----------------------------------------------------------------------
 270 # Radiant
 271 #-----------------------------------------------------------------------
 272
 273 if (BUILD_BINARIES)
 274     if (CMAKE_EXECUTABLE_SUFFIX)
 275         string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
 276     endif ()
 277
 278     macro (radiant_tool name)
 279         add_executable(${name} ${ARGN})
 280
 281         copy_dlls(${name})
 282
 283         install(
 284             TARGETS ${name}
 285             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 286         )
 287     endmacro ()
 288
 289     if (BUILD_RADIANT)
 290         add_subdirectory(radiant)
 291         set_target_properties(${RADIANT_BASENAME} PROPERTIES
 292         COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
 293     )
 294     endif ()
 295 endif ()
 296
 297 #-----------------------------------------------------------------------
 298 # Tools
 299 #-----------------------------------------------------------------------
 300
 301 if (BUILD_TOOLS)
 302     add_subdirectory(tools)
 303
 304     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 305
 306     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 307         # Copy data files from sources to the build directory
 308         message(STATUS "Copying data files")
 309         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 310     endif ()
 311 endif ()
 312
 313 #-----------------------------------------------------------------------
 314 # Game packs
 315 #-----------------------------------------------------------------------
 316
 317 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 318 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 319
 320 if (DOWNLOAD_GAMEPACKS)
 321     add_custom_target(game_packs ALL
 322        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${PROJECT_BINARY_DIR}/download" --install-dir "${PROJECT_BINARY_DIR}" --download --install
 323        COMMENT "Downloading game packs"
 324     )
 325 endif ()
 326
 327 #-----------------------------------------------------------------------
 328 # Install
 329 #-----------------------------------------------------------------------
 330
 331 if (BUILD_BINARIES)
 332     install(DIRECTORY
 333         setup/data/tools/base
 334         setup/data/tools/bitmaps
 335         setup/data/tools/gl
 336         setup/data/tools/plugins
 337         docs
 338         DESTINATION ${RADIANT_DATA_DIR}
 339     )
 340 endif ()
 341
 342 if (DOWNLOAD_GAMEPACKS)
 343     if (FHS_INSTALL)
 344        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/share/netradiant")
 345     else ()
 346        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")
 347     endif ()
 348
 349     file(GLOB GAME_DIRS ${PROJECT_BINARY_DIR}/*.game)
 350
 351     install(DIRECTORY
 352         ${PROJECT_BINARY_DIR}/games
 353         ${GAME_DIRS}
 354         DESTINATION ${RADIANT_DATA_DIR}
 355     )
 356 endif ()
 357
 358 if(BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 359     install(FILES
 360         ${PROJECT_SOURCE_DIR}/icons/netradiant.png
 361         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/pixmaps
 362     )
 363     install(FILES
 364         ${PROJECT_SOURCE_DIR}/icons/netradiant.desktop
 365         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications
 366     )
 367     install(FILES
 368         ${PROJECT_SOURCE_DIR}/icons/mime/map.xml
 369         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/mime/model
 370     )
 371 endif ()
 372
 373 include(cmake/scripts/package.cmake)